cgelq2()

subroutine cgelq2	(	integer	m,
		integer	n,
		complex, dimension( lda, * )	a,
		integer	lda,
		complex, dimension( * )	tau,
		complex, dimension( * )	work,
		integer	info )

CGELQ2 computes the LQ factorization of a general rectangular matrix using an unblocked algorithm.

Download CGELQ2 + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> CGELQ2 computes an LQ factorization of a complex m-by-n matrix A:
!>
!>    A = ( L 0 ) *  Q
!>
!> where:
!>
!>    Q is a n-by-n orthogonal matrix;
!>    L is a lower-triangular m-by-m matrix;
!>    0 is a m-by-(n-m) zero matrix, if m < n.
!>
!> 

Parameters

[in]	M	!> M is INTEGER !> The number of rows of the matrix A. M >= 0. !>
[in]	N	!> N is INTEGER !> The number of columns of the matrix A. N >= 0. !>
[in,out]	A	!> A is COMPLEX array, dimension (LDA,N) !> On entry, the m by n matrix A. !> On exit, the elements on and below the diagonal of the array !> contain the m by min(m,n) lower trapezoidal matrix L (L is !> lower triangular if m <= n); the elements above the diagonal, !> with the array TAU, represent the unitary matrix Q as a !> product of elementary reflectors (see Further Details). !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= max(1,M). !>
[out]	TAU	!> TAU is COMPLEX array, dimension (min(M,N)) !> The scalar factors of the elementary reflectors (see Further !> Details). !>
[out]	WORK	!> WORK is COMPLEX array, dimension (M) !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -i, the i-th argument had an illegal value !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Further Details:

!>
!>  The matrix Q is represented as a product of elementary reflectors
!>
!>     Q = H(k)**H . . . H(2)**H H(1)**H, where k = min(m,n).
!>
!>  Each H(i) has the form
!>
!>     H(i) = I - tau * v * v**H
!>
!>  where tau is a complex scalar, and v is a complex vector with
!>  v(1:i-1) = 0 and v(i) = 1; conjg(v(i+1:n)) is stored on exit in
!>  A(i,i+1:n), and tau in TAU(i).
!> 

Definition at line 126 of file cgelq2.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            INFO, LDA, M, N
*     ..
*     .. Array Arguments ..
      COMPLEX            A( LDA, * ), TAU( * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Local Scalars ..
      INTEGER            I, K
*     ..
*     .. External Subroutines ..
      EXTERNAL           clacgv, clarf1f, clarfg, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min
*     ..
*     .. Executable Statements ..
*
*     Test the input arguments
*
      info = 0
      IF( m.LT.0 ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( lda.LT.max( 1, m ) ) THEN
         info = -4
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CGELQ2', -info )
         RETURN
      END IF
*
      k = min( m, n )
*
      DO 10 i = 1, k
*
*        Generate elementary reflector H(i) to annihilate A(i,i+1:n)
*
         CALL clacgv( n-i+1, a( i, i ), lda )
         CALL clarfg( n-i+1, a( i, i ), a( i, min( i+1, n ) ), lda,
     $                tau( i ) )
         IF( i.LT.m ) THEN
*
*           Apply H(i) to A(i+1:m,i:n) from the right
*
            CALL clarf1f( 'Right', m-i, n-i+1, a( i, i ), lda,
     $                    tau( i ), a( i+1, i ), lda, work )
         END IF
         CALL clacgv( n-i+1, a( i, i ), lda )
   10 CONTINUE
      RETURN
*
*     End of CGELQ2
*

Here is the call graph for this function:

Here is the caller graph for this function: