cla_gbrpvgrw()

real function cla_gbrpvgrw	(	integer	n,
		integer	kl,
		integer	ku,
		integer	ncols,
		complex, dimension( ldab, * )	ab,
		integer	ldab,
		complex, dimension( ldafb, * )	afb,
		integer	ldafb )

CLA_GBRPVGRW computes the reciprocal pivot growth factor norm(A)/norm(U) for a general banded matrix.

Download CLA_GBRPVGRW + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> CLA_GBRPVGRW computes the reciprocal pivot growth factor
!> norm(A)/norm(U). The  norm is used. If this is
!> much less than 1, the stability of the LU factorization of the
!> (equilibrated) matrix A could be poor. This also means that the
!> solution X, estimated condition numbers, and error bounds could be
!> unreliable.
!> 

Parameters

[in]	N	!> N is INTEGER !> The number of linear equations, i.e., the order of the !> matrix A. N >= 0. !>
[in]	KL	!> KL is INTEGER !> The number of subdiagonals within the band of A. KL >= 0. !>
[in]	KU	!> KU is INTEGER !> The number of superdiagonals within the band of A. KU >= 0. !>
[in]	NCOLS	!> NCOLS is INTEGER !> The number of columns of the matrix A. NCOLS >= 0. !>
[in]	AB	!> AB is COMPLEX array, dimension (LDAB,N) !> On entry, the matrix A in band storage, in rows 1 to KL+KU+1. !> The j-th column of A is stored in the j-th column of the !> array AB as follows: !> AB(KU+1+i-j,j) = A(i,j) for max(1,j-KU)<=i<=min(N,j+kl) !>
[in]	LDAB	!> LDAB is INTEGER !> The leading dimension of the array AB. LDAB >= KL+KU+1. !>
[in]	AFB	!> AFB is COMPLEX array, dimension (LDAFB,N) !> Details of the LU factorization of the band matrix A, as !> computed by CGBTRF. U is stored as an upper triangular !> band matrix with KL+KU superdiagonals in rows 1 to KL+KU+1, !> and the multipliers used during the factorization are stored !> in rows KL+KU+2 to 2*KL+KU+1. !>
[in]	LDAFB	!> LDAFB is INTEGER !> The leading dimension of the array AFB. LDAFB >= 2*KL+KU+1. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 113 of file cla_gbrpvgrw.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            N, KL, KU, NCOLS, LDAB, LDAFB
*     ..
*     .. Array Arguments ..
      COMPLEX            AB( LDAB, * ), AFB( LDAFB, * )
*     ..
*
*  =====================================================================
*
*     .. Local Scalars ..
      INTEGER            I, J, KD
      REAL               AMAX, UMAX, RPVGRW
      COMPLEX            ZDUM
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, max, min, real, aimag
*     ..
*     .. Statement Functions ..
      REAL               CABS1
*     ..
*     .. Statement Function Definitions ..
      cabs1( zdum ) = abs( real( zdum ) ) + abs( aimag( zdum ) )
*     ..
*     .. Executable Statements ..
*
      rpvgrw = 1.0
 
      kd = ku + 1
      DO j = 1, ncols
         amax = 0.0
         umax = 0.0
         DO i = max( j-ku, 1 ), min( j+kl, n )
            amax = max( cabs1( ab( kd+i-j, j ) ), amax )
         END DO
         DO i = max( j-ku, 1 ), j
            umax = max( cabs1( afb( kd+i-j, j ) ), umax )
         END DO
         IF ( umax /= 0.0 ) THEN
            rpvgrw = min( amax / umax, rpvgrw )
         END IF
      END DO
      cla_gbrpvgrw = rpvgrw
*
*     End of CLA_GBRPVGRW
*

Here is the call graph for this function:

Here is the caller graph for this function: