chetf2_rook()

subroutine chetf2_rook	(	character	uplo,
		integer	n,
		complex, dimension( lda, * )	a,
		integer	lda,
		integer, dimension( * )	ipiv,
		integer	info )

CHETF2_ROOK computes the factorization of a complex Hermitian indefinite matrix using the bounded Bunch-Kaufman ("rook") diagonal pivoting method (unblocked algorithm).

Download CHETF2_ROOK + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> CHETF2_ROOK computes the factorization of a complex Hermitian matrix A
!> using the bounded Bunch-Kaufman () diagonal pivoting method:
!>
!>    A = U*D*U**H  or  A = L*D*L**H
!>
!> where U (or L) is a product of permutation and unit upper (lower)
!> triangular matrices, U**H is the conjugate transpose of U, and D is
!> Hermitian and block diagonal with 1-by-1 and 2-by-2 diagonal blocks.
!>
!> This is the unblocked version of the algorithm, calling Level 2 BLAS.
!> 

Parameters

[in]	UPLO	!> UPLO is CHARACTER*1 !> Specifies whether the upper or lower triangular part of the !> Hermitian matrix A is stored: !> = 'U': Upper triangular !> = 'L': Lower triangular !>
[in]	N	!> N is INTEGER !> The order of the matrix A. N >= 0. !>
[in,out]	A	!> A is COMPLEX array, dimension (LDA,N) !> On entry, the Hermitian matrix A. If UPLO = 'U', the leading !> n-by-n upper triangular part of A contains the upper !> triangular part of the matrix A, and the strictly lower !> triangular part of A is not referenced. If UPLO = 'L', the !> leading n-by-n lower triangular part of A contains the lower !> triangular part of the matrix A, and the strictly upper !> triangular part of A is not referenced. !> !> On exit, the block diagonal matrix D and the multipliers used !> to obtain the factor U or L (see below for further details). !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= max(1,N). !>
[out]	IPIV	!> IPIV is INTEGER array, dimension (N) !> Details of the interchanges and the block structure of D. !> !> If UPLO = 'U': !> If IPIV(k) > 0, then rows and columns k and IPIV(k) were !> interchanged and D(k,k) is a 1-by-1 diagonal block. !> !> If IPIV(k) < 0 and IPIV(k-1) < 0, then rows and !> columns k and -IPIV(k) were interchanged and rows and !> columns k-1 and -IPIV(k-1) were inerchaged, !> D(k-1:k,k-1:k) is a 2-by-2 diagonal block. !> !> If UPLO = 'L': !> If IPIV(k) > 0, then rows and columns k and IPIV(k) !> were interchanged and D(k,k) is a 1-by-1 diagonal block. !> !> If IPIV(k) < 0 and IPIV(k+1) < 0, then rows and !> columns k and -IPIV(k) were interchanged and rows and !> columns k+1 and -IPIV(k+1) were inerchaged, !> D(k:k+1,k:k+1) is a 2-by-2 diagonal block. !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -k, the k-th argument had an illegal value !> > 0: if INFO = k, D(k,k) is exactly zero. The factorization !> has been completed, but the block diagonal matrix D is !> exactly singular, and division by zero will occur if it !> is used to solve a system of equations. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Further Details:

!>
!>  If UPLO = 'U', then A = U*D*U**H, where
!>     U = P(n)*U(n)* ... *P(k)U(k)* ...,
!>  i.e., U is a product of terms P(k)*U(k), where k decreases from n to
!>  1 in steps of 1 or 2, and D is a block diagonal matrix with 1-by-1
!>  and 2-by-2 diagonal blocks D(k).  P(k) is a permutation matrix as
!>  defined by IPIV(k), and U(k) is a unit upper triangular matrix, such
!>  that if the diagonal block D(k) is of order s (s = 1 or 2), then
!>
!>             (   I    v    0   )   k-s
!>     U(k) =  (   0    I    0   )   s
!>             (   0    0    I   )   n-k
!>                k-s   s   n-k
!>
!>  If s = 1, D(k) overwrites A(k,k), and v overwrites A(1:k-1,k).
!>  If s = 2, the upper triangle of D(k) overwrites A(k-1,k-1), A(k-1,k),
!>  and A(k,k), and v overwrites A(1:k-2,k-1:k).
!>
!>  If UPLO = 'L', then A = L*D*L**H, where
!>     L = P(1)*L(1)* ... *P(k)*L(k)* ...,
!>  i.e., L is a product of terms P(k)*L(k), where k increases from 1 to
!>  n in steps of 1 or 2, and D is a block diagonal matrix with 1-by-1
!>  and 2-by-2 diagonal blocks D(k).  P(k) is a permutation matrix as
!>  defined by IPIV(k), and L(k) is a unit lower triangular matrix, such
!>  that if the diagonal block D(k) is of order s (s = 1 or 2), then
!>
!>             (   I    0     0   )  k-1
!>     L(k) =  (   0    I     0   )  s
!>             (   0    v     I   )  n-k-s+1
!>                k-1   s  n-k-s+1
!>
!>  If s = 1, D(k) overwrites A(k,k), and v overwrites A(k+1:n,k).
!>  If s = 2, the lower triangle of D(k) overwrites A(k,k), A(k+1,k),
!>  and A(k+1,k+1), and v overwrites A(k+2:n,k:k+1).
!> 

Contributors:

!>
!>  November 2013,  Igor Kozachenko,
!>                  Computer Science Division,
!>                  University of California, Berkeley
!>
!>  September 2007, Sven Hammarling, Nicholas J. Higham, Craig Lucas,
!>                  School of Mathematics,
!>                  University of Manchester
!>
!>  01-01-96 - Based on modifications by
!>    J. Lewis, Boeing Computer Services Company
!>    A. Petitet, Computer Science Dept., Univ. of Tenn., Knoxville, USA
!> 

Definition at line 191 of file chetf2_rook.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            INFO, LDA, N
*     ..
*     .. Array Arguments ..
      INTEGER            IPIV( * )
      COMPLEX            A( LDA, * )
*     ..
*
*  ======================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE
      parameter( zero = 0.0e+0, one = 1.0e+0 )
      REAL               EIGHT, SEVTEN
      parameter( eight = 8.0e+0, sevten = 17.0e+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            DONE, UPPER
      INTEGER            I, II, IMAX, ITEMP, J, JMAX, K, KK, KP, KSTEP,
     $                   P
      REAL               ABSAKK, ALPHA, COLMAX, D, D11, D22, R1, STEMP,
     $                   ROWMAX, TT, SFMIN
      COMPLEX            D12, D21, T, WK, WKM1, WKP1, Z
*     ..
*     .. External Functions ..
*
      LOGICAL            LSAME
      INTEGER            ICAMAX
      REAL               SLAMCH, SLAPY2
      EXTERNAL           lsame, icamax, slamch, slapy2
*     ..
*     .. External Subroutines ..
      EXTERNAL           xerbla, csscal, cher, cswap
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, aimag, cmplx, conjg, max, real, sqrt
*     ..
*     .. Statement Functions ..
      REAL   CABS1
*     ..
*     .. Statement Function definitions ..
      cabs1( z ) = abs( real( z ) ) + abs( aimag( z ) )
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      upper = lsame( uplo, 'U' )
      IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -4
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CHETF2_ROOK', -info )
         RETURN
      END IF
*
*     Initialize ALPHA for use in choosing pivot block size.
*
      alpha = ( one+sqrt( sevten ) ) / eight
*
*     Compute machine safe minimum
*
      sfmin = slamch( 'S' )
*
      IF( upper ) THEN
*
*        Factorize A as U*D*U**H using the upper triangle of A
*
*        K is the main loop index, decreasing from N to 1 in steps of
*        1 or 2
*
         k = n
   10    CONTINUE
*
*        If K < 1, exit from loop
*
         IF( k.LT.1 )
     $      GO TO 70
         kstep = 1
         p = k
*
*        Determine rows and columns to be interchanged and whether
*        a 1-by-1 or 2-by-2 pivot block will be used
*
         absakk = abs( real( a( k, k ) ) )
*
*        IMAX is the row-index of the largest off-diagonal element in
*        column K, and COLMAX is its absolute value.
*        Determine both COLMAX and IMAX.
*
         IF( k.GT.1 ) THEN
            imax = icamax( k-1, a( 1, k ), 1 )
            colmax = cabs1( a( imax, k ) )
         ELSE
            colmax = zero
         END IF
*
         IF( ( max( absakk, colmax ).EQ.zero ) ) THEN
*
*           Column K is zero or underflow: set INFO and continue
*
            IF( info.EQ.0 )
     $         info = k
            kp = k
            a( k, k ) = real( a( k, k ) )
         ELSE
*
*           ============================================================
*
*           BEGIN pivot search
*
*           Case(1)
*           Equivalent to testing for ABSAKK.GE.ALPHA*COLMAX
*           (used to handle NaN and Inf)
*
            IF( .NOT.( absakk.LT.alpha*colmax ) ) THEN
*
*              no interchange, use 1-by-1 pivot block
*
               kp = k
*
            ELSE
*
               done = .false.
*
*              Loop until pivot found
*
   12          CONTINUE
*
*                 BEGIN pivot search loop body
*
*
*                 JMAX is the column-index of the largest off-diagonal
*                 element in row IMAX, and ROWMAX is its absolute value.
*                 Determine both ROWMAX and JMAX.
*
                  IF( imax.NE.k ) THEN
                     jmax = imax + icamax( k-imax, a( imax, imax+1 ),
     $                                     lda )
                     rowmax = cabs1( a( imax, jmax ) )
                  ELSE
                     rowmax = zero
                  END IF
*
                  IF( imax.GT.1 ) THEN
                     itemp = icamax( imax-1, a( 1, imax ), 1 )
                     stemp = cabs1( a( itemp, imax ) )
                     IF( stemp.GT.rowmax ) THEN
                        rowmax = stemp
                        jmax = itemp
                     END IF
                  END IF
*
*                 Case(2)
*                 Equivalent to testing for
*                 ABS( REAL( W( IMAX,KW-1 ) ) ).GE.ALPHA*ROWMAX
*                 (used to handle NaN and Inf)
*
                  IF( .NOT.( abs( real( a( imax, imax ) ) )
     $                       .LT.alpha*rowmax ) ) THEN
*
*                    interchange rows and columns K and IMAX,
*                    use 1-by-1 pivot block
*
                     kp = imax
                     done = .true.
*
*                 Case(3)
*                 Equivalent to testing for ROWMAX.EQ.COLMAX,
*                 (used to handle NaN and Inf)
*
                  ELSE IF( ( p.EQ.jmax ) .OR. ( rowmax.LE.colmax ) )
     $            THEN
*
*                    interchange rows and columns K-1 and IMAX,
*                    use 2-by-2 pivot block
*
                     kp = imax
                     kstep = 2
                     done = .true.
*
*                 Case(4)
                  ELSE
*
*                    Pivot not found: set params and repeat
*
                     p = imax
                     colmax = rowmax
                     imax = jmax
                  END IF
*
*                 END pivot search loop body
*
               IF( .NOT.done ) GOTO 12
*
            END IF
*
*           END pivot search
*
*           ============================================================
*
*           KK is the column of A where pivoting step stopped
*
            kk = k - kstep + 1
*
*           For only a 2x2 pivot, interchange rows and columns K and P
*           in the leading submatrix A(1:k,1:k)
*
            IF( ( kstep.EQ.2 ) .AND. ( p.NE.k ) ) THEN
*              (1) Swap columnar parts
               IF( p.GT.1 )
     $            CALL cswap( p-1, a( 1, k ), 1, a( 1, p ), 1 )
*              (2) Swap and conjugate middle parts
               DO 14 j = p + 1, k - 1
                  t = conjg( a( j, k ) )
                  a( j, k ) = conjg( a( p, j ) )
                  a( p, j ) = t
   14          CONTINUE
*              (3) Swap and conjugate corner elements at row-col intersection
               a( p, k ) = conjg( a( p, k ) )
*              (4) Swap diagonal elements at row-col intersection
               r1 = real( a( k, k ) )
               a( k, k ) = real( a( p, p ) )
               a( p, p ) = r1
            END IF
*
*           For both 1x1 and 2x2 pivots, interchange rows and
*           columns KK and KP in the leading submatrix A(1:k,1:k)
*
            IF( kp.NE.kk ) THEN
*              (1) Swap columnar parts
               IF( kp.GT.1 )
     $            CALL cswap( kp-1, a( 1, kk ), 1, a( 1, kp ), 1 )
*              (2) Swap and conjugate middle parts
               DO 15 j = kp + 1, kk - 1
                  t = conjg( a( j, kk ) )
                  a( j, kk ) = conjg( a( kp, j ) )
                  a( kp, j ) = t
   15          CONTINUE
*              (3) Swap and conjugate corner elements at row-col intersection
               a( kp, kk ) = conjg( a( kp, kk ) )
*              (4) Swap diagonal elements at row-col intersection
               r1 = real( a( kk, kk ) )
               a( kk, kk ) = real( a( kp, kp ) )
               a( kp, kp ) = r1
*
               IF( kstep.EQ.2 ) THEN
*                 (*) Make sure that diagonal element of pivot is real
                  a( k, k ) = real( a( k, k ) )
*                 (5) Swap row elements
                  t = a( k-1, k )
                  a( k-1, k ) = a( kp, k )
                  a( kp, k ) = t
               END IF
            ELSE
*              (*) Make sure that diagonal element of pivot is real
               a( k, k ) = real( a( k, k ) )
               IF( kstep.EQ.2 )
     $            a( k-1, k-1 ) = real( a( k-1, k-1 ) )
            END IF
*
*           Update the leading submatrix
*
            IF( kstep.EQ.1 ) THEN
*
*              1-by-1 pivot block D(k): column k now holds
*
*              W(k) = U(k)*D(k)
*
*              where U(k) is the k-th column of U
*
               IF( k.GT.1 ) THEN
*
*                 Perform a rank-1 update of A(1:k-1,1:k-1) and
*                 store U(k) in column k
*
                  IF( abs( real( a( k, k ) ) ).GE.sfmin ) THEN
*
*                    Perform a rank-1 update of A(1:k-1,1:k-1) as
*                    A := A - U(k)*D(k)*U(k)**T
*                       = A - W(k)*1/D(k)*W(k)**T
*
                     d11 = one / real( a( k, k ) )
                     CALL cher( uplo, k-1, -d11, a( 1, k ), 1, a,
     $                          lda )
*
*                    Store U(k) in column k
*
                     CALL csscal( k-1, d11, a( 1, k ), 1 )
                  ELSE
*
*                    Store L(k) in column K
*
                     d11 = real( a( k, k ) )
                     DO 16 ii = 1, k - 1
                        a( ii, k ) = a( ii, k ) / d11
   16                CONTINUE
*
*                    Perform a rank-1 update of A(k+1:n,k+1:n) as
*                    A := A - U(k)*D(k)*U(k)**T
*                       = A - W(k)*(1/D(k))*W(k)**T
*                       = A - (W(k)/D(k))*(D(k))*(W(k)/D(K))**T
*
                     CALL cher( uplo, k-1, -d11, a( 1, k ), 1, a,
     $                          lda )
                  END IF
               END IF
*
            ELSE
*
*              2-by-2 pivot block D(k): columns k and k-1 now hold
*
*              ( W(k-1) W(k) ) = ( U(k-1) U(k) )*D(k)
*
*              where U(k) and U(k-1) are the k-th and (k-1)-th columns
*              of U
*
*              Perform a rank-2 update of A(1:k-2,1:k-2) as
*
*              A := A - ( U(k-1) U(k) )*D(k)*( U(k-1) U(k) )**T
*                 = A - ( ( A(k-1)A(k) )*inv(D(k)) ) * ( A(k-1)A(k) )**T
*
*              and store L(k) and L(k+1) in columns k and k+1
*
               IF( k.GT.2 ) THEN
*                 D = |A12|
                  d = slapy2( real( a( k-1, k ) ),
     $                aimag( a( k-1, k ) ) )
                  d11 = real( a( k, k ) / d )
                  d22 = real( a( k-1, k-1 ) / d )
                  d12 = a( k-1, k ) / d
                  tt = one / ( d11*d22-one )
*
                  DO 30 j = k - 2, 1, -1
*
*                    Compute  D21 * ( W(k)W(k+1) ) * inv(D(k)) for row J
*
                     wkm1 = tt*( d11*a( j, k-1 )-conjg( d12 )*
     $                      a( j, k ) )
                     wk = tt*( d22*a( j, k )-d12*a( j, k-1 ) )
*
*                    Perform a rank-2 update of A(1:k-2,1:k-2)
*
                     DO 20 i = j, 1, -1
                        a( i, j ) = a( i, j ) -
     $                              ( a( i, k ) / d )*conjg( wk ) -
     $                              ( a( i, k-1 ) / d )*conjg( wkm1 )
   20                CONTINUE
*
*                    Store U(k) and U(k-1) in cols k and k-1 for row J
*
                     a( j, k ) = wk / d
                     a( j, k-1 ) = wkm1 / d
*                    (*) Make sure that diagonal element of pivot is real
                     a( j, j ) = cmplx( real( a( j, j ) ), zero )
*
   30             CONTINUE
*
               END IF
*
            END IF
*
         END IF
*
*        Store details of the interchanges in IPIV
*
         IF( kstep.EQ.1 ) THEN
            ipiv( k ) = kp
         ELSE
            ipiv( k ) = -p
            ipiv( k-1 ) = -kp
         END IF
*
*        Decrease K and return to the start of the main loop
*
         k = k - kstep
         GO TO 10
*
      ELSE
*
*        Factorize A as L*D*L**H using the lower triangle of A
*
*        K is the main loop index, increasing from 1 to N in steps of
*        1 or 2
*
         k = 1
   40    CONTINUE
*
*        If K > N, exit from loop
*
         IF( k.GT.n )
     $      GO TO 70
         kstep = 1
         p = k
*
*        Determine rows and columns to be interchanged and whether
*        a 1-by-1 or 2-by-2 pivot block will be used
*
         absakk = abs( real( a( k, k ) ) )
*
*        IMAX is the row-index of the largest off-diagonal element in
*        column K, and COLMAX is its absolute value.
*        Determine both COLMAX and IMAX.
*
         IF( k.LT.n ) THEN
            imax = k + icamax( n-k, a( k+1, k ), 1 )
            colmax = cabs1( a( imax, k ) )
         ELSE
            colmax = zero
         END IF
*
         IF( max( absakk, colmax ).EQ.zero ) THEN
*
*           Column K is zero or underflow: set INFO and continue
*
            IF( info.EQ.0 )
     $         info = k
            kp = k
            a( k, k ) = real( a( k, k ) )
         ELSE
*
*           ============================================================
*
*           BEGIN pivot search
*
*           Case(1)
*           Equivalent to testing for ABSAKK.GE.ALPHA*COLMAX
*           (used to handle NaN and Inf)
*
            IF( .NOT.( absakk.LT.alpha*colmax ) ) THEN
*
*              no interchange, use 1-by-1 pivot block
*
               kp = k
*
            ELSE
*
               done = .false.
*
*              Loop until pivot found
*
   42          CONTINUE
*
*                 BEGIN pivot search loop body
*
*
*                 JMAX is the column-index of the largest off-diagonal
*                 element in row IMAX, and ROWMAX is its absolute value.
*                 Determine both ROWMAX and JMAX.
*
                  IF( imax.NE.k ) THEN
                     jmax = k - 1 + icamax( imax-k, a( imax, k ),
     $                                      lda )
                     rowmax = cabs1( a( imax, jmax ) )
                  ELSE
                     rowmax = zero
                  END IF
*
                  IF( imax.LT.n ) THEN
                     itemp = imax + icamax( n-imax, a( imax+1,
     $                                      imax ),
     $                                     1 )
                     stemp = cabs1( a( itemp, imax ) )
                     IF( stemp.GT.rowmax ) THEN
                        rowmax = stemp
                        jmax = itemp
                     END IF
                  END IF
*
*                 Case(2)
*                 Equivalent to testing for
*                 ABS( REAL( W( IMAX,KW-1 ) ) ).GE.ALPHA*ROWMAX
*                 (used to handle NaN and Inf)
*
                  IF( .NOT.( abs( real( a( imax, imax ) ) )
     $                       .LT.alpha*rowmax ) ) THEN
*
*                    interchange rows and columns K and IMAX,
*                    use 1-by-1 pivot block
*
                     kp = imax
                     done = .true.
*
*                 Case(3)
*                 Equivalent to testing for ROWMAX.EQ.COLMAX,
*                 (used to handle NaN and Inf)
*
                  ELSE IF( ( p.EQ.jmax ) .OR. ( rowmax.LE.colmax ) )
     $            THEN
*
*                    interchange rows and columns K+1 and IMAX,
*                    use 2-by-2 pivot block
*
                     kp = imax
                     kstep = 2
                     done = .true.
*
*                 Case(4)
                  ELSE
*
*                    Pivot not found: set params and repeat
*
                     p = imax
                     colmax = rowmax
                     imax = jmax
                  END IF
*
*
*                 END pivot search loop body
*
               IF( .NOT.done ) GOTO 42
*
            END IF
*
*           END pivot search
*
*           ============================================================
*
*           KK is the column of A where pivoting step stopped
*
            kk = k + kstep - 1
*
*           For only a 2x2 pivot, interchange rows and columns K and P
*           in the trailing submatrix A(k:n,k:n)
*
            IF( ( kstep.EQ.2 ) .AND. ( p.NE.k ) ) THEN
*              (1) Swap columnar parts
               IF( p.LT.n )
     $            CALL cswap( n-p, a( p+1, k ), 1, a( p+1, p ), 1 )
*              (2) Swap and conjugate middle parts
               DO 44 j = k + 1, p - 1
                  t = conjg( a( j, k ) )
                  a( j, k ) = conjg( a( p, j ) )
                  a( p, j ) = t
   44          CONTINUE
*              (3) Swap and conjugate corner elements at row-col intersection
               a( p, k ) = conjg( a( p, k ) )
*              (4) Swap diagonal elements at row-col intersection
               r1 = real( a( k, k ) )
               a( k, k ) = real( a( p, p ) )
               a( p, p ) = r1
            END IF
*
*           For both 1x1 and 2x2 pivots, interchange rows and
*           columns KK and KP in the trailing submatrix A(k:n,k:n)
*
            IF( kp.NE.kk ) THEN
*              (1) Swap columnar parts
               IF( kp.LT.n )
     $            CALL cswap( n-kp, a( kp+1, kk ), 1, a( kp+1, kp ),
     $                        1 )
*              (2) Swap and conjugate middle parts
               DO 45 j = kk + 1, kp - 1
                  t = conjg( a( j, kk ) )
                  a( j, kk ) = conjg( a( kp, j ) )
                  a( kp, j ) = t
   45          CONTINUE
*              (3) Swap and conjugate corner elements at row-col intersection
               a( kp, kk ) = conjg( a( kp, kk ) )
*              (4) Swap diagonal elements at row-col intersection
               r1 = real( a( kk, kk ) )
               a( kk, kk ) = real( a( kp, kp ) )
               a( kp, kp ) = r1
*
               IF( kstep.EQ.2 ) THEN
*                 (*) Make sure that diagonal element of pivot is real
                  a( k, k ) = real( a( k, k ) )
*                 (5) Swap row elements
                  t = a( k+1, k )
                  a( k+1, k ) = a( kp, k )
                  a( kp, k ) = t
               END IF
            ELSE
*              (*) Make sure that diagonal element of pivot is real
               a( k, k ) = real( a( k, k ) )
               IF( kstep.EQ.2 )
     $            a( k+1, k+1 ) = real( a( k+1, k+1 ) )
            END IF
*
*           Update the trailing submatrix
*
            IF( kstep.EQ.1 ) THEN
*
*              1-by-1 pivot block D(k): column k of A now holds
*
*              W(k) = L(k)*D(k),
*
*              where L(k) is the k-th column of L
*
               IF( k.LT.n ) THEN
*
*                 Perform a rank-1 update of A(k+1:n,k+1:n) and
*                 store L(k) in column k
*
*                 Handle division by a small number
*
                  IF( abs( real( a( k, k ) ) ).GE.sfmin ) THEN
*
*                    Perform a rank-1 update of A(k+1:n,k+1:n) as
*                    A := A - L(k)*D(k)*L(k)**T
*                       = A - W(k)*(1/D(k))*W(k)**T
*
                     d11 = one / real( a( k, k ) )
                     CALL cher( uplo, n-k, -d11, a( k+1, k ), 1,
     $                          a( k+1, k+1 ), lda )
*
*                    Store L(k) in column k
*
                     CALL csscal( n-k, d11, a( k+1, k ), 1 )
                  ELSE
*
*                    Store L(k) in column k
*
                     d11 = real( a( k, k ) )
                     DO 46 ii = k + 1, n
                        a( ii, k ) = a( ii, k ) / d11
   46                CONTINUE
*
*                    Perform a rank-1 update of A(k+1:n,k+1:n) as
*                    A := A - L(k)*D(k)*L(k)**T
*                       = A - W(k)*(1/D(k))*W(k)**T
*                       = A - (W(k)/D(k))*(D(k))*(W(k)/D(K))**T
*
                     CALL cher( uplo, n-k, -d11, a( k+1, k ), 1,
     $                          a( k+1, k+1 ), lda )
                  END IF
               END IF
*
            ELSE
*
*              2-by-2 pivot block D(k): columns k and k+1 now hold
*
*              ( W(k) W(k+1) ) = ( L(k) L(k+1) )*D(k)
*
*              where L(k) and L(k+1) are the k-th and (k+1)-th columns
*              of L
*
*
*              Perform a rank-2 update of A(k+2:n,k+2:n) as
*
*              A := A - ( L(k) L(k+1) ) * D(k) * ( L(k) L(k+1) )**T
*                 = A - ( ( A(k)A(k+1) )*inv(D(k) ) * ( A(k)A(k+1) )**T
*
*              and store L(k) and L(k+1) in columns k and k+1
*
               IF( k.LT.n-1 ) THEN
*                 D = |A21|
                  d = slapy2( real( a( k+1, k ) ),
     $                aimag( a( k+1, k ) ) )
                  d11 = real( a( k+1, k+1 ) ) / d
                  d22 = real( a( k, k ) ) / d
                  d21 = a( k+1, k ) / d
                  tt = one / ( d11*d22-one )
*
                  DO 60 j = k + 2, n
*
*                    Compute  D21 * ( W(k)W(k+1) ) * inv(D(k)) for row J
*
                     wk = tt*( d11*a( j, k )-d21*a( j, k+1 ) )
                     wkp1 = tt*( d22*a( j, k+1 )-conjg( d21 )*
     $                      a( j, k ) )
*
*                    Perform a rank-2 update of A(k+2:n,k+2:n)
*
                     DO 50 i = j, n
                        a( i, j ) = a( i, j ) -
     $                              ( a( i, k ) / d )*conjg( wk ) -
     $                              ( a( i, k+1 ) / d )*conjg( wkp1 )
   50                CONTINUE
*
*                    Store L(k) and L(k+1) in cols k and k+1 for row J
*
                     a( j, k ) = wk / d
                     a( j, k+1 ) = wkp1 / d
*                    (*) Make sure that diagonal element of pivot is real
                     a( j, j ) = cmplx( real( a( j, j ) ), zero )
*
   60             CONTINUE
*
               END IF
*
            END IF
*
         END IF
*
*        Store details of the interchanges in IPIV
*
         IF( kstep.EQ.1 ) THEN
            ipiv( k ) = kp
         ELSE
            ipiv( k ) = -p
            ipiv( k+1 ) = -kp
         END IF
*
*        Increase K and return to the start of the main loop
*
         k = k + kstep
         GO TO 40
*
      END IF
*
   70 CONTINUE
*
      RETURN
*
*     End of CHETF2_ROOK
*

Here is the call graph for this function:

Here is the caller graph for this function: