cgrqts.f

Go to the documentation of this file.

*> \brief \b CGRQTS
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*  Definition:
*  ===========
*
*       SUBROUTINE CGRQTS( M, P, N, A, AF, Q, R, LDA, TAUA, B, BF, Z, T,
*                          BWK, LDB, TAUB, WORK, LWORK, RWORK, RESULT )
*
*       .. Scalar Arguments ..
*       INTEGER            LDA, LDB, LWORK, M, P, N
*       ..
*       .. Array Arguments ..
*       REAL               RESULT( 4 ), RWORK( * )
*       COMPLEX            A( LDA, * ), AF( LDA, * ), R( LDA, * ),
*      $                   Q( LDA, * ), B( LDB, * ), BF( LDB, * ),
*      $                   T( LDB, * ),  Z( LDB, * ), BWK( LDB, * ),
*      $                   TAUA( * ), TAUB( * ), WORK( LWORK )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> CGRQTS tests CGGRQF, which computes the GRQ factorization of an
*> M-by-N matrix A and a P-by-N matrix B: A = R*Q and B = Z*T*Q.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] M
*> \verbatim
*>          M is INTEGER
*>          The number of rows of the matrix A.  M >= 0.
*> \endverbatim
*>
*> \param[in] P
*> \verbatim
*>          P is INTEGER
*>          The number of rows of the matrix B.  P >= 0.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The number of columns of the matrices A and B.  N >= 0.
*> \endverbatim
*>
*> \param[in] A
*> \verbatim
*>          A is COMPLEX array, dimension (LDA,N)
*>          The M-by-N matrix A.
*> \endverbatim
*>
*> \param[out] AF
*> \verbatim
*>          AF is COMPLEX array, dimension (LDA,N)
*>          Details of the GRQ factorization of A and B, as returned
*>          by CGGRQF, see CGGRQF for further details.
*> \endverbatim
*>
*> \param[out] Q
*> \verbatim
*>          Q is COMPLEX array, dimension (LDA,N)
*>          The N-by-N unitary matrix Q.
*> \endverbatim
*>
*> \param[out] R
*> \verbatim
*>          R is COMPLEX array, dimension (LDA,MAX(M,N))
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of the arrays A, AF, R and Q.
*>          LDA >= max(M,N).
*> \endverbatim
*>
*> \param[out] TAUA
*> \verbatim
*>          TAUA is COMPLEX array, dimension (min(M,N))
*>          The scalar factors of the elementary reflectors, as returned
*>          by SGGQRC.
*> \endverbatim
*>
*> \param[in] B
*> \verbatim
*>          B is COMPLEX array, dimension (LDB,N)
*>          On entry, the P-by-N matrix A.
*> \endverbatim
*>
*> \param[out] BF
*> \verbatim
*>          BF is COMPLEX array, dimension (LDB,N)
*>          Details of the GQR factorization of A and B, as returned
*>          by CGGRQF, see CGGRQF for further details.
*> \endverbatim
*>
*> \param[out] Z
*> \verbatim
*>          Z is REAL array, dimension (LDB,P)
*>          The P-by-P unitary matrix Z.
*> \endverbatim
*>
*> \param[out] T
*> \verbatim
*>          T is COMPLEX array, dimension (LDB,max(P,N))
*> \endverbatim
*>
*> \param[out] BWK
*> \verbatim
*>          BWK is COMPLEX array, dimension (LDB,N)
*> \endverbatim
*>
*> \param[in] LDB
*> \verbatim
*>          LDB is INTEGER
*>          The leading dimension of the arrays B, BF, Z and T.
*>          LDB >= max(P,N).
*> \endverbatim
*>
*> \param[out] TAUB
*> \verbatim
*>          TAUB is COMPLEX array, dimension (min(P,N))
*>          The scalar factors of the elementary reflectors, as returned
*>          by SGGRQF.
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is COMPLEX array, dimension (LWORK)
*> \endverbatim
*>
*> \param[in] LWORK
*> \verbatim
*>          LWORK is INTEGER
*>          The dimension of the array WORK, LWORK >= max(M,P,N)**2.
*> \endverbatim
*>
*> \param[out] RWORK
*> \verbatim
*>          RWORK is REAL array, dimension (M)
*> \endverbatim
*>
*> \param[out] RESULT
*> \verbatim
*>          RESULT is REAL array, dimension (4)
*>          The test ratios:
*>            RESULT(1) = norm( R - A*Q' ) / ( MAX(M,N)*norm(A)*ULP)
*>            RESULT(2) = norm( T*Q - Z'*B ) / (MAX(P,N)*norm(B)*ULP)
*>            RESULT(3) = norm( I - Q'*Q ) / ( N*ULP )
*>            RESULT(4) = norm( I - Z'*Z ) / ( P*ULP )
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup complex_eig
*
*  =====================================================================
      SUBROUTINE cgrqts( M, P, N, A, AF, Q, R, LDA, TAUA, B, BF, Z, T,
     $                   BWK, LDB, TAUB, WORK, LWORK, RWORK, RESULT )
*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            LDA, LDB, LWORK, M, P, N
*     ..
*     .. Array Arguments ..
      REAL               RESULT( 4 ), RWORK( * )
      COMPLEX            A( LDA, * ), AF( LDA, * ), R( LDA, * ),
     $                   q( lda, * ), b( ldb, * ), bf( ldb, * ),
     $                   t( ldb, * ),  z( ldb, * ), bwk( ldb, * ),
     $                   taua( * ), taub( * ), work( lwork )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE
      parameter( zero = 0.0e+0, one = 1.0e+0 )
      COMPLEX            CZERO, CONE
      parameter( czero = ( 0.0e+0, 0.0e+0 ),
     $                   cone = ( 1.0e+0, 0.0e+0 ) )
      COMPLEX            CROGUE
      parameter( crogue = ( -1.0e+10, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            INFO
      REAL               ANORM, BNORM, ULP, UNFL, RESID
*     ..
*     .. External Functions ..
      REAL               SLAMCH, CLANGE, CLANHE
      EXTERNAL           slamch, clange, clanhe
*     ..
*     .. External Subroutines ..
      EXTERNAL           cgemm, cggrqf, clacpy, claset, cungqr,
     $                   cungrq, cherk
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min, real
*     ..
*     .. Executable Statements ..
*
      ulp = slamch( 'Precision' )
      unfl = slamch( 'Safe minimum' )
*
*     Copy the matrix A to the array AF.
*
      CALL clacpy( 'Full', m, n, a, lda, af, lda )
      CALL clacpy( 'Full', p, n, b, ldb, bf, ldb )
*
      anorm = max( clange( '1', m, n, a, lda, rwork ), unfl )
      bnorm = max( clange( '1', p, n, b, ldb, rwork ), unfl )
*
*     Factorize the matrices A and B in the arrays AF and BF.
*
      CALL cggrqf( m, p, n, af, lda, taua, bf, ldb, taub, work,
     $             lwork, info )
*
*     Generate the N-by-N matrix Q
*
      CALL claset( 'Full', n, n, crogue, crogue, q, lda )
      IF( m.LE.n ) THEN
         IF( m.GT.0 .AND. m.LT.n )
     $      CALL clacpy( 'Full', m, n-m, af, lda, q( n-m+1, 1 ), lda )
         IF( m.GT.1 )
     $      CALL clacpy( 'Lower', m-1, m-1, af( 2, n-m+1 ), lda,
     $                   q( n-m+2, n-m+1 ), lda )
      ELSE
         IF( n.GT.1 )
     $      CALL clacpy( 'Lower', n-1, n-1, af( m-n+2, 1 ), lda,
     $                   q( 2, 1 ), lda )
      END IF
      CALL cungrq( n, n, min( m, n ), q, lda, taua, work, lwork, info )
*
*     Generate the P-by-P matrix Z
*
      CALL claset( 'Full', p, p, crogue, crogue, z, ldb )
      IF( p.GT.1 )
     $   CALL clacpy( 'Lower', p-1, n, bf( 2,1 ), ldb, z( 2,1 ), ldb )
      CALL cungqr( p, p, min( p,n ), z, ldb, taub, work, lwork, info )
*
*     Copy R
*
      CALL claset( 'Full', m, n, czero, czero, r, lda )
      IF( m.LE.n )THEN
         CALL clacpy( 'Upper', m, m, af( 1, n-m+1 ), lda, r( 1, n-m+1 ),
     $                lda )
      ELSE
         CALL clacpy( 'Full', m-n, n, af, lda, r, lda )
         CALL clacpy( 'Upper', n, n, af( m-n+1, 1 ), lda, r( m-n+1, 1 ),
     $                lda )
      END IF
*
*     Copy T
*
      CALL claset( 'Full', p, n, czero, czero, t, ldb )
      CALL clacpy( 'Upper', p, n, bf, ldb, t, ldb )
*
*     Compute R - A*Q'
*
      CALL cgemm( 'No transpose', 'Conjugate transpose', m, n, n, -cone,
     $            a, lda, q, lda, cone, r, lda )
*
*     Compute norm( R - A*Q' ) / ( MAX(M,N)*norm(A)*ULP ) .
*
      resid = clange( '1', m, n, r, lda, rwork )
      IF( anorm.GT.zero ) THEN
         result( 1 ) = ( ( resid / real(max(1,m,n) ) ) / anorm ) / ulp
      ELSE
         result( 1 ) = zero
      END IF
*
*     Compute T*Q - Z'*B
*
      CALL cgemm( 'Conjugate transpose', 'No transpose', p, n, p, cone,
     $           z, ldb, b, ldb, czero, bwk, ldb )
      CALL cgemm( 'No transpose', 'No transpose', p, n, n, cone, t, ldb,
     $            q, lda, -cone, bwk, ldb )
*
*     Compute norm( T*Q - Z'*B ) / ( MAX(P,N)*norm(A)*ULP ) .
*
      resid = clange( '1', p, n, bwk, ldb, rwork )
      IF( bnorm.GT.zero ) THEN
         result( 2 ) = ( ( resid / real( max( 1,p,m ) ) )/bnorm ) / ulp
      ELSE
         result( 2 ) = zero
      END IF
*
*     Compute I - Q*Q'
*
      CALL claset( 'Full', n, n, czero, cone, r, lda )
      CALL cherk( 'Upper', 'No Transpose', n, n, -one, q, lda, one, r,
     $            lda )
*
*     Compute norm( I - Q'*Q ) / ( N * ULP ) .
*
      resid = clanhe( '1', 'Upper', n, r, lda, rwork )
      result( 3 ) = ( resid / real( max( 1,n ) ) ) / ulp
*
*     Compute I - Z'*Z
*
      CALL claset( 'Full', p, p, czero, cone, t, ldb )
      CALL cherk( 'Upper', 'Conjugate transpose', p, p, -one, z, ldb,
     $            one, t, ldb )
*
*     Compute norm( I - Z'*Z ) / ( P*ULP ) .
*
      resid = clanhe( '1', 'Upper', p, t, ldb, rwork )
      result( 4 ) = ( resid / real( max( 1,p ) ) ) / ulp
*
      RETURN
*
*     End of CGRQTS
*
      SUBROUTINE cgrqts( M, P, N, A, AF, Q, R, LDA, TAUA, B, BF, Z, T, …
      END