 LAPACK  3.10.1 LAPACK: Linear Algebra PACKage

## ◆ clange()

 real function clange ( character NORM, integer M, integer N, complex, dimension( lda, * ) A, integer LDA, real, dimension( * ) WORK )

CLANGE returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value of any element of a general rectangular matrix.

Download CLANGE + dependencies [TGZ] [ZIP] [TXT]

Purpose:
``` CLANGE  returns the value of the one norm,  or the Frobenius norm, or
the  infinity norm,  or the  element of  largest absolute value  of a
complex matrix A.```
Returns
CLANGE
```    CLANGE = ( max(abs(A(i,j))), NORM = 'M' or 'm'
(
( norm1(A),         NORM = '1', 'O' or 'o'
(
( normI(A),         NORM = 'I' or 'i'
(
( normF(A),         NORM = 'F', 'f', 'E' or 'e'

where  norm1  denotes the  one norm of a matrix (maximum column sum),
normI  denotes the  infinity norm  of a matrix  (maximum row sum) and
normF  denotes the  Frobenius norm of a matrix (square root of sum of
squares).  Note that  max(abs(A(i,j)))  is not a consistent matrix norm.```
Parameters
 [in] NORM ``` NORM is CHARACTER*1 Specifies the value to be returned in CLANGE as described above.``` [in] M ``` M is INTEGER The number of rows of the matrix A. M >= 0. When M = 0, CLANGE is set to zero.``` [in] N ``` N is INTEGER The number of columns of the matrix A. N >= 0. When N = 0, CLANGE is set to zero.``` [in] A ``` A is COMPLEX array, dimension (LDA,N) The m by n matrix A.``` [in] LDA ``` LDA is INTEGER The leading dimension of the array A. LDA >= max(M,1).``` [out] WORK ``` WORK is REAL array, dimension (MAX(1,LWORK)), where LWORK >= M when NORM = 'I'; otherwise, WORK is not referenced.```

Definition at line 114 of file clange.f.

115 *
116 * -- LAPACK auxiliary routine --
117 * -- LAPACK is a software package provided by Univ. of Tennessee, --
118 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
119 *
120 * .. Scalar Arguments ..
121  CHARACTER NORM
122  INTEGER LDA, M, N
123 * ..
124 * .. Array Arguments ..
125  REAL WORK( * )
126  COMPLEX A( LDA, * )
127 * ..
128 *
129 * =====================================================================
130 *
131 * .. Parameters ..
132  REAL ONE, ZERO
133  parameter( one = 1.0e+0, zero = 0.0e+0 )
134 * ..
135 * .. Local Scalars ..
136  INTEGER I, J
137  REAL SCALE, SUM, VALUE, TEMP
138 * ..
139 * .. External Functions ..
140  LOGICAL LSAME, SISNAN
141  EXTERNAL lsame, sisnan
142 * ..
143 * .. External Subroutines ..
144  EXTERNAL classq
145 * ..
146 * .. Intrinsic Functions ..
147  INTRINSIC abs, min, sqrt
148 * ..
149 * .. Executable Statements ..
150 *
151  IF( min( m, n ).EQ.0 ) THEN
152  VALUE = zero
153  ELSE IF( lsame( norm, 'M' ) ) THEN
154 *
155 * Find max(abs(A(i,j))).
156 *
157  VALUE = zero
158  DO 20 j = 1, n
159  DO 10 i = 1, m
160  temp = abs( a( i, j ) )
161  IF( VALUE.LT.temp .OR. sisnan( temp ) ) VALUE = temp
162  10 CONTINUE
163  20 CONTINUE
164  ELSE IF( ( lsame( norm, 'O' ) ) .OR. ( norm.EQ.'1' ) ) THEN
165 *
166 * Find norm1(A).
167 *
168  VALUE = zero
169  DO 40 j = 1, n
170  sum = zero
171  DO 30 i = 1, m
172  sum = sum + abs( a( i, j ) )
173  30 CONTINUE
174  IF( VALUE.LT.sum .OR. sisnan( sum ) ) VALUE = sum
175  40 CONTINUE
176  ELSE IF( lsame( norm, 'I' ) ) THEN
177 *
178 * Find normI(A).
179 *
180  DO 50 i = 1, m
181  work( i ) = zero
182  50 CONTINUE
183  DO 70 j = 1, n
184  DO 60 i = 1, m
185  work( i ) = work( i ) + abs( a( i, j ) )
186  60 CONTINUE
187  70 CONTINUE
188  VALUE = zero
189  DO 80 i = 1, m
190  temp = work( i )
191  IF( VALUE.LT.temp .OR. sisnan( temp ) ) VALUE = temp
192  80 CONTINUE
193  ELSE IF( ( lsame( norm, 'F' ) ) .OR. ( lsame( norm, 'E' ) ) ) THEN
194 *
195 * Find normF(A).
196 *
197  scale = zero
198  sum = one
199  DO 90 j = 1, n
200  CALL classq( m, a( 1, j ), 1, scale, sum )
201  90 CONTINUE
202  VALUE = scale*sqrt( sum )
203  END IF
204 *
205  clange = VALUE
206  RETURN
207 *
208 * End of CLANGE
209 *
subroutine classq(n, x, incx, scl, sumsq)
CLASSQ updates a sum of squares represented in scaled form.
Definition: classq.f90:137
logical function sisnan(SIN)
SISNAN tests input for NaN.
Definition: sisnan.f:59
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
real function clange(NORM, M, N, A, LDA, WORK)
CLANGE returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value ...
Definition: clange.f:115
Here is the call graph for this function:
Here is the caller graph for this function: