stpttr()

subroutine stpttr	(	character	uplo,
		integer	n,
		real, dimension( * )	ap,
		real, dimension( lda, * )	a,
		integer	lda,
		integer	info )

STPTTR copies a triangular matrix from the standard packed format (TP) to the standard full format (TR).

Download STPTTR + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> STPTTR copies a triangular matrix A from standard packed format (TP)
!> to standard full format (TR).
!> 

Parameters

[in]	UPLO	!> UPLO is CHARACTER*1 !> = 'U': A is upper triangular. !> = 'L': A is lower triangular. !>
[in]	N	!> N is INTEGER !> The order of the matrix A. N >= 0. !>
[in]	AP	!> AP is REAL array, dimension ( N*(N+1)/2 ), !> On entry, the upper or lower triangular matrix A, packed !> columnwise in a linear array. The j-th column of A is stored !> in the array AP as follows: !> if UPLO = 'U', AP(i + (j-1)*j/2) = A(i,j) for 1<=i<=j; !> if UPLO = 'L', AP(i + (j-1)*(2n-j)/2) = A(i,j) for j<=i<=n. !>
[out]	A	!> A is REAL array, dimension ( LDA, N ) !> On exit, the triangular matrix A. If UPLO = 'U', the leading !> N-by-N upper triangular part of A contains the upper !> triangular part of the matrix A, and the strictly lower !> triangular part of A is not referenced. If UPLO = 'L', the !> leading N-by-N lower triangular part of A contains the lower !> triangular part of the matrix A, and the strictly upper !> triangular part of A is not referenced. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= max(1,N). !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -i, the i-th argument had an illegal value !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 101 of file stpttr.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            INFO, N, LDA
*     ..
*     .. Array Arguments ..
      REAL               A( LDA, * ), AP( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
*     ..
*     .. Local Scalars ..
      LOGICAL            LOWER
      INTEGER            I, J, K
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           lsame
*     ..
*     .. External Subroutines ..
      EXTERNAL           xerbla
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      lower = lsame( uplo, 'L' )
      IF( .NOT.lower .AND. .NOT.lsame( uplo, 'U' ) ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -5
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'STPTTR', -info )
         RETURN
      END IF
*
      IF( lower ) THEN
         k = 0
         DO j = 1, n
            DO i = j, n
               k = k + 1
               a( i, j ) = ap( k )
            END DO
         END DO
      ELSE
         k = 0
         DO j = 1, n
            DO i = 1, j
               k = k + 1
               a( i, j ) = ap( k )
            END DO
         END DO
      END IF
*
*
      RETURN
*
*     End of STPTTR
*

Here is the call graph for this function:

Here is the caller graph for this function: