zlaic1()

subroutine zlaic1	(	integer	job,
		integer	j,
		complex*16, dimension( j )	x,
		double precision	sest,
		complex*16, dimension( j )	w,
		complex*16	gamma,
		double precision	sestpr,
		complex*16	s,
		complex*16	c )

ZLAIC1 applies one step of incremental condition estimation.

Download ZLAIC1 + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> ZLAIC1 applies one step of incremental condition estimation in
!> its simplest version:
!>
!> Let x, twonorm(x) = 1, be an approximate singular vector of an j-by-j
!> lower triangular matrix L, such that
!>          twonorm(L*x) = sest
!> Then ZLAIC1 computes sestpr, s, c such that
!> the vector
!>                 [ s*x ]
!>          xhat = [  c  ]
!> is an approximate singular vector of
!>                 [ L       0  ]
!>          Lhat = [ w**H gamma ]
!> in the sense that
!>          twonorm(Lhat*xhat) = sestpr.
!>
!> Depending on JOB, an estimate for the largest or smallest singular
!> value is computed.
!>
!> Note that [s c]**H and sestpr**2 is an eigenpair of the system
!>
!>     diag(sest*sest, 0) + [alpha  gamma] * [ conjg(alpha) ]
!>                                           [ conjg(gamma) ]
!>
!> where  alpha =  x**H * w.
!> 

Parameters

[in]	JOB	!> JOB is INTEGER !> = 1: an estimate for the largest singular value is computed. !> = 2: an estimate for the smallest singular value is computed. !>
[in]	J	!> J is INTEGER !> Length of X and W !>
[in]	X	!> X is COMPLEX*16 array, dimension (J) !> The j-vector x. !>
[in]	SEST	!> SEST is DOUBLE PRECISION !> Estimated singular value of j by j matrix L !>
[in]	W	!> W is COMPLEX*16 array, dimension (J) !> The j-vector w. !>
[in]	GAMMA	!> GAMMA is COMPLEX*16 !> The diagonal element gamma. !>
[out]	SESTPR	!> SESTPR is DOUBLE PRECISION !> Estimated singular value of (j+1) by (j+1) matrix Lhat. !>
[out]	S	!> S is COMPLEX*16 !> Sine needed in forming xhat. !>
[out]	C	!> C is COMPLEX*16 !> Cosine needed in forming xhat. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 132 of file zlaic1.f.

*
*  -- LAPACK auxiliary routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            J, JOB
      DOUBLE PRECISION   SEST, SESTPR
      COMPLEX*16         C, GAMMA, S
*     ..
*     .. Array Arguments ..
      COMPLEX*16         W( J ), X( J )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE, TWO
      parameter( zero = 0.0d0, one = 1.0d0, two = 2.0d0 )
      DOUBLE PRECISION   HALF, FOUR
      parameter( half = 0.5d0, four = 4.0d0 )
*     ..
*     .. Local Scalars ..
      DOUBLE PRECISION   ABSALP, ABSEST, ABSGAM, B, EPS, NORMA, S1, S2,
     $                   SCL, T, TEST, TMP, ZETA1, ZETA2
      COMPLEX*16         ALPHA, COSINE, SINE
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, dconjg, max, sqrt
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   DLAMCH
      COMPLEX*16         ZDOTC
      EXTERNAL           dlamch, zdotc
*     ..
*     .. Executable Statements ..
*
      eps = dlamch( 'Epsilon' )
      alpha = zdotc( j, x, 1, w, 1 )
*
      absalp = abs( alpha )
      absgam = abs( gamma )
      absest = abs( sest )
*
      IF( job.EQ.1 ) THEN
*
*        Estimating largest singular value
*
*        special cases
*
         IF( sest.EQ.zero ) THEN
            s1 = max( absgam, absalp )
            IF( s1.EQ.zero ) THEN
               s = zero
               c = one
               sestpr = zero
            ELSE
               s = alpha / s1
               c = gamma / s1
               tmp = dble( sqrt( s*dconjg( s )+c*dconjg( c ) ) )
               s = s / tmp
               c = c / tmp
               sestpr = s1*tmp
            END IF
            RETURN
         ELSE IF( absgam.LE.eps*absest ) THEN
            s = one
            c = zero
            tmp = max( absest, absalp )
            s1 = absest / tmp
            s2 = absalp / tmp
            sestpr = tmp*sqrt( s1*s1+s2*s2 )
            RETURN
         ELSE IF( absalp.LE.eps*absest ) THEN
            s1 = absgam
            s2 = absest
            IF( s1.LE.s2 ) THEN
               s = one
               c = zero
               sestpr = s2
            ELSE
               s = zero
               c = one
               sestpr = s1
            END IF
            RETURN
         ELSE IF( absest.LE.eps*absalp .OR. absest.LE.eps*absgam ) THEN
            s1 = absgam
            s2 = absalp
            IF( s1.LE.s2 ) THEN
               tmp = s1 / s2
               scl = sqrt( one+tmp*tmp )
               sestpr = s2*scl
               s = ( alpha / s2 ) / scl
               c = ( gamma / s2 ) / scl
            ELSE
               tmp = s2 / s1
               scl = sqrt( one+tmp*tmp )
               sestpr = s1*scl
               s = ( alpha / s1 ) / scl
               c = ( gamma / s1 ) / scl
            END IF
            RETURN
         ELSE
*
*           normal case
*
            zeta1 = absalp / absest
            zeta2 = absgam / absest
*
            b = ( one-zeta1*zeta1-zeta2*zeta2 )*half
            c = zeta1*zeta1
            IF( b.GT.zero ) THEN
               t = dble( c / ( b+sqrt( b*b+c ) ) )
            ELSE
               t = dble( sqrt( b*b+c ) - b )
            END IF
*
            sine = -( alpha / absest ) / t
            cosine = -( gamma / absest ) / ( one+t )
            tmp = dble( sqrt( sine * dconjg( sine )
     $        + cosine * dconjg( cosine ) ) )
 
            s = sine / tmp
            c = cosine / tmp
            sestpr = sqrt( t+one )*absest
            RETURN
         END IF
*
      ELSE IF( job.EQ.2 ) THEN
*
*        Estimating smallest singular value
*
*        special cases
*
         IF( sest.EQ.zero ) THEN
            sestpr = zero
            IF( max( absgam, absalp ).EQ.zero ) THEN
               sine = one
               cosine = zero
            ELSE
               sine = -dconjg( gamma )
               cosine = dconjg( alpha )
            END IF
            s1 = max( abs( sine ), abs( cosine ) )
            s = sine / s1
            c = cosine / s1
            tmp = dble( sqrt( s*dconjg( s )+c*dconjg( c ) ) )
            s = s / tmp
            c = c / tmp
            RETURN
         ELSE IF( absgam.LE.eps*absest ) THEN
            s = zero
            c = one
            sestpr = absgam
            RETURN
         ELSE IF( absalp.LE.eps*absest ) THEN
            s1 = absgam
            s2 = absest
            IF( s1.LE.s2 ) THEN
               s = zero
               c = one
               sestpr = s1
            ELSE
               s = one
               c = zero
               sestpr = s2
            END IF
            RETURN
         ELSE IF( absest.LE.eps*absalp .OR. absest.LE.eps*absgam ) THEN
            s1 = absgam
            s2 = absalp
            IF( s1.LE.s2 ) THEN
               tmp = s1 / s2
               scl = sqrt( one+tmp*tmp )
               sestpr = absest*( tmp / scl )
               s = -( dconjg( gamma ) / s2 ) / scl
               c = ( dconjg( alpha ) / s2 ) / scl
            ELSE
               tmp = s2 / s1
               scl = sqrt( one+tmp*tmp )
               sestpr = absest / scl
               s = -( dconjg( gamma ) / s1 ) / scl
               c = ( dconjg( alpha ) / s1 ) / scl
            END IF
            RETURN
         ELSE
*
*           normal case
*
            zeta1 = absalp / absest
            zeta2 = absgam / absest
*
            norma = max( one+zeta1*zeta1+zeta1*zeta2,
     $              zeta1*zeta2+zeta2*zeta2 )
*
*           See if root is closer to zero or to ONE
*
            test = one + two*( zeta1-zeta2 )*( zeta1+zeta2 )
            IF( test.GE.zero ) THEN
*
*              root is close to zero, compute directly
*
               b = ( zeta1*zeta1+zeta2*zeta2+one )*half
               c = zeta2*zeta2
               t = dble( c / ( b+sqrt( abs( b*b-c ) ) ) )
               sine = ( alpha / absest ) / ( one-t )
               cosine = -( gamma / absest ) / t
               sestpr = sqrt( t+four*eps*eps*norma )*absest
            ELSE
*
*              root is closer to ONE, shift by that amount
*
               b = ( zeta2*zeta2+zeta1*zeta1-one )*half
               c = zeta1*zeta1
               IF( b.GE.zero ) THEN
                  t = dble( -c / ( b+sqrt( b*b+c ) ) )
               ELSE
                  t = dble( b - sqrt( b*b+c ) )
               END IF
               sine = -( alpha / absest ) / t
               cosine = -( gamma / absest ) / ( one+t )
               sestpr = sqrt( one+t+four*eps*eps*norma )*absest
            END IF
            tmp = dble( sqrt( sine * dconjg( sine )
     $        + cosine * dconjg( cosine ) ) )
            s = sine / tmp
            c = cosine / tmp
            RETURN
*
         END IF
      END IF
      RETURN
*
*     End of ZLAIC1
*

Here is the caller graph for this function: