 LAPACK 3.11.0 LAPACK: Linear Algebra PACKage
Searching...
No Matches

## ◆ slaed7()

 subroutine slaed7 ( integer ICOMPQ, integer N, integer QSIZ, integer TLVLS, integer CURLVL, integer CURPBM, real, dimension( * ) D, real, dimension( ldq, * ) Q, integer LDQ, integer, dimension( * ) INDXQ, real RHO, integer CUTPNT, real, dimension( * ) QSTORE, integer, dimension( * ) QPTR, integer, dimension( * ) PRMPTR, integer, dimension( * ) PERM, integer, dimension( * ) GIVPTR, integer, dimension( 2, * ) GIVCOL, real, dimension( 2, * ) GIVNUM, real, dimension( * ) WORK, integer, dimension( * ) IWORK, integer INFO )

SLAED7 used by SSTEDC. Computes the updated eigensystem of a diagonal matrix after modification by a rank-one symmetric matrix. Used when the original matrix is dense.

Purpose:
``` SLAED7 computes the updated eigensystem of a diagonal
matrix after modification by a rank-one symmetric matrix. This
routine is used only for the eigenproblem which requires all
eigenvalues and optionally eigenvectors of a dense symmetric matrix
that has been reduced to tridiagonal form.  SLAED1 handles
the case in which all eigenvalues and eigenvectors of a symmetric
tridiagonal matrix are desired.

T = Q(in) ( D(in) + RHO * Z*Z**T ) Q**T(in) = Q(out) * D(out) * Q**T(out)

where Z = Q**Tu, u is a vector of length N with ones in the
CUTPNT and CUTPNT + 1 th elements and zeros elsewhere.

The eigenvectors of the original matrix are stored in Q, and the
eigenvalues are in D.  The algorithm consists of three stages:

The first stage consists of deflating the size of the problem
when there are multiple eigenvalues or if there is a zero in
the Z vector.  For each such occurrence the dimension of the
secular equation problem is reduced by one.  This stage is
performed by the routine SLAED8.

The second stage consists of calculating the updated
eigenvalues. This is done by finding the roots of the secular
equation via the routine SLAED4 (as called by SLAED9).
This routine also calculates the eigenvectors of the current
problem.

The final stage consists of computing the updated eigenvectors
directly using the updated eigenvalues.  The eigenvectors for
the current problem are multiplied with the eigenvectors from
the overall problem.```
Parameters
 [in] ICOMPQ ``` ICOMPQ is INTEGER = 0: Compute eigenvalues only. = 1: Compute eigenvectors of original dense symmetric matrix also. On entry, Q contains the orthogonal matrix used to reduce the original matrix to tridiagonal form.``` [in] N ``` N is INTEGER The dimension of the symmetric tridiagonal matrix. N >= 0.``` [in] QSIZ ``` QSIZ is INTEGER The dimension of the orthogonal matrix used to reduce the full matrix to tridiagonal form. QSIZ >= N if ICOMPQ = 1.``` [in] TLVLS ``` TLVLS is INTEGER The total number of merging levels in the overall divide and conquer tree.``` [in] CURLVL ``` CURLVL is INTEGER The current level in the overall merge routine, 0 <= CURLVL <= TLVLS.``` [in] CURPBM ``` CURPBM is INTEGER The current problem in the current level in the overall merge routine (counting from upper left to lower right).``` [in,out] D ``` D is REAL array, dimension (N) On entry, the eigenvalues of the rank-1-perturbed matrix. On exit, the eigenvalues of the repaired matrix.``` [in,out] Q ``` Q is REAL array, dimension (LDQ, N) On entry, the eigenvectors of the rank-1-perturbed matrix. On exit, the eigenvectors of the repaired tridiagonal matrix.``` [in] LDQ ``` LDQ is INTEGER The leading dimension of the array Q. LDQ >= max(1,N).``` [out] INDXQ ``` INDXQ is INTEGER array, dimension (N) The permutation which will reintegrate the subproblem just solved back into sorted order, i.e., D( INDXQ( I = 1, N ) ) will be in ascending order.``` [in] RHO ``` RHO is REAL The subdiagonal element used to create the rank-1 modification.``` [in] CUTPNT ``` CUTPNT is INTEGER Contains the location of the last eigenvalue in the leading sub-matrix. min(1,N) <= CUTPNT <= N.``` [in,out] QSTORE ``` QSTORE is REAL array, dimension (N**2+1) Stores eigenvectors of submatrices encountered during divide and conquer, packed together. QPTR points to beginning of the submatrices.``` [in,out] QPTR ``` QPTR is INTEGER array, dimension (N+2) List of indices pointing to beginning of submatrices stored in QSTORE. The submatrices are numbered starting at the bottom left of the divide and conquer tree, from left to right and bottom to top.``` [in] PRMPTR ``` PRMPTR is INTEGER array, dimension (N lg N) Contains a list of pointers which indicate where in PERM a level's permutation is stored. PRMPTR(i+1) - PRMPTR(i) indicates the size of the permutation and also the size of the full, non-deflated problem.``` [in] PERM ``` PERM is INTEGER array, dimension (N lg N) Contains the permutations (from deflation and sorting) to be applied to each eigenblock.``` [in] GIVPTR ``` GIVPTR is INTEGER array, dimension (N lg N) Contains a list of pointers which indicate where in GIVCOL a level's Givens rotations are stored. GIVPTR(i+1) - GIVPTR(i) indicates the number of Givens rotations.``` [in] GIVCOL ``` GIVCOL is INTEGER array, dimension (2, N lg N) Each pair of numbers indicates a pair of columns to take place in a Givens rotation.``` [in] GIVNUM ``` GIVNUM is REAL array, dimension (2, N lg N) Each number indicates the S value to be used in the corresponding Givens rotation.``` [out] WORK ` WORK is REAL array, dimension (3*N+2*QSIZ*N)` [out] IWORK ` IWORK is INTEGER array, dimension (4*N)` [out] INFO ``` INFO is INTEGER = 0: successful exit. < 0: if INFO = -i, the i-th argument had an illegal value. > 0: if INFO = 1, an eigenvalue did not converge```
Contributors:
Jeff Rutter, Computer Science Division, University of California at Berkeley, USA

Definition at line 256 of file slaed7.f.

260*
261* -- LAPACK computational routine --
262* -- LAPACK is a software package provided by Univ. of Tennessee, --
263* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
264*
265* .. Scalar Arguments ..
266 INTEGER CURLVL, CURPBM, CUTPNT, ICOMPQ, INFO, LDQ, N,
267 \$ QSIZ, TLVLS
268 REAL RHO
269* ..
270* .. Array Arguments ..
271 INTEGER GIVCOL( 2, * ), GIVPTR( * ), INDXQ( * ),
272 \$ IWORK( * ), PERM( * ), PRMPTR( * ), QPTR( * )
273 REAL D( * ), GIVNUM( 2, * ), Q( LDQ, * ),
274 \$ QSTORE( * ), WORK( * )
275* ..
276*
277* =====================================================================
278*
279* .. Parameters ..
280 REAL ONE, ZERO
281 parameter( one = 1.0e0, zero = 0.0e0 )
282* ..
283* .. Local Scalars ..
284 INTEGER COLTYP, CURR, I, IDLMDA, INDX, INDXC, INDXP,
285 \$ IQ2, IS, IW, IZ, K, LDQ2, N1, N2, PTR
286* ..
287* .. External Subroutines ..
288 EXTERNAL sgemm, slaed8, slaed9, slaeda, slamrg, xerbla
289* ..
290* .. Intrinsic Functions ..
291 INTRINSIC max, min
292* ..
293* .. Executable Statements ..
294*
295* Test the input parameters.
296*
297 info = 0
298*
299 IF( icompq.LT.0 .OR. icompq.GT.1 ) THEN
300 info = -1
301 ELSE IF( n.LT.0 ) THEN
302 info = -2
303 ELSE IF( icompq.EQ.1 .AND. qsiz.LT.n ) THEN
304 info = -3
305 ELSE IF( ldq.LT.max( 1, n ) ) THEN
306 info = -9
307 ELSE IF( min( 1, n ).GT.cutpnt .OR. n.LT.cutpnt ) THEN
308 info = -12
309 END IF
310 IF( info.NE.0 ) THEN
311 CALL xerbla( 'SLAED7', -info )
312 RETURN
313 END IF
314*
315* Quick return if possible
316*
317 IF( n.EQ.0 )
318 \$ RETURN
319*
320* The following values are for bookkeeping purposes only. They are
321* integer pointers which indicate the portion of the workspace
322* used by a particular array in SLAED8 and SLAED9.
323*
324 IF( icompq.EQ.1 ) THEN
325 ldq2 = qsiz
326 ELSE
327 ldq2 = n
328 END IF
329*
330 iz = 1
331 idlmda = iz + n
332 iw = idlmda + n
333 iq2 = iw + n
334 is = iq2 + n*ldq2
335*
336 indx = 1
337 indxc = indx + n
338 coltyp = indxc + n
339 indxp = coltyp + n
340*
341* Form the z-vector which consists of the last row of Q_1 and the
342* first row of Q_2.
343*
344 ptr = 1 + 2**tlvls
345 DO 10 i = 1, curlvl - 1
346 ptr = ptr + 2**( tlvls-i )
347 10 CONTINUE
348 curr = ptr + curpbm
349 CALL slaeda( n, tlvls, curlvl, curpbm, prmptr, perm, givptr,
350 \$ givcol, givnum, qstore, qptr, work( iz ),
351 \$ work( iz+n ), info )
352*
353* When solving the final problem, we no longer need the stored data,
354* so we will overwrite the data from this level onto the previously
355* used storage space.
356*
357 IF( curlvl.EQ.tlvls ) THEN
358 qptr( curr ) = 1
359 prmptr( curr ) = 1
360 givptr( curr ) = 1
361 END IF
362*
363* Sort and Deflate eigenvalues.
364*
365 CALL slaed8( icompq, k, n, qsiz, d, q, ldq, indxq, rho, cutpnt,
366 \$ work( iz ), work( idlmda ), work( iq2 ), ldq2,
367 \$ work( iw ), perm( prmptr( curr ) ), givptr( curr+1 ),
368 \$ givcol( 1, givptr( curr ) ),
369 \$ givnum( 1, givptr( curr ) ), iwork( indxp ),
370 \$ iwork( indx ), info )
371 prmptr( curr+1 ) = prmptr( curr ) + n
372 givptr( curr+1 ) = givptr( curr+1 ) + givptr( curr )
373*
374* Solve Secular Equation.
375*
376 IF( k.NE.0 ) THEN
377 CALL slaed9( k, 1, k, n, d, work( is ), k, rho, work( idlmda ),
378 \$ work( iw ), qstore( qptr( curr ) ), k, info )
379 IF( info.NE.0 )
380 \$ GO TO 30
381 IF( icompq.EQ.1 ) THEN
382 CALL sgemm( 'N', 'N', qsiz, k, k, one, work( iq2 ), ldq2,
383 \$ qstore( qptr( curr ) ), k, zero, q, ldq )
384 END IF
385 qptr( curr+1 ) = qptr( curr ) + k**2
386*
387* Prepare the INDXQ sorting permutation.
388*
389 n1 = k
390 n2 = n - k
391 CALL slamrg( n1, n2, d, 1, -1, indxq )
392 ELSE
393 qptr( curr+1 ) = qptr( curr )
394 DO 20 i = 1, n
395 indxq( i ) = i
396 20 CONTINUE
397 END IF
398*
399 30 CONTINUE
400 RETURN
401*
402* End of SLAED7
403*
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
subroutine slamrg(N1, N2, A, STRD1, STRD2, INDEX)
SLAMRG creates a permutation list to merge the entries of two independently sorted sets into a single...
Definition: slamrg.f:99
subroutine slaed8(ICOMPQ, K, N, QSIZ, D, Q, LDQ, INDXQ, RHO, CUTPNT, Z, DLAMDA, Q2, LDQ2, W, PERM, GIVPTR, GIVCOL, GIVNUM, INDXP, INDX, INFO)
SLAED8 used by SSTEDC. Merges eigenvalues and deflates secular equation. Used when the original matri...
Definition: slaed8.f:243
subroutine slaed9(K, KSTART, KSTOP, N, D, Q, LDQ, RHO, DLAMDA, W, S, LDS, INFO)
SLAED9 used by SSTEDC. Finds the roots of the secular equation and updates the eigenvectors....
Definition: slaed9.f:156
subroutine slaeda(N, TLVLS, CURLVL, CURPBM, PRMPTR, PERM, GIVPTR, GIVCOL, GIVNUM, Q, QPTR, Z, ZTEMP, INFO)
SLAEDA used by SSTEDC. Computes the Z vector determining the rank-one modification of the diagonal ma...
Definition: slaeda.f:166
subroutine sgemm(TRANSA, TRANSB, M, N, K, ALPHA, A, LDA, B, LDB, BETA, C, LDC)
SGEMM
Definition: sgemm.f:187
Here is the call graph for this function:
Here is the caller graph for this function: