cunm22()

subroutine cunm22	(	character	side,
		character	trans,
		integer	m,
		integer	n,
		integer	n1,
		integer	n2,
		complex, dimension( ldq, * )	q,
		integer	ldq,
		complex, dimension( ldc, * )	c,
		integer	ldc,
		complex, dimension( * )	work,
		integer	lwork,
		integer	info )

CUNM22 multiplies a general matrix by a banded unitary matrix.

Download CUNM22 + dependencies [TGZ] [ZIP] [TXT]

Purpose

!>
!>  CUNM22 overwrites the general complex M-by-N matrix C with
!>
!>                  SIDE = 'L'     SIDE = 'R'
!>  TRANS = 'N':      Q * C          C * Q
!>  TRANS = 'C':      Q**H * C       C * Q**H
!>
!>  where Q is a complex unitary matrix of order NQ, with NQ = M if
!>  SIDE = 'L' and NQ = N if SIDE = 'R'.
!>  The unitary matrix Q processes a 2-by-2 block structure
!>
!>         [  Q11  Q12  ]
!>     Q = [            ]
!>         [  Q21  Q22  ],
!>
!>  where Q12 is an N1-by-N1 lower triangular matrix and Q21 is an
!>  N2-by-N2 upper triangular matrix.
!> 

Parameters

[in]	SIDE	!> SIDE is CHARACTER*1 !> = 'L': apply Q or Q**H from the Left; !> = 'R': apply Q or Q**H from the Right. !>
[in]	TRANS	!> TRANS is CHARACTER*1 !> = 'N': apply Q (No transpose); !> = 'C': apply Q**H (Conjugate transpose). !>
[in]	M	!> M is INTEGER !> The number of rows of the matrix C. M >= 0. !>
[in]	N	!> N is INTEGER !> The number of columns of the matrix C. N >= 0. !>
[in]	N1
[in]	N2	!> N1 is INTEGER !> N2 is INTEGER !> The dimension of Q12 and Q21, respectively. N1, N2 >= 0. !> The following requirement must be satisfied: !> N1 + N2 = M if SIDE = 'L' and N1 + N2 = N if SIDE = 'R'. !>
[in]	Q	!> Q is COMPLEX array, dimension !> (LDQ,M) if SIDE = 'L' !> (LDQ,N) if SIDE = 'R' !>
[in]	LDQ	!> LDQ is INTEGER !> The leading dimension of the array Q. !> LDQ >= max(1,M) if SIDE = 'L'; LDQ >= max(1,N) if SIDE = 'R'. !>
[in,out]	C	!> C is COMPLEX array, dimension (LDC,N) !> On entry, the M-by-N matrix C. !> On exit, C is overwritten by Q*C or Q**H*C or C*Q**H or C*Q. !>
[in]	LDC	!> LDC is INTEGER !> The leading dimension of the array C. LDC >= max(1,M). !>
[out]	WORK	!> WORK is COMPLEX array, dimension (MAX(1,LWORK)) !> On exit, if INFO = 0, WORK(1) returns the optimal LWORK. !>
[in]	LWORK	!> LWORK is INTEGER !> The dimension of the array WORK. !> If SIDE = 'L', LWORK >= max(1,N); !> if SIDE = 'R', LWORK >= max(1,M). !> For optimum performance LWORK >= M*N. !> !> If LWORK = -1, then a workspace query is assumed; the routine !> only calculates the optimal size of the WORK array, returns !> this value as the first entry of the WORK array, and no error !> message related to LWORK is issued by XERBLA. !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -i, the i-th argument had an illegal value !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 158 of file cunm22.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
      IMPLICIT NONE
*
*     .. Scalar Arguments ..
      CHARACTER          SIDE, TRANS
      INTEGER            M, N, N1, N2, LDQ, LDC, LWORK, INFO
*     ..
*     .. Array Arguments ..
      COMPLEX            Q( LDQ, * ), C( LDC, * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      COMPLEX            ONE
      parameter( one = ( 1.0e+0, 0.0e+0 ) )
*
*     .. Local Scalars ..
      LOGICAL            LEFT, LQUERY, NOTRAN
      INTEGER            I, LDWORK, LEN, LWKOPT, NB, NQ, NW
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           lsame
*     ..
*     .. External Subroutines ..
      EXTERNAL           cgemm, clacpy, ctrmm, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          cmplx, max, min
*     ..
*     .. Executable Statements ..
*
*     Test the input arguments
*
      info = 0
      left = lsame( side, 'L' )
      notran = lsame( trans, 'N' )
      lquery = ( lwork.EQ.-1 )
*
*     NQ is the order of Q;
*     NW is the minimum dimension of WORK.
*
      IF( left ) THEN
         nq = m
      ELSE
         nq = n
      END IF
      nw = nq
      IF( n1.EQ.0 .OR. n2.EQ.0 ) nw = 1
      IF( .NOT.left .AND. .NOT.lsame( side, 'R' ) ) THEN
         info = -1
      ELSE IF( .NOT.lsame( trans, 'N' ) .AND.
     $         .NOT.lsame( trans, 'C' ) )
     $          THEN
         info = -2
      ELSE IF( m.LT.0 ) THEN
         info = -3
      ELSE IF( n.LT.0 ) THEN
         info = -4
      ELSE IF( n1.LT.0 .OR. n1+n2.NE.nq ) THEN
         info = -5
      ELSE IF( n2.LT.0 ) THEN
         info = -6
      ELSE IF( ldq.LT.max( 1, nq ) ) THEN
         info = -8
      ELSE IF( ldc.LT.max( 1, m ) ) THEN
         info = -10
      ELSE IF( lwork.LT.nw .AND. .NOT.lquery ) THEN
         info = -12
      END IF
*
      IF( info.EQ.0 ) THEN
         lwkopt = m*n
         work( 1 ) = cmplx( lwkopt )
      END IF
*
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CUNM22', -info )
         RETURN
      ELSE IF( lquery ) THEN
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( m.EQ.0 .OR. n.EQ.0 ) THEN
         work( 1 ) = 1
         RETURN
      END IF
*
*     Degenerate cases (N1 = 0 or N2 = 0) are handled using CTRMM.
*
      IF( n1.EQ.0 ) THEN
         CALL ctrmm( side, 'Upper', trans, 'Non-Unit', m, n, one,
     $               q, ldq, c, ldc )
         work( 1 ) = one
         RETURN
      ELSE IF( n2.EQ.0 ) THEN
         CALL ctrmm( side, 'Lower', trans, 'Non-Unit', m, n, one,
     $               q, ldq, c, ldc )
         work( 1 ) = one
         RETURN
      END IF
*
*     Compute the largest chunk size available from the workspace.
*
      nb = max( 1, min( lwork, lwkopt ) / nq )
*
      IF( left ) THEN
         IF( notran ) THEN
            DO i = 1, n, nb
               len = min( nb, n-i+1 )
               ldwork = m
*
*              Multiply bottom part of C by Q12.
*
               CALL clacpy( 'All', n1, len, c( n2+1, i ), ldc, work,
     $                      ldwork )
               CALL ctrmm( 'Left', 'Lower', 'No Transpose',
     $                     'Non-Unit',
     $                     n1, len, one, q( 1, n2+1 ), ldq, work,
     $                     ldwork )
*
*              Multiply top part of C by Q11.
*
               CALL cgemm( 'No Transpose', 'No Transpose', n1, len,
     $                     n2,
     $                     one, q, ldq, c( 1, i ), ldc, one, work,
     $                     ldwork )
*
*              Multiply top part of C by Q21.
*
               CALL clacpy( 'All', n2, len, c( 1, i ), ldc,
     $                      work( n1+1 ), ldwork )
               CALL ctrmm( 'Left', 'Upper', 'No Transpose',
     $                     'Non-Unit',
     $                     n2, len, one, q( n1+1, 1 ), ldq,
     $                     work( n1+1 ), ldwork )
*
*              Multiply bottom part of C by Q22.
*
               CALL cgemm( 'No Transpose', 'No Transpose', n2, len,
     $                     n1,
     $                     one, q( n1+1, n2+1 ), ldq, c( n2+1, i ), ldc,
     $                     one, work( n1+1 ), ldwork )
*
*              Copy everything back.
*
               CALL clacpy( 'All', m, len, work, ldwork, c( 1, i ),
     $                      ldc )
            END DO
         ELSE
            DO i = 1, n, nb
               len = min( nb, n-i+1 )
               ldwork = m
*
*              Multiply bottom part of C by Q21**H.
*
               CALL clacpy( 'All', n2, len, c( n1+1, i ), ldc, work,
     $                      ldwork )
               CALL ctrmm( 'Left', 'Upper', 'Conjugate', 'Non-Unit',
     $                     n2, len, one, q( n1+1, 1 ), ldq, work,
     $                     ldwork )
*
*              Multiply top part of C by Q11**H.
*
               CALL cgemm( 'Conjugate', 'No Transpose', n2, len, n1,
     $                     one, q, ldq, c( 1, i ), ldc, one, work,
     $                     ldwork )
*
*              Multiply top part of C by Q12**H.
*
               CALL clacpy( 'All', n1, len, c( 1, i ), ldc,
     $                      work( n2+1 ), ldwork )
               CALL ctrmm( 'Left', 'Lower', 'Conjugate', 'Non-Unit',
     $                     n1, len, one, q( 1, n2+1 ), ldq,
     $                     work( n2+1 ), ldwork )
*
*              Multiply bottom part of C by Q22**H.
*
               CALL cgemm( 'Conjugate', 'No Transpose', n1, len, n2,
     $                     one, q( n1+1, n2+1 ), ldq, c( n1+1, i ), ldc,
     $                     one, work( n2+1 ), ldwork )
*
*              Copy everything back.
*
               CALL clacpy( 'All', m, len, work, ldwork, c( 1, i ),
     $                      ldc )
            END DO
         END IF
      ELSE
         IF( notran ) THEN
            DO i = 1, m, nb
               len = min( nb, m-i+1 )
               ldwork = len
*
*              Multiply right part of C by Q21.
*
               CALL clacpy( 'All', len, n2, c( i, n1+1 ), ldc, work,
     $                      ldwork )
               CALL ctrmm( 'Right', 'Upper', 'No Transpose',
     $                     'Non-Unit',
     $                     len, n2, one, q( n1+1, 1 ), ldq, work,
     $                     ldwork )
*
*              Multiply left part of C by Q11.
*
               CALL cgemm( 'No Transpose', 'No Transpose', len, n2,
     $                     n1,
     $                     one, c( i, 1 ), ldc, q, ldq, one, work,
     $                     ldwork )
*
*              Multiply left part of C by Q12.
*
               CALL clacpy( 'All', len, n1, c( i, 1 ), ldc,
     $                      work( 1 + n2*ldwork ), ldwork )
               CALL ctrmm( 'Right', 'Lower', 'No Transpose',
     $                     'Non-Unit',
     $                     len, n1, one, q( 1, n2+1 ), ldq,
     $                     work( 1 + n2*ldwork ), ldwork )
*
*              Multiply right part of C by Q22.
*
               CALL cgemm( 'No Transpose', 'No Transpose', len, n1,
     $                     n2,
     $                     one, c( i, n1+1 ), ldc, q( n1+1, n2+1 ), ldq,
     $                     one, work( 1 + n2*ldwork ), ldwork )
*
*              Copy everything back.
*
               CALL clacpy( 'All', len, n, work, ldwork, c( i, 1 ),
     $                      ldc )
            END DO
         ELSE
            DO i = 1, m, nb
               len = min( nb, m-i+1 )
               ldwork = len
*
*              Multiply right part of C by Q12**H.
*
               CALL clacpy( 'All', len, n1, c( i, n2+1 ), ldc, work,
     $                      ldwork )
               CALL ctrmm( 'Right', 'Lower', 'Conjugate', 'Non-Unit',
     $                     len, n1, one, q( 1, n2+1 ), ldq, work,
     $                     ldwork )
*
*              Multiply left part of C by Q11**H.
*
               CALL cgemm( 'No Transpose', 'Conjugate', len, n1, n2,
     $                     one, c( i, 1 ), ldc, q, ldq, one, work,
     $                     ldwork )
*
*              Multiply left part of C by Q21**H.
*
               CALL clacpy( 'All', len, n2, c( i, 1 ), ldc,
     $                      work( 1 + n1*ldwork ), ldwork )
               CALL ctrmm( 'Right', 'Upper', 'Conjugate', 'Non-Unit',
     $                     len, n2, one, q( n1+1, 1 ), ldq,
     $                     work( 1 + n1*ldwork ), ldwork )
*
*              Multiply right part of C by Q22**H.
*
               CALL cgemm( 'No Transpose', 'Conjugate', len, n2, n1,
     $                     one, c( i, n2+1 ), ldc, q( n1+1, n2+1 ), ldq,
     $                     one, work( 1 + n1*ldwork ), ldwork )
*
*              Copy everything back.
*
               CALL clacpy( 'All', len, n, work, ldwork, c( i, 1 ),
     $                      ldc )
            END DO
         END IF
      END IF
*
      work( 1 ) = cmplx( lwkopt )
      RETURN
*
*     End of CUNM22
*

Here is the call graph for this function:

Here is the caller graph for this function: