cptt05()

subroutine cptt05	(	integer	n,
		integer	nrhs,
		real, dimension( * )	d,
		complex, dimension( * )	e,
		complex, dimension( ldb, * )	b,
		integer	ldb,
		complex, dimension( ldx, * )	x,
		integer	ldx,
		complex, dimension( ldxact, * )	xact,
		integer	ldxact,
		real, dimension( * )	ferr,
		real, dimension( * )	berr,
		real, dimension( * )	reslts )

CPTT05

Purpose:

!>
!> CPTT05 tests the error bounds from iterative refinement for the
!> computed solution to a system of equations A*X = B, where A is a
!> Hermitian tridiagonal matrix of order n.
!>
!> RESLTS(1) = test of the error bound
!>           = norm(X - XACT) / ( norm(X) * FERR )
!>
!> A large value is returned if this ratio is not less than one.
!>
!> RESLTS(2) = residual from the iterative refinement routine
!>           = the maximum of BERR / ( NZ*EPS + (*) ), where
!>             (*) = NZ*UNFL / (min_i (abs(A)*abs(X) +abs(b))_i )
!>             and NZ = max. number of nonzeros in any row of A, plus 1
!> 

Parameters

[in]	N	!> N is INTEGER !> The number of rows of the matrices X, B, and XACT, and the !> order of the matrix A. N >= 0. !>
[in]	NRHS	!> NRHS is INTEGER !> The number of columns of the matrices X, B, and XACT. !> NRHS >= 0. !>
[in]	D	!> D is REAL array, dimension (N) !> The n diagonal elements of the tridiagonal matrix A. !>
[in]	E	!> E is COMPLEX array, dimension (N-1) !> The (n-1) subdiagonal elements of the tridiagonal matrix A. !>
[in]	B	!> B is COMPLEX array, dimension (LDB,NRHS) !> The right hand side vectors for the system of linear !> equations. !>
[in]	LDB	!> LDB is INTEGER !> The leading dimension of the array B. LDB >= max(1,N). !>
[in]	X	!> X is COMPLEX array, dimension (LDX,NRHS) !> The computed solution vectors. Each vector is stored as a !> column of the matrix X. !>
[in]	LDX	!> LDX is INTEGER !> The leading dimension of the array X. LDX >= max(1,N). !>
[in]	XACT	!> XACT is COMPLEX array, dimension (LDX,NRHS) !> The exact solution vectors. Each vector is stored as a !> column of the matrix XACT. !>
[in]	LDXACT	!> LDXACT is INTEGER !> The leading dimension of the array XACT. LDXACT >= max(1,N). !>
[in]	FERR	!> FERR is REAL array, dimension (NRHS) !> The estimated forward error bounds for each solution vector !> X. If XTRUE is the true solution, FERR bounds the magnitude !> of the largest entry in (X - XTRUE) divided by the magnitude !> of the largest entry in X. !>
[in]	BERR	!> BERR is REAL array, dimension (NRHS) !> The componentwise relative backward error of each solution !> vector (i.e., the smallest relative change in any entry of A !> or B that makes X an exact solution). !>
[out]	RESLTS	!> RESLTS is REAL array, dimension (2) !> The maximum over the NRHS solution vectors of the ratios: !> RESLTS(1) = norm(X - XACT) / ( norm(X) * FERR ) !> RESLTS(2) = BERR / ( NZ*EPS + (*) ) !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 148 of file cptt05.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            LDB, LDX, LDXACT, N, NRHS
*     ..
*     .. Array Arguments ..
      REAL               BERR( * ), D( * ), FERR( * ), RESLTS( * )
      COMPLEX            B( LDB, * ), E( * ), X( LDX, * ),
     $                   XACT( LDXACT, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE
      parameter( zero = 0.0e+0, one = 1.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, IMAX, J, K, NZ
      REAL               AXBI, DIFF, EPS, ERRBND, OVFL, TMP, UNFL, XNORM
      COMPLEX            ZDUM
*     ..
*     .. External Functions ..
      INTEGER            ICAMAX
      REAL               SLAMCH
      EXTERNAL           icamax, slamch
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, aimag, max, min, real
*     ..
*     .. Statement Functions ..
      REAL               CABS1
*     ..
*     .. Statement Function definitions ..
      cabs1( zdum ) = abs( real( zdum ) ) + abs( aimag( zdum ) )
*     ..
*     .. Executable Statements ..
*
*     Quick exit if N = 0 or NRHS = 0.
*
      IF( n.LE.0 .OR. nrhs.LE.0 ) THEN
         reslts( 1 ) = zero
         reslts( 2 ) = zero
         RETURN
      END IF
*
      eps = slamch( 'Epsilon' )
      unfl = slamch( 'Safe minimum' )
      ovfl = one / unfl
      nz = 4
*
*     Test 1:  Compute the maximum of
*        norm(X - XACT) / ( norm(X) * FERR )
*     over all the vectors X and XACT using the infinity-norm.
*
      errbnd = zero
      DO 30 j = 1, nrhs
         imax = icamax( n, x( 1, j ), 1 )
         xnorm = max( cabs1( x( imax, j ) ), unfl )
         diff = zero
         DO 10 i = 1, n
            diff = max( diff, cabs1( x( i, j )-xact( i, j ) ) )
   10    CONTINUE
*
         IF( xnorm.GT.one ) THEN
            GO TO 20
         ELSE IF( diff.LE.ovfl*xnorm ) THEN
            GO TO 20
         ELSE
            errbnd = one / eps
            GO TO 30
         END IF
*
   20    CONTINUE
         IF( diff / xnorm.LE.ferr( j ) ) THEN
            errbnd = max( errbnd, ( diff / xnorm ) / ferr( j ) )
         ELSE
            errbnd = one / eps
         END IF
   30 CONTINUE
      reslts( 1 ) = errbnd
*
*     Test 2:  Compute the maximum of BERR / ( NZ*EPS + (*) ), where
*     (*) = NZ*UNFL / (min_i (abs(A)*abs(X) +abs(b))_i )
*
      DO 50 k = 1, nrhs
         IF( n.EQ.1 ) THEN
            axbi = cabs1( b( 1, k ) ) + cabs1( d( 1 )*x( 1, k ) )
         ELSE
            axbi = cabs1( b( 1, k ) ) + cabs1( d( 1 )*x( 1, k ) ) +
     $             cabs1( e( 1 ) )*cabs1( x( 2, k ) )
            DO 40 i = 2, n - 1
               tmp = cabs1( b( i, k ) ) + cabs1( e( i-1 ) )*
     $               cabs1( x( i-1, k ) ) + cabs1( d( i )*x( i, k ) ) +
     $               cabs1( e( i ) )*cabs1( x( i+1, k ) )
               axbi = min( axbi, tmp )
   40       CONTINUE
            tmp = cabs1( b( n, k ) ) + cabs1( e( n-1 ) )*
     $            cabs1( x( n-1, k ) ) + cabs1( d( n )*x( n, k ) )
            axbi = min( axbi, tmp )
         END IF
         tmp = berr( k ) / ( nz*eps+nz*unfl / max( axbi, nz*unfl ) )
         IF( k.EQ.1 ) THEN
            reslts( 2 ) = tmp
         ELSE
            reslts( 2 ) = max( reslts( 2 ), tmp )
         END IF
   50 CONTINUE
*
      RETURN
*
*     End of CPTT05
*

Here is the caller graph for this function: