LAPACK 3.11.0
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches

◆ dgemlq()

subroutine dgemlq ( character  SIDE,
character  TRANS,
integer  M,
integer  N,
integer  K,
double precision, dimension( lda, * )  A,
integer  LDA,
double precision, dimension( * )  T,
integer  TSIZE,
double precision, dimension( ldc, * )  C,
integer  LDC,
double precision, dimension( * )  WORK,
integer  LWORK,
integer  INFO 
)

DGEMLQ

Purpose:
     DGEMLQ overwrites the general real M-by-N matrix C with

                    SIDE = 'L'     SIDE = 'R'
    TRANS = 'N':      Q * C          C * Q
    TRANS = 'T':      Q**T * C       C * Q**T
    where Q is a real orthogonal matrix defined as the product
    of blocked elementary reflectors computed by short wide LQ
    factorization (DGELQ)
Parameters
[in]SIDE
          SIDE is CHARACTER*1
          = 'L': apply Q or Q**T from the Left;
          = 'R': apply Q or Q**T from the Right.
[in]TRANS
          TRANS is CHARACTER*1
          = 'N':  No transpose, apply Q;
          = 'T':  Transpose, apply Q**T.
[in]M
          M is INTEGER
          The number of rows of the matrix A.  M >=0.
[in]N
          N is INTEGER
          The number of columns of the matrix C. N >= 0.
[in]K
          K is INTEGER
          The number of elementary reflectors whose product defines
          the matrix Q.
          If SIDE = 'L', M >= K >= 0;
          if SIDE = 'R', N >= K >= 0.
[in]A
          A is DOUBLE PRECISION array, dimension
                               (LDA,M) if SIDE = 'L',
                               (LDA,N) if SIDE = 'R'
          Part of the data structure to represent Q as returned by DGELQ.
[in]LDA
          LDA is INTEGER
          The leading dimension of the array A. LDA >= max(1,K).
[in]T
          T is DOUBLE PRECISION array, dimension (MAX(5,TSIZE)).
          Part of the data structure to represent Q as returned by DGELQ.
[in]TSIZE
          TSIZE is INTEGER
          The dimension of the array T. TSIZE >= 5.
[in,out]C
          C is DOUBLE PRECISION array, dimension (LDC,N)
          On entry, the M-by-N matrix C.
          On exit, C is overwritten by Q*C or Q**T*C or C*Q**T or C*Q.
[in]LDC
          LDC is INTEGER
          The leading dimension of the array C. LDC >= max(1,M).
[out]WORK
         (workspace) DOUBLE PRECISION array, dimension (MAX(1,LWORK))
[in]LWORK
          LWORK is INTEGER
          The dimension of the array WORK.
          If LWORK = -1, then a workspace query is assumed. The routine
          only calculates the size of the WORK array, returns this
          value as WORK(1), and no error message related to WORK 
          is issued by XERBLA.
[out]INFO
          INFO is INTEGER
          = 0:  successful exit
          < 0:  if INFO = -i, the i-th argument had an illegal value
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Further Details
 These details are particular for this LAPACK implementation. Users should not 
 take them for granted. These details may change in the future, and are not likely
 true for another LAPACK implementation. These details are relevant if one wants
 to try to understand the code. They are not part of the interface.

 In this version,

          T(2): row block size (MB)
          T(3): column block size (NB)
          T(6:TSIZE): data structure needed for Q, computed by
                           DLASWLQ or DGELQT

  Depending on the matrix dimensions M and N, and row and column
  block sizes MB and NB returned by ILAENV, DGELQ will use either
  DLASWLQ (if the matrix is wide-and-short) or DGELQT to compute
  the LQ factorization.
  This version of DGEMLQ will use either DLAMSWLQ or DGEMLQT to 
  multiply matrix Q by another matrix.
  Further Details in DLAMSWLQ or DGEMLQT.

Definition at line 169 of file dgemlq.f.

171*
172* -- LAPACK computational routine --
173* -- LAPACK is a software package provided by Univ. of Tennessee, --
174* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
175*
176* .. Scalar Arguments ..
177 CHARACTER SIDE, TRANS
178 INTEGER INFO, LDA, M, N, K, TSIZE, LWORK, LDC
179* ..
180* .. Array Arguments ..
181 DOUBLE PRECISION A( LDA, * ), T( * ), C( LDC, * ), WORK( * )
182* ..
183*
184* =====================================================================
185*
186* ..
187* .. Local Scalars ..
188 LOGICAL LEFT, RIGHT, TRAN, NOTRAN, LQUERY
189 INTEGER MB, NB, LW, NBLCKS, MN
190* ..
191* .. External Functions ..
192 LOGICAL LSAME
193 EXTERNAL lsame
194* ..
195* .. External Subroutines ..
196 EXTERNAL dlamswlq, dgemlqt, xerbla
197* ..
198* .. Intrinsic Functions ..
199 INTRINSIC int, max, min, mod
200* ..
201* .. Executable Statements ..
202*
203* Test the input arguments
204*
205 lquery = lwork.EQ.-1
206 notran = lsame( trans, 'N' )
207 tran = lsame( trans, 'T' )
208 left = lsame( side, 'L' )
209 right = lsame( side, 'R' )
210*
211 mb = int( t( 2 ) )
212 nb = int( t( 3 ) )
213 IF( left ) THEN
214 lw = n * mb
215 mn = m
216 ELSE
217 lw = m * mb
218 mn = n
219 END IF
220*
221 IF( ( nb.GT.k ) .AND. ( mn.GT.k ) ) THEN
222 IF( mod( mn - k, nb - k ) .EQ. 0 ) THEN
223 nblcks = ( mn - k ) / ( nb - k )
224 ELSE
225 nblcks = ( mn - k ) / ( nb - k ) + 1
226 END IF
227 ELSE
228 nblcks = 1
229 END IF
230*
231 info = 0
232 IF( .NOT.left .AND. .NOT.right ) THEN
233 info = -1
234 ELSE IF( .NOT.tran .AND. .NOT.notran ) THEN
235 info = -2
236 ELSE IF( m.LT.0 ) THEN
237 info = -3
238 ELSE IF( n.LT.0 ) THEN
239 info = -4
240 ELSE IF( k.LT.0 .OR. k.GT.mn ) THEN
241 info = -5
242 ELSE IF( lda.LT.max( 1, k ) ) THEN
243 info = -7
244 ELSE IF( tsize.LT.5 ) THEN
245 info = -9
246 ELSE IF( ldc.LT.max( 1, m ) ) THEN
247 info = -11
248 ELSE IF( ( lwork.LT.max( 1, lw ) ) .AND. ( .NOT.lquery ) ) THEN
249 info = -13
250 END IF
251*
252 IF( info.EQ.0 ) THEN
253 work( 1 ) = lw
254 END IF
255*
256 IF( info.NE.0 ) THEN
257 CALL xerbla( 'DGEMLQ', -info )
258 RETURN
259 ELSE IF( lquery ) THEN
260 RETURN
261 END IF
262*
263* Quick return if possible
264*
265 IF( min( m, n, k ).EQ.0 ) THEN
266 RETURN
267 END IF
268*
269 IF( ( left .AND. m.LE.k ) .OR. ( right .AND. n.LE.k )
270 $ .OR. ( nb.LE.k ) .OR. ( nb.GE.max( m, n, k ) ) ) THEN
271 CALL dgemlqt( side, trans, m, n, k, mb, a, lda,
272 $ t( 6 ), mb, c, ldc, work, info )
273 ELSE
274 CALL dlamswlq( side, trans, m, n, k, mb, nb, a, lda, t( 6 ),
275 $ mb, c, ldc, work, lwork, info )
276 END IF
277*
278 work( 1 ) = lw
279*
280 RETURN
281*
282* End of DGEMLQ
283*
subroutine dlamswlq(SIDE, TRANS, M, N, K, MB, NB, A, LDA, T, LDT, C, LDC, WORK, LWORK, INFO)
DLAMSWLQ
Definition: dlamswlq.f:195
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
subroutine dgemlqt(SIDE, TRANS, M, N, K, MB, V, LDV, T, LDT, C, LDC, WORK, INFO)
DGEMLQT
Definition: dgemlqt.f:168
Here is the call graph for this function:
Here is the caller graph for this function: