 LAPACK  3.10.1 LAPACK: Linear Algebra PACKage

## ◆ sppcon()

 subroutine sppcon ( character UPLO, integer N, real, dimension( * ) AP, real ANORM, real RCOND, real, dimension( * ) WORK, integer, dimension( * ) IWORK, integer INFO )

SPPCON

Download SPPCON + dependencies [TGZ] [ZIP] [TXT]

Purpose:
``` SPPCON estimates the reciprocal of the condition number (in the
1-norm) of a real symmetric positive definite packed matrix using
the Cholesky factorization A = U**T*U or A = L*L**T computed by
SPPTRF.

An estimate is obtained for norm(inv(A)), and the reciprocal of the
condition number is computed as RCOND = 1 / (ANORM * norm(inv(A))).```
Parameters
 [in] UPLO ``` UPLO is CHARACTER*1 = 'U': Upper triangle of A is stored; = 'L': Lower triangle of A is stored.``` [in] N ``` N is INTEGER The order of the matrix A. N >= 0.``` [in] AP ``` AP is REAL array, dimension (N*(N+1)/2) The triangular factor U or L from the Cholesky factorization A = U**T*U or A = L*L**T, packed columnwise in a linear array. The j-th column of U or L is stored in the array AP as follows: if UPLO = 'U', AP(i + (j-1)*j/2) = U(i,j) for 1<=i<=j; if UPLO = 'L', AP(i + (j-1)*(2n-j)/2) = L(i,j) for j<=i<=n.``` [in] ANORM ``` ANORM is REAL The 1-norm (or infinity-norm) of the symmetric matrix A.``` [out] RCOND ``` RCOND is REAL The reciprocal of the condition number of the matrix A, computed as RCOND = 1/(ANORM * AINVNM), where AINVNM is an estimate of the 1-norm of inv(A) computed in this routine.``` [out] WORK ` WORK is REAL array, dimension (3*N)` [out] IWORK ` IWORK is INTEGER array, dimension (N)` [out] INFO ``` INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value```

Definition at line 117 of file sppcon.f.

118 *
119 * -- LAPACK computational routine --
120 * -- LAPACK is a software package provided by Univ. of Tennessee, --
121 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
122 *
123 * .. Scalar Arguments ..
124  CHARACTER UPLO
125  INTEGER INFO, N
126  REAL ANORM, RCOND
127 * ..
128 * .. Array Arguments ..
129  INTEGER IWORK( * )
130  REAL AP( * ), WORK( * )
131 * ..
132 *
133 * =====================================================================
134 *
135 * .. Parameters ..
136  REAL ONE, ZERO
137  parameter( one = 1.0e+0, zero = 0.0e+0 )
138 * ..
139 * .. Local Scalars ..
140  LOGICAL UPPER
141  CHARACTER NORMIN
142  INTEGER IX, KASE
143  REAL AINVNM, SCALE, SCALEL, SCALEU, SMLNUM
144 * ..
145 * .. Local Arrays ..
146  INTEGER ISAVE( 3 )
147 * ..
148 * .. External Functions ..
149  LOGICAL LSAME
150  INTEGER ISAMAX
151  REAL SLAMCH
152  EXTERNAL lsame, isamax, slamch
153 * ..
154 * .. External Subroutines ..
155  EXTERNAL slacn2, slatps, srscl, xerbla
156 * ..
157 * .. Intrinsic Functions ..
158  INTRINSIC abs
159 * ..
160 * .. Executable Statements ..
161 *
162 * Test the input parameters.
163 *
164  info = 0
165  upper = lsame( uplo, 'U' )
166  IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
167  info = -1
168  ELSE IF( n.LT.0 ) THEN
169  info = -2
170  ELSE IF( anorm.LT.zero ) THEN
171  info = -4
172  END IF
173  IF( info.NE.0 ) THEN
174  CALL xerbla( 'SPPCON', -info )
175  RETURN
176  END IF
177 *
178 * Quick return if possible
179 *
180  rcond = zero
181  IF( n.EQ.0 ) THEN
182  rcond = one
183  RETURN
184  ELSE IF( anorm.EQ.zero ) THEN
185  RETURN
186  END IF
187 *
188  smlnum = slamch( 'Safe minimum' )
189 *
190 * Estimate the 1-norm of the inverse.
191 *
192  kase = 0
193  normin = 'N'
194  10 CONTINUE
195  CALL slacn2( n, work( n+1 ), work, iwork, ainvnm, kase, isave )
196  IF( kase.NE.0 ) THEN
197  IF( upper ) THEN
198 *
199 * Multiply by inv(U**T).
200 *
201  CALL slatps( 'Upper', 'Transpose', 'Non-unit', normin, n,
202  \$ ap, work, scalel, work( 2*n+1 ), info )
203  normin = 'Y'
204 *
205 * Multiply by inv(U).
206 *
207  CALL slatps( 'Upper', 'No transpose', 'Non-unit', normin, n,
208  \$ ap, work, scaleu, work( 2*n+1 ), info )
209  ELSE
210 *
211 * Multiply by inv(L).
212 *
213  CALL slatps( 'Lower', 'No transpose', 'Non-unit', normin, n,
214  \$ ap, work, scalel, work( 2*n+1 ), info )
215  normin = 'Y'
216 *
217 * Multiply by inv(L**T).
218 *
219  CALL slatps( 'Lower', 'Transpose', 'Non-unit', normin, n,
220  \$ ap, work, scaleu, work( 2*n+1 ), info )
221  END IF
222 *
223 * Multiply by 1/SCALE if doing so will not cause overflow.
224 *
225  scale = scalel*scaleu
226  IF( scale.NE.one ) THEN
227  ix = isamax( n, work, 1 )
228  IF( scale.LT.abs( work( ix ) )*smlnum .OR. scale.EQ.zero )
229  \$ GO TO 20
230  CALL srscl( n, scale, work, 1 )
231  END IF
232  GO TO 10
233  END IF
234 *
235 * Compute the estimate of the reciprocal condition number.
236 *
237  IF( ainvnm.NE.zero )
238  \$ rcond = ( one / ainvnm ) / anorm
239 *
240  20 CONTINUE
241  RETURN
242 *
243 * End of SPPCON
244 *
integer function isamax(N, SX, INCX)
ISAMAX
Definition: isamax.f:71
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
subroutine slacn2(N, V, X, ISGN, EST, KASE, ISAVE)
SLACN2 estimates the 1-norm of a square matrix, using reverse communication for evaluating matrix-vec...
Definition: slacn2.f:136
subroutine slatps(UPLO, TRANS, DIAG, NORMIN, N, AP, X, SCALE, CNORM, INFO)
SLATPS solves a triangular system of equations with the matrix held in packed storage.
Definition: slatps.f:229
subroutine srscl(N, SA, SX, INCX)
SRSCL multiplies a vector by the reciprocal of a real scalar.
Definition: srscl.f:84
real function slamch(CMACH)
SLAMCH
Definition: slamch.f:68
Here is the call graph for this function:
Here is the caller graph for this function: