dsxt1()

double precision function dsxt1	(	integer	ijob,
		double precision, dimension( * )	d1,
		integer	n1,
		double precision, dimension( * )	d2,
		integer	n2,
		double precision	abstol,
		double precision	ulp,
		double precision	unfl
	)

DSXT1

Purpose:

 DSXT1  computes the difference between a set of eigenvalues.
 The result is returned as the function value.

 IJOB = 1:   Computes   max { min | D1(i)-D2(j) | }
                         i     j

 IJOB = 2:   Computes   max { min | D1(i)-D2(j) | /
                         i     j
                              ( ABSTOL + |D1(i)|*ULP ) }

Parameters

[in]	IJOB	IJOB is INTEGER Specifies the type of tests to be performed. (See above.)
[in]	D1	D1 is DOUBLE PRECISION array, dimension (N1) The first array. D1 should be in increasing order, i.e., D1(j) <= D1(j+1).
[in]	N1	N1 is INTEGER The length of D1.
[in]	D2	D2 is DOUBLE PRECISION array, dimension (N2) The second array. D2 should be in increasing order, i.e., D2(j) <= D2(j+1).
[in]	N2	N2 is INTEGER The length of D2.
[in]	ABSTOL	ABSTOL is DOUBLE PRECISION The absolute tolerance, used as a measure of the error.
[in]	ULP	ULP is DOUBLE PRECISION Machine precision.
[in]	UNFL	UNFL is DOUBLE PRECISION The smallest positive number whose reciprocal does not overflow.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 104 of file dsxt1.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            IJOB, N1, N2
      DOUBLE PRECISION   ABSTOL, ULP, UNFL
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   D1( * ), D2( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO
      parameter( zero = 0.0d0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, J
      DOUBLE PRECISION   TEMP1, TEMP2
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, max, min
*     ..
*     .. Executable Statements ..
*
      temp1 = zero
*
      j = 1
      DO 20 i = 1, n1
   10    CONTINUE
         IF( d2( j ).LT.d1( i ) .AND. j.LT.n2 ) THEN
            j = j + 1
            GO TO 10
         END IF
         IF( j.EQ.1 ) THEN
            temp2 = abs( d2( j )-d1( i ) )
            IF( ijob.EQ.2 )
     $         temp2 = temp2 / max( unfl, abstol+ulp*abs( d1( i ) ) )
         ELSE
            temp2 = min( abs( d2( j )-d1( i ) ),
     $              abs( d1( i )-d2( j-1 ) ) )
            IF( ijob.EQ.2 )
     $         temp2 = temp2 / max( unfl, abstol+ulp*abs( d1( i ) ) )
         END IF
         temp1 = max( temp1, temp2 )
   20 CONTINUE
*
      dsxt1 = temp1
      RETURN
*
*     End of DSXT1
*

Here is the call graph for this function:

Here is the caller graph for this function: