chst01()

subroutine chst01	(	integer	n,
		integer	ilo,
		integer	ihi,
		complex, dimension( lda, * )	a,
		integer	lda,
		complex, dimension( ldh, * )	h,
		integer	ldh,
		complex, dimension( ldq, * )	q,
		integer	ldq,
		complex, dimension( lwork )	work,
		integer	lwork,
		real, dimension( * )	rwork,
		real, dimension( 2 )	result )

CHST01

Purpose:

!>
!> CHST01 tests the reduction of a general matrix A to upper Hessenberg
!> form:  A = Q*H*Q'.  Two test ratios are computed;
!>
!> RESULT(1) = norm( A - Q*H*Q' ) / ( norm(A) * N * EPS )
!> RESULT(2) = norm( I - Q'*Q ) / ( N * EPS )
!>
!> The matrix Q is assumed to be given explicitly as it would be
!> following CGEHRD + CUNGHR.
!>
!> In this version, ILO and IHI are not used, but they could be used
!> to save some work if this is desired.
!> 

Parameters

[in]	N	!> N is INTEGER !> The order of the matrix A. N >= 0. !>
[in]	ILO	!> ILO is INTEGER !>
[in]	IHI	!> IHI is INTEGER !> !> A is assumed to be upper triangular in rows and columns !> 1:ILO-1 and IHI+1:N, so Q differs from the identity only in !> rows and columns ILO+1:IHI. !>
[in]	A	!> A is COMPLEX array, dimension (LDA,N) !> The original n by n matrix A. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= max(1,N). !>
[in]	H	!> H is COMPLEX array, dimension (LDH,N) !> The upper Hessenberg matrix H from the reduction A = Q*H*Q' !> as computed by CGEHRD. H is assumed to be zero below the !> first subdiagonal. !>
[in]	LDH	!> LDH is INTEGER !> The leading dimension of the array H. LDH >= max(1,N). !>
[in]	Q	!> Q is COMPLEX array, dimension (LDQ,N) !> The orthogonal matrix Q from the reduction A = Q*H*Q' as !> computed by CGEHRD + CUNGHR. !>
[in]	LDQ	!> LDQ is INTEGER !> The leading dimension of the array Q. LDQ >= max(1,N). !>
[out]	WORK	!> WORK is COMPLEX array, dimension (LWORK) !>
[in]	LWORK	!> LWORK is INTEGER !> The length of the array WORK. LWORK >= 2*N*N. !>
[out]	RWORK	!> RWORK is REAL array, dimension (N) !>
[out]	RESULT	!> RESULT is REAL array, dimension (2) !> RESULT(1) = norm( A - Q*H*Q' ) / ( norm(A) * N * EPS ) !> RESULT(2) = norm( I - Q'*Q ) / ( N * EPS ) !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 138 of file chst01.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            IHI, ILO, LDA, LDH, LDQ, LWORK, N
*     ..
*     .. Array Arguments ..
      REAL               RESULT( 2 ), RWORK( * )
      COMPLEX            A( LDA, * ), H( LDH, * ), Q( LDQ, * ),
     $                   WORK( LWORK )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ONE, ZERO
      parameter( one = 1.0e+0, zero = 0.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            LDWORK
      REAL               ANORM, EPS, OVFL, SMLNUM, UNFL, WNORM
*     ..
*     .. External Functions ..
      REAL               CLANGE, SLAMCH
      EXTERNAL           clange, slamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           cgemm, clacpy, cunt01
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          cmplx, max, min
*     ..
*     .. Executable Statements ..
*
*     Quick return if possible
*
      IF( n.LE.0 ) THEN
         result( 1 ) = zero
         result( 2 ) = zero
         RETURN
      END IF
*
      unfl = slamch( 'Safe minimum' )
      eps = slamch( 'Precision' )
      ovfl = one / unfl
      smlnum = unfl*n / eps
*
*     Test 1:  Compute norm( A - Q*H*Q' ) / ( norm(A) * N * EPS )
*
*     Copy A to WORK
*
      ldwork = max( 1, n )
      CALL clacpy( ' ', n, n, a, lda, work, ldwork )
*
*     Compute Q*H
*
      CALL cgemm( 'No transpose', 'No transpose', n, n, n, cmplx( one ),
     $            q, ldq, h, ldh, cmplx( zero ), work( ldwork*n+1 ),
     $            ldwork )
*
*     Compute A - Q*H*Q'
*
      CALL cgemm( 'No transpose', 'Conjugate transpose', n, n, n,
     $            cmplx( -one ), work( ldwork*n+1 ), ldwork, q, ldq,
     $            cmplx( one ), work, ldwork )
*
      anorm = max( clange( '1', n, n, a, lda, rwork ), unfl )
      wnorm = clange( '1', n, n, work, ldwork, rwork )
*
*     Note that RESULT(1) cannot overflow and is bounded by 1/(N*EPS)
*
      result( 1 ) = min( wnorm, anorm ) / max( smlnum, anorm*eps ) / n
*
*     Test 2:  Compute norm( I - Q'*Q ) / ( N * EPS )
*
      CALL cunt01( 'Columns', n, n, q, ldq, work, lwork, rwork,
     $             result( 2 ) )
*
      RETURN
*
*     End of CHST01
*

Here is the call graph for this function:

Here is the caller graph for this function: