sget03()

subroutine sget03	(	integer	n,
		real, dimension( lda, * )	a,
		integer	lda,
		real, dimension( ldainv, * )	ainv,
		integer	ldainv,
		real, dimension( ldwork, * )	work,
		integer	ldwork,
		real, dimension( * )	rwork,
		real	rcond,
		real	resid )

SGET03

Purpose:

!>
!> SGET03 computes the residual for a general matrix times its inverse:
!>    norm( I - AINV*A ) / ( N * norm(A) * norm(AINV) * EPS ),
!> where EPS is the machine epsilon.
!> 

Parameters

[in]	N	!> N is INTEGER !> The number of rows and columns of the matrix A. N >= 0. !>
[in]	A	!> A is REAL array, dimension (LDA,N) !> The original N x N matrix A. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= max(1,N). !>
[in]	AINV	!> AINV is REAL array, dimension (LDAINV,N) !> The inverse of the matrix A. !>
[in]	LDAINV	!> LDAINV is INTEGER !> The leading dimension of the array AINV. LDAINV >= max(1,N). !>
[out]	WORK	!> WORK is REAL array, dimension (LDWORK,N) !>
[in]	LDWORK	!> LDWORK is INTEGER !> The leading dimension of the array WORK. LDWORK >= max(1,N). !>
[out]	RWORK	!> RWORK is REAL array, dimension (N) !>
[out]	RCOND	!> RCOND is REAL !> The reciprocal of the condition number of A, computed as !> ( 1/norm(A) ) / norm(AINV). !>
[out]	RESID	!> RESID is REAL !> norm(I - AINV*A) / ( N * norm(A) * norm(AINV) * EPS ) !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 107 of file sget03.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            LDA, LDAINV, LDWORK, N
      REAL               RCOND, RESID
*     ..
*     .. Array Arguments ..
      REAL               A( LDA, * ), AINV( LDAINV, * ), RWORK( * ),
     $                   WORK( LDWORK, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE
      parameter( zero = 0.0e+0, one = 1.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I
      REAL               AINVNM, ANORM, EPS
*     ..
*     .. External Functions ..
      REAL               SLAMCH, SLANGE
      EXTERNAL           slamch, slange
*     ..
*     .. External Subroutines ..
      EXTERNAL           sgemm
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          real
*     ..
*     .. Executable Statements ..
*
*     Quick exit if N = 0.
*
      IF( n.LE.0 ) THEN
         rcond = one
         resid = zero
         RETURN
      END IF
*
*     Exit with RESID = 1/EPS if ANORM = 0 or AINVNM = 0.
*
      eps = slamch( 'Epsilon' )
      anorm = slange( '1', n, n, a, lda, rwork )
      ainvnm = slange( '1', n, n, ainv, ldainv, rwork )
      IF( anorm.LE.zero .OR. ainvnm.LE.zero ) THEN
         rcond = zero
         resid = one / eps
         RETURN
      END IF
      rcond = ( one / anorm ) / ainvnm
*
*     Compute I - A * AINV
*
      CALL sgemm( 'No transpose', 'No transpose', n, n, n, -one,
     $     ainv, ldainv, a, lda, zero, work, ldwork )
      DO 10 i = 1, n
         work( i, i ) = one + work( i, i )
   10 CONTINUE
*
*     Compute norm(I - AINV*A) / (N * norm(A) * norm(AINV) * EPS)
*
      resid = slange( '1', n, n, work, ldwork, rwork )
*
      resid = ( ( resid*rcond ) / eps ) / real( n )
*
      RETURN
*
*     End of SGET03
*

Here is the call graph for this function:

Here is the caller graph for this function: