cunml2()

subroutine cunml2	(	character	side,
		character	trans,
		integer	m,
		integer	n,
		integer	k,
		complex, dimension( lda, * )	a,
		integer	lda,
		complex, dimension( * )	tau,
		complex, dimension( ldc, * )	c,
		integer	ldc,
		complex, dimension( * )	work,
		integer	info
	)

CUNML2 multiplies a general matrix by the unitary matrix from a LQ factorization determined by cgelqf (unblocked algorithm).

Download CUNML2 + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 CUNML2 overwrites the general complex m-by-n matrix C with

       Q * C  if SIDE = 'L' and TRANS = 'N', or

       Q**H* C  if SIDE = 'L' and TRANS = 'C', or

       C * Q  if SIDE = 'R' and TRANS = 'N', or

       C * Q**H if SIDE = 'R' and TRANS = 'C',

 where Q is a complex unitary matrix defined as the product of k
 elementary reflectors

       Q = H(k)**H . . . H(2)**H H(1)**H

 as returned by CGELQF. Q is of order m if SIDE = 'L' and of order n
 if SIDE = 'R'.

Parameters

[in]	SIDE	SIDE is CHARACTER*1 = 'L': apply Q or Q**H from the Left = 'R': apply Q or Q**H from the Right
[in]	TRANS	TRANS is CHARACTER*1 = 'N': apply Q (No transpose) = 'C': apply Q**H (Conjugate transpose)
[in]	M	M is INTEGER The number of rows of the matrix C. M >= 0.
[in]	N	N is INTEGER The number of columns of the matrix C. N >= 0.
[in]	K	K is INTEGER The number of elementary reflectors whose product defines the matrix Q. If SIDE = 'L', M >= K >= 0; if SIDE = 'R', N >= K >= 0.
[in]	A	A is COMPLEX array, dimension (LDA,M) if SIDE = 'L', (LDA,N) if SIDE = 'R' The i-th row must contain the vector which defines the elementary reflector H(i), for i = 1,2,...,k, as returned by CGELQF in the first k rows of its array argument A. A is modified by the routine but restored on exit.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,K).
[in]	TAU	TAU is COMPLEX array, dimension (K) TAU(i) must contain the scalar factor of the elementary reflector H(i), as returned by CGELQF.
[in,out]	C	C is COMPLEX array, dimension (LDC,N) On entry, the m-by-n matrix C. On exit, C is overwritten by Q*C or Q**H*C or C*Q**H or C*Q.
[in]	LDC	LDC is INTEGER The leading dimension of the array C. LDC >= max(1,M).
[out]	WORK	WORK is COMPLEX array, dimension (N) if SIDE = 'L', (M) if SIDE = 'R'
[out]	INFO	INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 157 of file cunml2.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          SIDE, TRANS
      INTEGER            INFO, K, LDA, LDC, M, N
*     ..
*     .. Array Arguments ..
      COMPLEX            A( LDA, * ), C( LDC, * ), TAU( * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      COMPLEX            ONE
      parameter( one = ( 1.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      LOGICAL            LEFT, NOTRAN
      INTEGER            I, I1, I2, I3, IC, JC, MI, NI, NQ
      COMPLEX            AII, TAUI
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           lsame
*     ..
*     .. External Subroutines ..
      EXTERNAL           clacgv, clarf, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          conjg, max
*     ..
*     .. Executable Statements ..
*
*     Test the input arguments
*
      info = 0
      left = lsame( side, 'L' )
      notran = lsame( trans, 'N' )
*
*     NQ is the order of Q
*
      IF( left ) THEN
         nq = m
      ELSE
         nq = n
      END IF
      IF( .NOT.left .AND. .NOT.lsame( side, 'R' ) ) THEN
         info = -1
      ELSE IF( .NOT.notran .AND. .NOT.lsame( trans, 'C' ) ) THEN
         info = -2
      ELSE IF( m.LT.0 ) THEN
         info = -3
      ELSE IF( n.LT.0 ) THEN
         info = -4
      ELSE IF( k.LT.0 .OR. k.GT.nq ) THEN
         info = -5
      ELSE IF( lda.LT.max( 1, k ) ) THEN
         info = -7
      ELSE IF( ldc.LT.max( 1, m ) ) THEN
         info = -10
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CUNML2', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( m.EQ.0 .OR. n.EQ.0 .OR. k.EQ.0 )
     $   RETURN
*
      IF( ( left .AND. notran .OR. .NOT.left .AND. .NOT.notran ) ) THEN
         i1 = 1
         i2 = k
         i3 = 1
      ELSE
         i1 = k
         i2 = 1
         i3 = -1
      END IF
*
      IF( left ) THEN
         ni = n
         jc = 1
      ELSE
         mi = m
         ic = 1
      END IF
*
      DO 10 i = i1, i2, i3
         IF( left ) THEN
*
*           H(i) or H(i)**H is applied to C(i:m,1:n)
*
            mi = m - i + 1
            ic = i
         ELSE
*
*           H(i) or H(i)**H is applied to C(1:m,i:n)
*
            ni = n - i + 1
            jc = i
         END IF
*
*        Apply H(i) or H(i)**H
*
         IF( notran ) THEN
            taui = conjg( tau( i ) )
         ELSE
            taui = tau( i )
         END IF
         IF( i.LT.nq )
     $      CALL clacgv( nq-i, a( i, i+1 ), lda )
         aii = a( i, i )
         a( i, i ) = one
         CALL clarf( side, mi, ni, a( i, i ), lda, taui, c( ic, jc ),
     $               ldc, work )
         a( i, i ) = aii
         IF( i.LT.nq )
     $      CALL clacgv( nq-i, a( i, i+1 ), lda )
   10 CONTINUE
      RETURN
*
*     End of CUNML2
*

Here is the call graph for this function:

Here is the caller graph for this function: