LAPACK 3.11.0 LAPACK: Linear Algebra PACKage
Searching...
No Matches

## ◆ dlaed1()

 subroutine dlaed1 ( integer N, double precision, dimension( * ) D, double precision, dimension( ldq, * ) Q, integer LDQ, integer, dimension( * ) INDXQ, double precision RHO, integer CUTPNT, double precision, dimension( * ) WORK, integer, dimension( * ) IWORK, integer INFO )

DLAED1 used by DSTEDC. Computes the updated eigensystem of a diagonal matrix after modification by a rank-one symmetric matrix. Used when the original matrix is tridiagonal.

Download DLAED1 + dependencies [TGZ] [ZIP] [TXT]

Purpose:
``` DLAED1 computes the updated eigensystem of a diagonal
matrix after modification by a rank-one symmetric matrix.  This
routine is used only for the eigenproblem which requires all
eigenvalues and eigenvectors of a tridiagonal matrix.  DLAED7 handles
the case in which eigenvalues only or eigenvalues and eigenvectors
of a full symmetric matrix (which was reduced to tridiagonal form)
are desired.

T = Q(in) ( D(in) + RHO * Z*Z**T ) Q**T(in) = Q(out) * D(out) * Q**T(out)

where Z = Q**T*u, u is a vector of length N with ones in the
CUTPNT and CUTPNT + 1 th elements and zeros elsewhere.

The eigenvectors of the original matrix are stored in Q, and the
eigenvalues are in D.  The algorithm consists of three stages:

The first stage consists of deflating the size of the problem
when there are multiple eigenvalues or if there is a zero in
the Z vector.  For each such occurrence the dimension of the
secular equation problem is reduced by one.  This stage is
performed by the routine DLAED2.

The second stage consists of calculating the updated
eigenvalues. This is done by finding the roots of the secular
equation via the routine DLAED4 (as called by DLAED3).
This routine also calculates the eigenvectors of the current
problem.

The final stage consists of computing the updated eigenvectors
directly using the updated eigenvalues.  The eigenvectors for
the current problem are multiplied with the eigenvectors from
the overall problem.```
Parameters
 [in] N ``` N is INTEGER The dimension of the symmetric tridiagonal matrix. N >= 0.``` [in,out] D ``` D is DOUBLE PRECISION array, dimension (N) On entry, the eigenvalues of the rank-1-perturbed matrix. On exit, the eigenvalues of the repaired matrix.``` [in,out] Q ``` Q is DOUBLE PRECISION array, dimension (LDQ,N) On entry, the eigenvectors of the rank-1-perturbed matrix. On exit, the eigenvectors of the repaired tridiagonal matrix.``` [in] LDQ ``` LDQ is INTEGER The leading dimension of the array Q. LDQ >= max(1,N).``` [in,out] INDXQ ``` INDXQ is INTEGER array, dimension (N) On entry, the permutation which separately sorts the two subproblems in D into ascending order. On exit, the permutation which will reintegrate the subproblems back into sorted order, i.e. D( INDXQ( I = 1, N ) ) will be in ascending order.``` [in] RHO ``` RHO is DOUBLE PRECISION The subdiagonal entry used to create the rank-1 modification.``` [in] CUTPNT ``` CUTPNT is INTEGER The location of the last eigenvalue in the leading sub-matrix. min(1,N) <= CUTPNT <= N/2.``` [out] WORK ` WORK is DOUBLE PRECISION array, dimension (4*N + N**2)` [out] IWORK ` IWORK is INTEGER array, dimension (4*N)` [out] INFO ``` INFO is INTEGER = 0: successful exit. < 0: if INFO = -i, the i-th argument had an illegal value. > 0: if INFO = 1, an eigenvalue did not converge```
Contributors:
Jeff Rutter, Computer Science Division, University of California at Berkeley, USA
Modified by Francoise Tisseur, University of Tennessee

Definition at line 161 of file dlaed1.f.

163*
164* -- LAPACK computational routine --
165* -- LAPACK is a software package provided by Univ. of Tennessee, --
166* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
167*
168* .. Scalar Arguments ..
169 INTEGER CUTPNT, INFO, LDQ, N
170 DOUBLE PRECISION RHO
171* ..
172* .. Array Arguments ..
173 INTEGER INDXQ( * ), IWORK( * )
174 DOUBLE PRECISION D( * ), Q( LDQ, * ), WORK( * )
175* ..
176*
177* =====================================================================
178*
179* .. Local Scalars ..
180 INTEGER COLTYP, I, IDLMDA, INDX, INDXC, INDXP, IQ2, IS,
181 \$ IW, IZ, K, N1, N2, ZPP1
182* ..
183* .. External Subroutines ..
184 EXTERNAL dcopy, dlaed2, dlaed3, dlamrg, xerbla
185* ..
186* .. Intrinsic Functions ..
187 INTRINSIC max, min
188* ..
189* .. Executable Statements ..
190*
191* Test the input parameters.
192*
193 info = 0
194*
195 IF( n.LT.0 ) THEN
196 info = -1
197 ELSE IF( ldq.LT.max( 1, n ) ) THEN
198 info = -4
199 ELSE IF( min( 1, n / 2 ).GT.cutpnt .OR. ( n / 2 ).LT.cutpnt ) THEN
200 info = -7
201 END IF
202 IF( info.NE.0 ) THEN
203 CALL xerbla( 'DLAED1', -info )
204 RETURN
205 END IF
206*
207* Quick return if possible
208*
209 IF( n.EQ.0 )
210 \$ RETURN
211*
212* The following values are integer pointers which indicate
213* the portion of the workspace
214* used by a particular array in DLAED2 and DLAED3.
215*
216 iz = 1
217 idlmda = iz + n
218 iw = idlmda + n
219 iq2 = iw + n
220*
221 indx = 1
222 indxc = indx + n
223 coltyp = indxc + n
224 indxp = coltyp + n
225*
226*
227* Form the z-vector which consists of the last row of Q_1 and the
228* first row of Q_2.
229*
230 CALL dcopy( cutpnt, q( cutpnt, 1 ), ldq, work( iz ), 1 )
231 zpp1 = cutpnt + 1
232 CALL dcopy( n-cutpnt, q( zpp1, zpp1 ), ldq, work( iz+cutpnt ), 1 )
233*
234* Deflate eigenvalues.
235*
236 CALL dlaed2( k, n, cutpnt, d, q, ldq, indxq, rho, work( iz ),
237 \$ work( idlmda ), work( iw ), work( iq2 ),
238 \$ iwork( indx ), iwork( indxc ), iwork( indxp ),
239 \$ iwork( coltyp ), info )
240*
241 IF( info.NE.0 )
242 \$ GO TO 20
243*
244* Solve Secular Equation.
245*
246 IF( k.NE.0 ) THEN
247 is = ( iwork( coltyp )+iwork( coltyp+1 ) )*cutpnt +
248 \$ ( iwork( coltyp+1 )+iwork( coltyp+2 ) )*( n-cutpnt ) + iq2
249 CALL dlaed3( k, n, cutpnt, d, q, ldq, rho, work( idlmda ),
250 \$ work( iq2 ), iwork( indxc ), iwork( coltyp ),
251 \$ work( iw ), work( is ), info )
252 IF( info.NE.0 )
253 \$ GO TO 20
254*
255* Prepare the INDXQ sorting permutation.
256*
257 n1 = k
258 n2 = n - k
259 CALL dlamrg( n1, n2, d, 1, -1, indxq )
260 ELSE
261 DO 10 i = 1, n
262 indxq( i ) = i
263 10 CONTINUE
264 END IF
265*
266 20 CONTINUE
267 RETURN
268*
269* End of DLAED1
270*
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
subroutine dlamrg(N1, N2, A, DTRD1, DTRD2, INDEX)
DLAMRG creates a permutation list to merge the entries of two independently sorted sets into a single...
Definition: dlamrg.f:99
subroutine dlaed2(K, N, N1, D, Q, LDQ, INDXQ, RHO, Z, DLAMDA, W, Q2, INDX, INDXC, INDXP, COLTYP, INFO)
DLAED2 used by DSTEDC. Merges eigenvalues and deflates secular equation. Used when the original matri...
Definition: dlaed2.f:212
subroutine dlaed3(K, N, N1, D, Q, LDQ, RHO, DLAMDA, Q2, INDX, CTOT, W, S, INFO)
DLAED3 used by DSTEDC. Finds the roots of the secular equation and updates the eigenvectors....
Definition: dlaed3.f:185
subroutine dcopy(N, DX, INCX, DY, INCY)
DCOPY
Definition: dcopy.f:82
Here is the call graph for this function:
Here is the caller graph for this function: