LAPACK  3.10.1 LAPACK: Linear Algebra PACKage

## ◆ sgtsvx()

 subroutine sgtsvx ( character FACT, character TRANS, integer N, integer NRHS, real, dimension( * ) DL, real, dimension( * ) D, real, dimension( * ) DU, real, dimension( * ) DLF, real, dimension( * ) DF, real, dimension( * ) DUF, real, dimension( * ) DU2, integer, dimension( * ) IPIV, real, dimension( ldb, * ) B, integer LDB, real, dimension( ldx, * ) X, integer LDX, real RCOND, real, dimension( * ) FERR, real, dimension( * ) BERR, real, dimension( * ) WORK, integer, dimension( * ) IWORK, integer INFO )

SGTSVX computes the solution to system of linear equations A * X = B for GT matrices

Purpose:
``` SGTSVX uses the LU factorization to compute the solution to a real
system of linear equations A * X = B or A**T * X = B,
where A is a tridiagonal matrix of order N and X and B are N-by-NRHS
matrices.

Error bounds on the solution and a condition estimate are also
provided.```
Description:
``` The following steps are performed:

1. If FACT = 'N', the LU decomposition is used to factor the matrix A
as A = L * U, where L is a product of permutation and unit lower
bidiagonal matrices and U is upper triangular with nonzeros in
only the main diagonal and first two superdiagonals.

2. If some U(i,i)=0, so that U is exactly singular, then the routine
returns with INFO = i. Otherwise, the factored form of A is used
to estimate the condition number of the matrix A.  If the
reciprocal of the condition number is less than machine precision,
INFO = N+1 is returned as a warning, but the routine still goes on
to solve for X and compute error bounds as described below.

3. The system of equations is solved for X using the factored form
of A.

4. Iterative refinement is applied to improve the computed solution
matrix and calculate error bounds and backward error estimates
for it.```
Parameters
 [in] FACT ``` FACT is CHARACTER*1 Specifies whether or not the factored form of A has been supplied on entry. = 'F': DLF, DF, DUF, DU2, and IPIV contain the factored form of A; DL, D, DU, DLF, DF, DUF, DU2 and IPIV will not be modified. = 'N': The matrix will be copied to DLF, DF, and DUF and factored.``` [in] TRANS ``` TRANS is CHARACTER*1 Specifies the form of the system of equations: = 'N': A * X = B (No transpose) = 'T': A**T * X = B (Transpose) = 'C': A**H * X = B (Conjugate transpose = Transpose)``` [in] N ``` N is INTEGER The order of the matrix A. N >= 0.``` [in] NRHS ``` NRHS is INTEGER The number of right hand sides, i.e., the number of columns of the matrix B. NRHS >= 0.``` [in] DL ``` DL is REAL array, dimension (N-1) The (n-1) subdiagonal elements of A.``` [in] D ``` D is REAL array, dimension (N) The n diagonal elements of A.``` [in] DU ``` DU is REAL array, dimension (N-1) The (n-1) superdiagonal elements of A.``` [in,out] DLF ``` DLF is REAL array, dimension (N-1) If FACT = 'F', then DLF is an input argument and on entry contains the (n-1) multipliers that define the matrix L from the LU factorization of A as computed by SGTTRF. If FACT = 'N', then DLF is an output argument and on exit contains the (n-1) multipliers that define the matrix L from the LU factorization of A.``` [in,out] DF ``` DF is REAL array, dimension (N) If FACT = 'F', then DF is an input argument and on entry contains the n diagonal elements of the upper triangular matrix U from the LU factorization of A. If FACT = 'N', then DF is an output argument and on exit contains the n diagonal elements of the upper triangular matrix U from the LU factorization of A.``` [in,out] DUF ``` DUF is REAL array, dimension (N-1) If FACT = 'F', then DUF is an input argument and on entry contains the (n-1) elements of the first superdiagonal of U. If FACT = 'N', then DUF is an output argument and on exit contains the (n-1) elements of the first superdiagonal of U.``` [in,out] DU2 ``` DU2 is REAL array, dimension (N-2) If FACT = 'F', then DU2 is an input argument and on entry contains the (n-2) elements of the second superdiagonal of U. If FACT = 'N', then DU2 is an output argument and on exit contains the (n-2) elements of the second superdiagonal of U.``` [in,out] IPIV ``` IPIV is INTEGER array, dimension (N) If FACT = 'F', then IPIV is an input argument and on entry contains the pivot indices from the LU factorization of A as computed by SGTTRF. If FACT = 'N', then IPIV is an output argument and on exit contains the pivot indices from the LU factorization of A; row i of the matrix was interchanged with row IPIV(i). IPIV(i) will always be either i or i+1; IPIV(i) = i indicates a row interchange was not required.``` [in] B ``` B is REAL array, dimension (LDB,NRHS) The N-by-NRHS right hand side matrix B.``` [in] LDB ``` LDB is INTEGER The leading dimension of the array B. LDB >= max(1,N).``` [out] X ``` X is REAL array, dimension (LDX,NRHS) If INFO = 0 or INFO = N+1, the N-by-NRHS solution matrix X.``` [in] LDX ``` LDX is INTEGER The leading dimension of the array X. LDX >= max(1,N).``` [out] RCOND ``` RCOND is REAL The estimate of the reciprocal condition number of the matrix A. If RCOND is less than the machine precision (in particular, if RCOND = 0), the matrix is singular to working precision. This condition is indicated by a return code of INFO > 0.``` [out] FERR ``` FERR is REAL array, dimension (NRHS) The estimated forward error bound for each solution vector X(j) (the j-th column of the solution matrix X). If XTRUE is the true solution corresponding to X(j), FERR(j) is an estimated upper bound for the magnitude of the largest element in (X(j) - XTRUE) divided by the magnitude of the largest element in X(j). The estimate is as reliable as the estimate for RCOND, and is almost always a slight overestimate of the true error.``` [out] BERR ``` BERR is REAL array, dimension (NRHS) The componentwise relative backward error of each solution vector X(j) (i.e., the smallest relative change in any element of A or B that makes X(j) an exact solution).``` [out] WORK ` WORK is REAL array, dimension (3*N)` [out] IWORK ` IWORK is INTEGER array, dimension (N)` [out] INFO ``` INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value > 0: if INFO = i, and i is <= N: U(i,i) is exactly zero. The factorization has not been completed unless i = N, but the factor U is exactly singular, so the solution and error bounds could not be computed. RCOND = 0 is returned. = N+1: U is nonsingular, but RCOND is less than machine precision, meaning that the matrix is singular to working precision. Nevertheless, the solution and error bounds are computed because there are a number of situations where the computed solution can be more accurate than the value of RCOND would suggest.```

Definition at line 290 of file sgtsvx.f.

293 *
294 * -- LAPACK driver routine --
295 * -- LAPACK is a software package provided by Univ. of Tennessee, --
296 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
297 *
298 * .. Scalar Arguments ..
299  CHARACTER FACT, TRANS
300  INTEGER INFO, LDB, LDX, N, NRHS
301  REAL RCOND
302 * ..
303 * .. Array Arguments ..
304  INTEGER IPIV( * ), IWORK( * )
305  REAL B( LDB, * ), BERR( * ), D( * ), DF( * ),
306  \$ DL( * ), DLF( * ), DU( * ), DU2( * ), DUF( * ),
307  \$ FERR( * ), WORK( * ), X( LDX, * )
308 * ..
309 *
310 * =====================================================================
311 *
312 * .. Parameters ..
313  REAL ZERO
314  parameter( zero = 0.0e+0 )
315 * ..
316 * .. Local Scalars ..
317  LOGICAL NOFACT, NOTRAN
318  CHARACTER NORM
319  REAL ANORM
320 * ..
321 * .. External Functions ..
322  LOGICAL LSAME
323  REAL SLAMCH, SLANGT
324  EXTERNAL lsame, slamch, slangt
325 * ..
326 * .. External Subroutines ..
327  EXTERNAL scopy, sgtcon, sgtrfs, sgttrf, sgttrs, slacpy,
328  \$ xerbla
329 * ..
330 * .. Intrinsic Functions ..
331  INTRINSIC max
332 * ..
333 * .. Executable Statements ..
334 *
335  info = 0
336  nofact = lsame( fact, 'N' )
337  notran = lsame( trans, 'N' )
338  IF( .NOT.nofact .AND. .NOT.lsame( fact, 'F' ) ) THEN
339  info = -1
340  ELSE IF( .NOT.notran .AND. .NOT.lsame( trans, 'T' ) .AND. .NOT.
341  \$ lsame( trans, 'C' ) ) THEN
342  info = -2
343  ELSE IF( n.LT.0 ) THEN
344  info = -3
345  ELSE IF( nrhs.LT.0 ) THEN
346  info = -4
347  ELSE IF( ldb.LT.max( 1, n ) ) THEN
348  info = -14
349  ELSE IF( ldx.LT.max( 1, n ) ) THEN
350  info = -16
351  END IF
352  IF( info.NE.0 ) THEN
353  CALL xerbla( 'SGTSVX', -info )
354  RETURN
355  END IF
356 *
357  IF( nofact ) THEN
358 *
359 * Compute the LU factorization of A.
360 *
361  CALL scopy( n, d, 1, df, 1 )
362  IF( n.GT.1 ) THEN
363  CALL scopy( n-1, dl, 1, dlf, 1 )
364  CALL scopy( n-1, du, 1, duf, 1 )
365  END IF
366  CALL sgttrf( n, dlf, df, duf, du2, ipiv, info )
367 *
368 * Return if INFO is non-zero.
369 *
370  IF( info.GT.0 )THEN
371  rcond = zero
372  RETURN
373  END IF
374  END IF
375 *
376 * Compute the norm of the matrix A.
377 *
378  IF( notran ) THEN
379  norm = '1'
380  ELSE
381  norm = 'I'
382  END IF
383  anorm = slangt( norm, n, dl, d, du )
384 *
385 * Compute the reciprocal of the condition number of A.
386 *
387  CALL sgtcon( norm, n, dlf, df, duf, du2, ipiv, anorm, rcond, work,
388  \$ iwork, info )
389 *
390 * Compute the solution vectors X.
391 *
392  CALL slacpy( 'Full', n, nrhs, b, ldb, x, ldx )
393  CALL sgttrs( trans, n, nrhs, dlf, df, duf, du2, ipiv, x, ldx,
394  \$ info )
395 *
396 * Use iterative refinement to improve the computed solutions and
397 * compute error bounds and backward error estimates for them.
398 *
399  CALL sgtrfs( trans, n, nrhs, dl, d, du, dlf, df, duf, du2, ipiv,
400  \$ b, ldb, x, ldx, ferr, berr, work, iwork, info )
401 *
402 * Set INFO = N+1 if the matrix is singular to working precision.
403 *
404  IF( rcond.LT.slamch( 'Epsilon' ) )
405  \$ info = n + 1
406 *
407  RETURN
408 *
409 * End of SGTSVX
410 *
subroutine slacpy(UPLO, M, N, A, LDA, B, LDB)
SLACPY copies all or part of one two-dimensional array to another.
Definition: slacpy.f:103
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
subroutine sgttrf(N, DL, D, DU, DU2, IPIV, INFO)
SGTTRF
Definition: sgttrf.f:124
subroutine sgttrs(TRANS, N, NRHS, DL, D, DU, DU2, IPIV, B, LDB, INFO)
SGTTRS
Definition: sgttrs.f:138
subroutine sgtcon(NORM, N, DL, D, DU, DU2, IPIV, ANORM, RCOND, WORK, IWORK, INFO)
SGTCON
Definition: sgtcon.f:146
subroutine sgtrfs(TRANS, N, NRHS, DL, D, DU, DLF, DF, DUF, DU2, IPIV, B, LDB, X, LDX, FERR, BERR, WORK, IWORK, INFO)
SGTRFS
Definition: sgtrfs.f:209
real function slangt(NORM, N, DL, D, DU)
SLANGT returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value ...
Definition: slangt.f:106
subroutine scopy(N, SX, INCX, SY, INCY)
SCOPY
Definition: scopy.f:82
real function slamch(CMACH)
SLAMCH
Definition: slamch.f:68
Here is the call graph for this function:
Here is the caller graph for this function: