sorgl2()

subroutine sorgl2	(	integer	m,
		integer	n,
		integer	k,
		real, dimension( lda, * )	a,
		integer	lda,
		real, dimension( * )	tau,
		real, dimension( * )	work,
		integer	info
	)

SORGL2

Download SORGL2 + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 SORGL2 generates an m by n real matrix Q with orthonormal rows,
 which is defined as the first m rows of a product of k elementary
 reflectors of order n

       Q  =  H(k) . . . H(2) H(1)

 as returned by SGELQF.

Parameters

[in]	M	M is INTEGER The number of rows of the matrix Q. M >= 0.
[in]	N	N is INTEGER The number of columns of the matrix Q. N >= M.
[in]	K	K is INTEGER The number of elementary reflectors whose product defines the matrix Q. M >= K >= 0.
[in,out]	A	A is REAL array, dimension (LDA,N) On entry, the i-th row must contain the vector which defines the elementary reflector H(i), for i = 1,2,...,k, as returned by SGELQF in the first k rows of its array argument A. On exit, the m-by-n matrix Q.
[in]	LDA	LDA is INTEGER The first dimension of the array A. LDA >= max(1,M).
[in]	TAU	TAU is REAL array, dimension (K) TAU(i) must contain the scalar factor of the elementary reflector H(i), as returned by SGELQF.
[out]	WORK	WORK is REAL array, dimension (M)
[out]	INFO	INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument has an illegal value

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 112 of file sorgl2.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            INFO, K, LDA, M, N
*     ..
*     .. Array Arguments ..
      REAL               A( LDA, * ), TAU( * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ONE, ZERO
      parameter( one = 1.0e+0, zero = 0.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, J, L
*     ..
*     .. External Subroutines ..
      EXTERNAL           slarf, sscal, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max
*     ..
*     .. Executable Statements ..
*
*     Test the input arguments
*
      info = 0
      IF( m.LT.0 ) THEN
         info = -1
      ELSE IF( n.LT.m ) THEN
         info = -2
      ELSE IF( k.LT.0 .OR. k.GT.m ) THEN
         info = -3
      ELSE IF( lda.LT.max( 1, m ) ) THEN
         info = -5
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'SORGL2', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( m.LE.0 )
     $   RETURN
*
      IF( k.LT.m ) THEN
*
*        Initialise rows k+1:m to rows of the unit matrix
*
         DO 20 j = 1, n
            DO 10 l = k + 1, m
               a( l, j ) = zero
   10       CONTINUE
            IF( j.GT.k .AND. j.LE.m )
     $         a( j, j ) = one
   20    CONTINUE
      END IF
*
      DO 40 i = k, 1, -1
*
*        Apply H(i) to A(i:m,i:n) from the right
*
         IF( i.LT.n ) THEN
            IF( i.LT.m ) THEN
               a( i, i ) = one
               CALL slarf( 'Right', m-i, n-i+1, a( i, i ), lda,
     $                     tau( i ), a( i+1, i ), lda, work )
            END IF
            CALL sscal( n-i, -tau( i ), a( i, i+1 ), lda )
         END IF
         a( i, i ) = one - tau( i )
*
*        Set A(i,1:i-1) to zero
*
         DO 30 l = 1, i - 1
            a( i, l ) = zero
   30    CONTINUE
   40 CONTINUE
      RETURN
*
*     End of SORGL2
*

Here is the call graph for this function:

Here is the caller graph for this function: