zlaqge()

subroutine zlaqge	(	integer	m,
		integer	n,
		complex*16, dimension( lda, * )	a,
		integer	lda,
		double precision, dimension( * )	r,
		double precision, dimension( * )	c,
		double precision	rowcnd,
		double precision	colcnd,
		double precision	amax,
		character	equed )

ZLAQGE scales a general rectangular matrix, using row and column scaling factors computed by sgeequ.

Download ZLAQGE + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> ZLAQGE equilibrates a general M by N matrix A using the row and
!> column scaling factors in the vectors R and C.
!> 

Parameters

[in]	M	!> M is INTEGER !> The number of rows of the matrix A. M >= 0. !>
[in]	N	!> N is INTEGER !> The number of columns of the matrix A. N >= 0. !>
[in,out]	A	!> A is COMPLEX*16 array, dimension (LDA,N) !> On entry, the M by N matrix A. !> On exit, the equilibrated matrix. See EQUED for the form of !> the equilibrated matrix. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= max(M,1). !>
[in]	R	!> R is DOUBLE PRECISION array, dimension (M) !> The row scale factors for A. !>
[in]	C	!> C is DOUBLE PRECISION array, dimension (N) !> The column scale factors for A. !>
[in]	ROWCND	!> ROWCND is DOUBLE PRECISION !> Ratio of the smallest R(i) to the largest R(i). !>
[in]	COLCND	!> COLCND is DOUBLE PRECISION !> Ratio of the smallest C(i) to the largest C(i). !>
[in]	AMAX	!> AMAX is DOUBLE PRECISION !> Absolute value of largest matrix entry. !>
[out]	EQUED	!> EQUED is CHARACTER*1 !> Specifies the form of equilibration that was done. !> = 'N': No equilibration !> = 'R': Row equilibration, i.e., A has been premultiplied by !> diag(R). !> = 'C': Column equilibration, i.e., A has been postmultiplied !> by diag(C). !> = 'B': Both row and column equilibration, i.e., A has been !> replaced by diag(R) * A * diag(C). !>

Internal Parameters:

!>  THRESH is a threshold value used to decide if row or column scaling
!>  should be done based on the ratio of the row or column scaling
!>  factors.  If ROWCND < THRESH, row scaling is done, and if
!>  COLCND < THRESH, column scaling is done.
!>
!>  LARGE and SMALL are threshold values used to decide if row scaling
!>  should be done based on the absolute size of the largest matrix
!>  element.  If AMAX > LARGE or AMAX < SMALL, row scaling is done.
!> 

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 139 of file zlaqge.f.

*
*  -- LAPACK auxiliary routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          EQUED
      INTEGER            LDA, M, N
      DOUBLE PRECISION   AMAX, COLCND, ROWCND
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   C( * ), R( * )
      COMPLEX*16         A( LDA, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ONE, THRESH
      parameter( one = 1.0d+0, thresh = 0.1d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, J
      DOUBLE PRECISION   CJ, LARGE, SMALL
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   DLAMCH
      EXTERNAL           dlamch
*     ..
*     .. Executable Statements ..
*
*     Quick return if possible
*
      IF( m.LE.0 .OR. n.LE.0 ) THEN
         equed = 'N'
         RETURN
      END IF
*
*     Initialize LARGE and SMALL.
*
      small = dlamch( 'Safe minimum' ) / dlamch( 'Precision' )
      large = one / small
*
      IF( rowcnd.GE.thresh .AND. amax.GE.small .AND. amax.LE.large )
     $     THEN
*
*        No row scaling
*
         IF( colcnd.GE.thresh ) THEN
*
*           No column scaling
*
            equed = 'N'
         ELSE
*
*           Column scaling
*
            DO 20 j = 1, n
               cj = c( j )
               DO 10 i = 1, m
                  a( i, j ) = cj*a( i, j )
   10          CONTINUE
   20       CONTINUE
            equed = 'C'
         END IF
      ELSE IF( colcnd.GE.thresh ) THEN
*
*        Row scaling, no column scaling
*
         DO 40 j = 1, n
            DO 30 i = 1, m
               a( i, j ) = r( i )*a( i, j )
   30       CONTINUE
   40    CONTINUE
         equed = 'R'
      ELSE
*
*        Row and column scaling
*
         DO 60 j = 1, n
            cj = c( j )
            DO 50 i = 1, m
               a( i, j ) = cj*r( i )*a( i, j )
   50       CONTINUE
   60    CONTINUE
         equed = 'B'
      END IF
*
      RETURN
*
*     End of ZLAQGE
*

Here is the caller graph for this function: