clavsp.f

Go to the documentation of this file.

*> \brief \b CLAVSP
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*  Definition:
*  ===========
*
*       SUBROUTINE CLAVSP( UPLO, TRANS, DIAG, N, NRHS, A, IPIV, B, LDB,
*                          INFO )
*
*       .. Scalar Arguments ..
*       CHARACTER          DIAG, TRANS, UPLO
*       INTEGER            INFO, LDB, N, NRHS
*       ..
*       .. Array Arguments ..
*       INTEGER            IPIV( * )
*       COMPLEX            A( * ), B( LDB, * )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*>    CLAVSP  performs one of the matrix-vector operations
*>       x := A*x  or  x := A^T*x,
*>    where x is an N element vector and  A is one of the factors
*>    from the symmetric factorization computed by CSPTRF.
*>    CSPTRF produces a factorization of the form
*>         U * D * U^T     or     L * D * L^T,
*>    where U (or L) is a product of permutation and unit upper (lower)
*>    triangular matrices, U^T (or L^T) is the transpose of
*>    U (or L), and D is symmetric and block diagonal with 1 x 1 and
*>    2 x 2 diagonal blocks.  The multipliers for the transformations
*>    and the upper or lower triangular parts of the diagonal blocks
*>    are stored columnwise in packed format in the linear array A.
*>
*>    If TRANS = 'N' or 'n', CLAVSP multiplies either by U or U * D
*>    (or L or L * D).
*>    If TRANS = 'C' or 'c', CLAVSP multiplies either by U^T or D * U^T
*>    (or L^T or D * L^T ).
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \verbatim
*>  UPLO   - CHARACTER*1
*>           On entry, UPLO specifies whether the triangular matrix
*>           stored in A is upper or lower triangular.
*>              UPLO = 'U' or 'u'   The matrix is upper triangular.
*>              UPLO = 'L' or 'l'   The matrix is lower triangular.
*>           Unchanged on exit.
*>
*>  TRANS  - CHARACTER*1
*>           On entry, TRANS specifies the operation to be performed as
*>           follows:
*>              TRANS = 'N' or 'n'   x := A*x.
*>              TRANS = 'T' or 't'   x := A^T*x.
*>           Unchanged on exit.
*>
*>  DIAG   - CHARACTER*1
*>           On entry, DIAG specifies whether the diagonal blocks are
*>           assumed to be unit matrices, as follows:
*>              DIAG = 'U' or 'u'   Diagonal blocks are unit matrices.
*>              DIAG = 'N' or 'n'   Diagonal blocks are non-unit.
*>           Unchanged on exit.
*>
*>  N      - INTEGER
*>           On entry, N specifies the order of the matrix A.
*>           N must be at least zero.
*>           Unchanged on exit.
*>
*>  NRHS   - INTEGER
*>           On entry, NRHS specifies the number of right hand sides,
*>           i.e., the number of vectors x to be multiplied by A.
*>           NRHS must be at least zero.
*>           Unchanged on exit.
*>
*>  A      - COMPLEX array, dimension( N*(N+1)/2 )
*>           On entry, A contains a block diagonal matrix and the
*>           multipliers of the transformations used to obtain it,
*>           stored as a packed triangular matrix.
*>           Unchanged on exit.
*>
*>  IPIV   - INTEGER array, dimension( N )
*>           On entry, IPIV contains the vector of pivot indices as
*>           determined by CSPTRF.
*>           If IPIV( K ) = K, no interchange was done.
*>           If IPIV( K ) <> K but IPIV( K ) > 0, then row K was inter-
*>           changed with row IPIV( K ) and a 1 x 1 pivot block was used.
*>           If IPIV( K ) < 0 and UPLO = 'U', then row K-1 was exchanged
*>           with row | IPIV( K ) | and a 2 x 2 pivot block was used.
*>           If IPIV( K ) < 0 and UPLO = 'L', then row K+1 was exchanged
*>           with row | IPIV( K ) | and a 2 x 2 pivot block was used.
*>
*>  B      - COMPLEX array, dimension( LDB, NRHS )
*>           On entry, B contains NRHS vectors of length N.
*>           On exit, B is overwritten with the product A * B.
*>
*>  LDB    - INTEGER
*>           On entry, LDB contains the leading dimension of B as
*>           declared in the calling program.  LDB must be at least
*>           max( 1, N ).
*>           Unchanged on exit.
*>
*>  INFO   - INTEGER
*>           INFO is the error flag.
*>           On exit, a value of 0 indicates a successful exit.
*>           A negative value, say -K, indicates that the K-th argument
*>           has an illegal value.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup complex_lin
*
*  =====================================================================
      SUBROUTINE clavsp( UPLO, TRANS, DIAG, N, NRHS, A, IPIV, B, LDB,
     $                   INFO )
*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          DIAG, TRANS, UPLO
      INTEGER            INFO, LDB, N, NRHS
*     ..
*     .. Array Arguments ..
      INTEGER            IPIV( * )
      COMPLEX            A( * ), B( LDB, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      COMPLEX            ONE
      parameter( one = ( 1.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      LOGICAL            NOUNIT
      INTEGER            J, K, KC, KCNEXT, KP
      COMPLEX            D11, D12, D21, D22, T1, T2
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           lsame
*     ..
*     .. External Subroutines ..
      EXTERNAL           cgemv, cgeru, cscal, cswap, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, max
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      IF( .NOT.lsame( uplo, 'U' ) .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -1
      ELSE IF( .NOT.lsame( trans, 'N' ) .AND. .NOT.lsame( trans, 'T' ) )
     $          THEN
         info = -2
      ELSE IF( .NOT.lsame( diag, 'U' ) .AND. .NOT.lsame( diag, 'N' ) )
     $          THEN
         info = -3
      ELSE IF( n.LT.0 ) THEN
         info = -4
      ELSE IF( ldb.LT.max( 1, n ) ) THEN
         info = -8
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CLAVSP ', -info )
         RETURN
      END IF
*
*     Quick return if possible.
*
      IF( n.EQ.0 )
     $   RETURN
*
      nounit = lsame( diag, 'N' )
*------------------------------------------
*
*     Compute  B := A * B  (No transpose)
*
*------------------------------------------
      IF( lsame( trans, 'N' ) ) THEN
*
*        Compute  B := U*B
*        where U = P(m)*inv(U(m))* ... *P(1)*inv(U(1))
*
         IF( lsame( uplo, 'U' ) ) THEN
*
*        Loop forward applying the transformations.
*
            k = 1
            kc = 1
   10       CONTINUE
            IF( k.GT.n )
     $         GO TO 30
*
*           1 x 1 pivot block
*
            IF( ipiv( k ).GT.0 ) THEN
*
*              Multiply by the diagonal element if forming U * D.
*
               IF( nounit )
     $            CALL cscal( nrhs, a( kc+k-1 ), b( k, 1 ), ldb )
*
*              Multiply by P(K) * inv(U(K))  if K > 1.
*
               IF( k.GT.1 ) THEN
*
*                 Apply the transformation.
*
                  CALL cgeru( k-1, nrhs, one, a( kc ), 1, b( k, 1 ),
     $                        ldb, b( 1, 1 ), ldb )
*
*                 Interchange if P(K) != I.
*
                  kp = ipiv( k )
                  IF( kp.NE.k )
     $               CALL cswap( nrhs, b( k, 1 ), ldb, b( kp, 1 ), ldb )
               END IF
               kc = kc + k
               k = k + 1
            ELSE
*
*              2 x 2 pivot block
*
               kcnext = kc + k
*
*              Multiply by the diagonal block if forming U * D.
*
               IF( nounit ) THEN
                  d11 = a( kcnext-1 )
                  d22 = a( kcnext+k )
                  d12 = a( kcnext+k-1 )
                  d21 = d12
                  DO 20 j = 1, nrhs
                     t1 = b( k, j )
                     t2 = b( k+1, j )
                     b( k, j ) = d11*t1 + d12*t2
                     b( k+1, j ) = d21*t1 + d22*t2
   20             CONTINUE
               END IF
*
*              Multiply by  P(K) * inv(U(K))  if K > 1.
*
               IF( k.GT.1 ) THEN
*
*                 Apply the transformations.
*
                  CALL cgeru( k-1, nrhs, one, a( kc ), 1, b( k, 1 ),
     $                        ldb, b( 1, 1 ), ldb )
                  CALL cgeru( k-1, nrhs, one, a( kcnext ), 1,
     $                        b( k+1, 1 ), ldb, b( 1, 1 ), ldb )
*
*                 Interchange if P(K) != I.
*
                  kp = abs( ipiv( k ) )
                  IF( kp.NE.k )
     $               CALL cswap( nrhs, b( k, 1 ), ldb, b( kp, 1 ), ldb )
               END IF
               kc = kcnext + k + 1
               k = k + 2
            END IF
            GO TO 10
   30       CONTINUE
*
*        Compute  B := L*B
*        where L = P(1)*inv(L(1))* ... *P(m)*inv(L(m)) .
*
         ELSE
*
*           Loop backward applying the transformations to B.
*
            k = n
            kc = n*( n+1 ) / 2 + 1
   40       CONTINUE
            IF( k.LT.1 )
     $         GO TO 60
            kc = kc - ( n-k+1 )
*
*           Test the pivot index.  If greater than zero, a 1 x 1
*           pivot was used, otherwise a 2 x 2 pivot was used.
*
            IF( ipiv( k ).GT.0 ) THEN
*
*              1 x 1 pivot block:
*
*              Multiply by the diagonal element if forming L * D.
*
               IF( nounit )
     $            CALL cscal( nrhs, a( kc ), b( k, 1 ), ldb )
*
*              Multiply by  P(K) * inv(L(K))  if K < N.
*
               IF( k.NE.n ) THEN
                  kp = ipiv( k )
*
*                 Apply the transformation.
*
                  CALL cgeru( n-k, nrhs, one, a( kc+1 ), 1, b( k, 1 ),
     $                        ldb, b( k+1, 1 ), ldb )
*
*                 Interchange if a permutation was applied at the
*                 K-th step of the factorization.
*
                  IF( kp.NE.k )
     $               CALL cswap( nrhs, b( k, 1 ), ldb, b( kp, 1 ), ldb )
               END IF
               k = k - 1
*
            ELSE
*
*              2 x 2 pivot block:
*
               kcnext = kc - ( n-k+2 )
*
*              Multiply by the diagonal block if forming L * D.
*
               IF( nounit ) THEN
                  d11 = a( kcnext )
                  d22 = a( kc )
                  d21 = a( kcnext+1 )
                  d12 = d21
                  DO 50 j = 1, nrhs
                     t1 = b( k-1, j )
                     t2 = b( k, j )
                     b( k-1, j ) = d11*t1 + d12*t2
                     b( k, j ) = d21*t1 + d22*t2
   50             CONTINUE
               END IF
*
*              Multiply by  P(K) * inv(L(K))  if K < N.
*
               IF( k.NE.n ) THEN
*
*                 Apply the transformation.
*
                  CALL cgeru( n-k, nrhs, one, a( kc+1 ), 1, b( k, 1 ),
     $                        ldb, b( k+1, 1 ), ldb )
                  CALL cgeru( n-k, nrhs, one, a( kcnext+2 ), 1,
     $                        b( k-1, 1 ), ldb, b( k+1, 1 ), ldb )
*
*                 Interchange if a permutation was applied at the
*                 K-th step of the factorization.
*
                  kp = abs( ipiv( k ) )
                  IF( kp.NE.k )
     $               CALL cswap( nrhs, b( k, 1 ), ldb, b( kp, 1 ), ldb )
               END IF
               kc = kcnext
               k = k - 2
            END IF
            GO TO 40
   60       CONTINUE
         END IF
*-------------------------------------------------
*
*     Compute  B := A^T * B  (transpose)
*
*-------------------------------------------------
      ELSE
*
*        Form  B := U^T*B
*        where U  = P(m)*inv(U(m))* ... *P(1)*inv(U(1))
*        and   U^T = inv(U^T(1))*P(1)* ... *inv(U^T(m))*P(m)
*
         IF( lsame( uplo, 'U' ) ) THEN
*
*           Loop backward applying the transformations.
*
            k = n
            kc = n*( n+1 ) / 2 + 1
   70       IF( k.LT.1 )
     $         GO TO 90
            kc = kc - k
*
*           1 x 1 pivot block.
*
            IF( ipiv( k ).GT.0 ) THEN
               IF( k.GT.1 ) THEN
*
*                 Interchange if P(K) != I.
*
                  kp = ipiv( k )
                  IF( kp.NE.k )
     $               CALL cswap( nrhs, b( k, 1 ), ldb, b( kp, 1 ), ldb )
*
*                 Apply the transformation:
*                    y := y - B' * conjg(x)
*                 where x is a column of A and y is a row of B.
*
                  CALL cgemv( 'Transpose', k-1, nrhs, one, b, ldb,
     $                        a( kc ), 1, one, b( k, 1 ), ldb )
               END IF
               IF( nounit )
     $            CALL cscal( nrhs, a( kc+k-1 ), b( k, 1 ), ldb )
               k = k - 1
*
*           2 x 2 pivot block.
*
            ELSE
               kcnext = kc - ( k-1 )
               IF( k.GT.2 ) THEN
*
*                 Interchange if P(K) != I.
*
                  kp = abs( ipiv( k ) )
                  IF( kp.NE.k-1 )
     $               CALL cswap( nrhs, b( k-1, 1 ), ldb, b( kp, 1 ),
     $                           ldb )
*
*                 Apply the transformations.
*
                  CALL cgemv( 'Transpose', k-2, nrhs, one, b, ldb,
     $                        a( kc ), 1, one, b( k, 1 ), ldb )
*
                  CALL cgemv( 'Transpose', k-2, nrhs, one, b, ldb,
     $                        a( kcnext ), 1, one, b( k-1, 1 ), ldb )
               END IF
*
*              Multiply by the diagonal block if non-unit.
*
               IF( nounit ) THEN
                  d11 = a( kc-1 )
                  d22 = a( kc+k-1 )
                  d12 = a( kc+k-2 )
                  d21 = d12
                  DO 80 j = 1, nrhs
                     t1 = b( k-1, j )
                     t2 = b( k, j )
                     b( k-1, j ) = d11*t1 + d12*t2
                     b( k, j ) = d21*t1 + d22*t2
   80             CONTINUE
               END IF
               kc = kcnext
               k = k - 2
            END IF
            GO TO 70
   90       CONTINUE
*
*        Form  B := L^T*B
*        where L  = P(1)*inv(L(1))* ... *P(m)*inv(L(m))
*        and   L^T = inv(L(m))*P(m)* ... *inv(L(1))*P(1)
*
         ELSE
*
*           Loop forward applying the L-transformations.
*
            k = 1
            kc = 1
  100       CONTINUE
            IF( k.GT.n )
     $         GO TO 120
*
*           1 x 1 pivot block
*
            IF( ipiv( k ).GT.0 ) THEN
               IF( k.LT.n ) THEN
*
*                 Interchange if P(K) != I.
*
                  kp = ipiv( k )
                  IF( kp.NE.k )
     $               CALL cswap( nrhs, b( k, 1 ), ldb, b( kp, 1 ), ldb )
*
*                 Apply the transformation
*
                  CALL cgemv( 'Transpose', n-k, nrhs, one, b( k+1, 1 ),
     $                        ldb, a( kc+1 ), 1, one, b( k, 1 ), ldb )
               END IF
               IF( nounit )
     $            CALL cscal( nrhs, a( kc ), b( k, 1 ), ldb )
               kc = kc + n - k + 1
               k = k + 1
*
*           2 x 2 pivot block.
*
            ELSE
               kcnext = kc + n - k + 1
               IF( k.LT.n-1 ) THEN
*
*              Interchange if P(K) != I.
*
                  kp = abs( ipiv( k ) )
                  IF( kp.NE.k+1 )
     $               CALL cswap( nrhs, b( k+1, 1 ), ldb, b( kp, 1 ),
     $                           ldb )
*
*                 Apply the transformation
*
                  CALL cgemv( 'Transpose', n-k-1, nrhs, one,
     $                        b( k+2, 1 ), ldb, a( kcnext+1 ), 1, one,
     $                        b( k+1, 1 ), ldb )
*
                  CALL cgemv( 'Transpose', n-k-1, nrhs, one,
     $                        b( k+2, 1 ), ldb, a( kc+2 ), 1, one,
     $                        b( k, 1 ), ldb )
               END IF
*
*              Multiply by the diagonal block if non-unit.
*
               IF( nounit ) THEN
                  d11 = a( kc )
                  d22 = a( kcnext )
                  d21 = a( kc+1 )
                  d12 = d21
                  DO 110 j = 1, nrhs
                     t1 = b( k, j )
                     t2 = b( k+1, j )
                     b( k, j ) = d11*t1 + d12*t2
                     b( k+1, j ) = d21*t1 + d22*t2
  110             CONTINUE
               END IF
               kc = kcnext + ( n-k )
               k = k + 2
            END IF
            GO TO 100
  120       CONTINUE
         END IF
*
      END IF
      RETURN
*
*     End of CLAVSP
*
      SUBROUTINE clavsp( UPLO, TRANS, DIAG, N, NRHS, A, IPIV, B, LDB, …
      END