clarcm()

subroutine clarcm	(	integer	m,
		integer	n,
		real, dimension( lda, * )	a,
		integer	lda,
		complex, dimension( ldb, * )	b,
		integer	ldb,
		complex, dimension( ldc, * )	c,
		integer	ldc,
		real, dimension( * )	rwork
	)

CLARCM copies all or part of a real two-dimensional array to a complex array.

Download CLARCM + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 CLARCM performs a very simple matrix-matrix multiplication:
          C := A * B,
 where A is M by M and real; B is M by N and complex;
 C is M by N and complex.

Parameters

[in]	M	M is INTEGER The number of rows of the matrix A and of the matrix C. M >= 0.
[in]	N	N is INTEGER The number of columns and rows of the matrix B and the number of columns of the matrix C. N >= 0.
[in]	A	A is REAL array, dimension (LDA, M) On entry, A contains the M by M matrix A.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >=max(1,M).
[in]	B	B is COMPLEX array, dimension (LDB, N) On entry, B contains the M by N matrix B.
[in]	LDB	LDB is INTEGER The leading dimension of the array B. LDB >=max(1,M).
[out]	C	C is COMPLEX array, dimension (LDC, N) On exit, C contains the M by N matrix C.
[in]	LDC	LDC is INTEGER The leading dimension of the array C. LDC >=max(1,M).
[out]	RWORK	RWORK is REAL array, dimension (2*M*N)

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 113 of file clarcm.f.

*
*  -- LAPACK auxiliary routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            LDA, LDB, LDC, M, N
*     ..
*     .. Array Arguments ..
      REAL               A( LDA, * ), RWORK( * )
      COMPLEX            B( LDB, * ), C( LDC, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ONE, ZERO
      parameter( one = 1.0e0, zero = 0.0e0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, J, L
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          aimag, cmplx, real
*     ..
*     .. External Subroutines ..
      EXTERNAL           sgemm
*     ..
*     .. Executable Statements ..
*
*     Quick return if possible.
*
      IF( ( m.EQ.0 ) .OR. ( n.EQ.0 ) )
     $   RETURN
*
      DO 20 j = 1, n
         DO 10 i = 1, m
            rwork( ( j-1 )*m+i ) = real( b( i, j ) )
   10    CONTINUE
   20 CONTINUE
*
      l = m*n + 1
      CALL sgemm( 'N', 'N', m, n, m, one, a, lda, rwork, m, zero,
     $            rwork( l ), m )
      DO 40 j = 1, n
         DO 30 i = 1, m
            c( i, j ) = rwork( l+( j-1 )*m+i-1 )
   30    CONTINUE
   40 CONTINUE
*
      DO 60 j = 1, n
         DO 50 i = 1, m
            rwork( ( j-1 )*m+i ) = aimag( b( i, j ) )
   50    CONTINUE
   60 CONTINUE
      CALL sgemm( 'N', 'N', m, n, m, one, a, lda, rwork, m, zero,
     $            rwork( l ), m )
      DO 80 j = 1, n
         DO 70 i = 1, m
            c( i, j ) = cmplx( real( c( i, j ) ),
     $                  rwork( l+( j-1 )*m+i-1 ) )
   70    CONTINUE
   80 CONTINUE
*
      RETURN
*
*     End of CLARCM
*

Here is the call graph for this function:

Here is the caller graph for this function: