dlaed5()

subroutine dlaed5	(	integer	i,
		double precision, dimension( 2 )	d,
		double precision, dimension( 2 )	z,
		double precision, dimension( 2 )	delta,
		double precision	rho,
		double precision	dlam )

DLAED5 used by DSTEDC. Solves the 2-by-2 secular equation.

Download DLAED5 + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> This subroutine computes the I-th eigenvalue of a symmetric rank-one
!> modification of a 2-by-2 diagonal matrix
!>
!>            diag( D )  +  RHO * Z * transpose(Z) .
!>
!> The diagonal elements in the array D are assumed to satisfy
!>
!>            D(i) < D(j)  for  i < j .
!>
!> We also assume RHO > 0 and that the Euclidean norm of the vector
!> Z is one.
!> 

Parameters

[in]	I	!> I is INTEGER !> The index of the eigenvalue to be computed. I = 1 or I = 2. !>
[in]	D	!> D is DOUBLE PRECISION array, dimension (2) !> The original eigenvalues. We assume D(1) < D(2). !>
[in]	Z	!> Z is DOUBLE PRECISION array, dimension (2) !> The components of the updating vector. !>
[out]	DELTA	!> DELTA is DOUBLE PRECISION array, dimension (2) !> The vector DELTA contains the information necessary !> to construct the eigenvectors. !>
[in]	RHO	!> RHO is DOUBLE PRECISION !> The scalar in the symmetric updating formula. !>
[out]	DLAM	!> DLAM is DOUBLE PRECISION !> The computed lambda_I, the I-th updated eigenvalue. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Contributors:

Ren-Cang Li, Computer Science Division, University of California at Berkeley, USA

Definition at line 105 of file dlaed5.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            I
      DOUBLE PRECISION   DLAM, RHO
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   D( 2 ), DELTA( 2 ), Z( 2 )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE, TWO, FOUR
      parameter( zero = 0.0d0, one = 1.0d0, two = 2.0d0,
     $                   four = 4.0d0 )
*     ..
*     .. Local Scalars ..
      DOUBLE PRECISION   B, C, DEL, TAU, TEMP, W
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, sqrt
*     ..
*     .. Executable Statements ..
*
      del = d( 2 ) - d( 1 )
      IF( i.EQ.1 ) THEN
         w = one + two*rho*( z( 2 )*z( 2 )-z( 1 )*z( 1 ) ) / del
         IF( w.GT.zero ) THEN
            b = del + rho*( z( 1 )*z( 1 )+z( 2 )*z( 2 ) )
            c = rho*z( 1 )*z( 1 )*del
*
*           B > ZERO, always
*
            tau = two*c / ( b+sqrt( abs( b*b-four*c ) ) )
            dlam = d( 1 ) + tau
            delta( 1 ) = -z( 1 ) / tau
            delta( 2 ) = z( 2 ) / ( del-tau )
         ELSE
            b = -del + rho*( z( 1 )*z( 1 )+z( 2 )*z( 2 ) )
            c = rho*z( 2 )*z( 2 )*del
            IF( b.GT.zero ) THEN
               tau = -two*c / ( b+sqrt( b*b+four*c ) )
            ELSE
               tau = ( b-sqrt( b*b+four*c ) ) / two
            END IF
            dlam = d( 2 ) + tau
            delta( 1 ) = -z( 1 ) / ( del+tau )
            delta( 2 ) = -z( 2 ) / tau
         END IF
         temp = sqrt( delta( 1 )*delta( 1 )+delta( 2 )*delta( 2 ) )
         delta( 1 ) = delta( 1 ) / temp
         delta( 2 ) = delta( 2 ) / temp
      ELSE
*
*     Now I=2
*
         b = -del + rho*( z( 1 )*z( 1 )+z( 2 )*z( 2 ) )
         c = rho*z( 2 )*z( 2 )*del
         IF( b.GT.zero ) THEN
            tau = ( b+sqrt( b*b+four*c ) ) / two
         ELSE
            tau = two*c / ( -b+sqrt( b*b+four*c ) )
         END IF
         dlam = d( 2 ) + tau
         delta( 1 ) = -z( 1 ) / ( del+tau )
         delta( 2 ) = -z( 2 ) / tau
         temp = sqrt( delta( 1 )*delta( 1 )+delta( 2 )*delta( 2 ) )
         delta( 1 ) = delta( 1 ) / temp
         delta( 2 ) = delta( 2 ) / temp
      END IF
      RETURN
*
*     End of DLAED5
*

Here is the caller graph for this function: