zptcon()

subroutine zptcon	(	integer	n,
		double precision, dimension( * )	d,
		complex*16, dimension( * )	e,
		double precision	anorm,
		double precision	rcond,
		double precision, dimension( * )	rwork,
		integer	info )

ZPTCON

Download ZPTCON + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> ZPTCON computes the reciprocal of the condition number (in the
!> 1-norm) of a complex Hermitian positive definite tridiagonal matrix
!> using the factorization A = L*D*L**H or A = U**H*D*U computed by
!> ZPTTRF.
!>
!> Norm(inv(A)) is computed by a direct method, and the reciprocal of
!> the condition number is computed as
!>                  RCOND = 1 / (ANORM * norm(inv(A))).
!> 

Parameters

[in]	N	!> N is INTEGER !> The order of the matrix A. N >= 0. !>
[in]	D	!> D is DOUBLE PRECISION array, dimension (N) !> The n diagonal elements of the diagonal matrix D from the !> factorization of A, as computed by ZPTTRF. !>
[in]	E	!> E is COMPLEX*16 array, dimension (N-1) !> The (n-1) off-diagonal elements of the unit bidiagonal factor !> U or L from the factorization of A, as computed by ZPTTRF. !>
[in]	ANORM	!> ANORM is DOUBLE PRECISION !> The 1-norm of the original matrix A. !>
[out]	RCOND	!> RCOND is DOUBLE PRECISION !> The reciprocal of the condition number of the matrix A, !> computed as RCOND = 1/(ANORM * AINVNM), where AINVNM is the !> 1-norm of inv(A) computed in this routine. !>
[out]	RWORK	!> RWORK is DOUBLE PRECISION array, dimension (N) !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -i, the i-th argument had an illegal value !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Further Details:

!>
!>  The method used is described in Nicholas J. Higham, , SIAM J. Sci. Stat. Comput., Vol. 7, No. 1, January 1986.
!> 

Definition at line 116 of file zptcon.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            INFO, N
      DOUBLE PRECISION   ANORM, RCOND
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   D( * ), RWORK( * )
      COMPLEX*16         E( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ONE, ZERO
      parameter( one = 1.0d+0, zero = 0.0d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, IX
      DOUBLE PRECISION   AINVNM
*     ..
*     .. External Functions ..
      INTEGER            IDAMAX
      EXTERNAL           idamax
*     ..
*     .. External Subroutines ..
      EXTERNAL           xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs
*     ..
*     .. Executable Statements ..
*
*     Test the input arguments.
*
      info = 0
      IF( n.LT.0 ) THEN
         info = -1
      ELSE IF( anorm.LT.zero ) THEN
         info = -4
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'ZPTCON', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      rcond = zero
      IF( n.EQ.0 ) THEN
         rcond = one
         RETURN
      ELSE IF( anorm.EQ.zero ) THEN
         RETURN
      END IF
*
*     Check that D(1:N) is positive.
*
      DO 10 i = 1, n
         IF( d( i ).LE.zero )
     $      RETURN
   10 CONTINUE
*
*     Solve M(A) * x = e, where M(A) = (m(i,j)) is given by
*
*        m(i,j) =  abs(A(i,j)), i = j,
*        m(i,j) = -abs(A(i,j)), i .ne. j,
*
*     and e = [ 1, 1, ..., 1 ]**T.  Note M(A) = M(L)*D*M(L)**H.
*
*     Solve M(L) * x = e.
*
      rwork( 1 ) = one
      DO 20 i = 2, n
         rwork( i ) = one + rwork( i-1 )*abs( e( i-1 ) )
   20 CONTINUE
*
*     Solve D * M(L)**H * x = b.
*
      rwork( n ) = rwork( n ) / d( n )
      DO 30 i = n - 1, 1, -1
         rwork( i ) = rwork( i ) / d( i ) + rwork( i+1 )*abs( e( i ) )
   30 CONTINUE
*
*     Compute AINVNM = max(x(i)), 1<=i<=n.
*
      ix = idamax( n, rwork, 1 )
      ainvnm = abs( rwork( ix ) )
*
*     Compute the reciprocal condition number.
*
      IF( ainvnm.NE.zero )
     $   rcond = ( one / ainvnm ) / anorm
*
      RETURN
*
*     End of ZPTCON
*

Here is the call graph for this function:

Here is the caller graph for this function: