slanv2()

subroutine slanv2	(	real	a,
		real	b,
		real	c,
		real	d,
		real	rt1r,
		real	rt1i,
		real	rt2r,
		real	rt2i,
		real	cs,
		real	sn
	)

SLANV2 computes the Schur factorization of a real 2-by-2 nonsymmetric matrix in standard form.

Download SLANV2 + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 SLANV2 computes the Schur factorization of a real 2-by-2 nonsymmetric
 matrix in standard form:

      [ A  B ] = [ CS -SN ] [ AA  BB ] [ CS  SN ]
      [ C  D ]   [ SN  CS ] [ CC  DD ] [-SN  CS ]

 where either
 1) CC = 0 so that AA and DD are real eigenvalues of the matrix, or
 2) AA = DD and BB*CC < 0, so that AA + or - sqrt(BB*CC) are complex
 conjugate eigenvalues.

Parameters

[in,out]	A	A is REAL
[in,out]	B	B is REAL
[in,out]	C	C is REAL
[in,out]	D	D is REAL On entry, the elements of the input matrix. On exit, they are overwritten by the elements of the standardised Schur form.
[out]	RT1R	RT1R is REAL
[out]	RT1I	RT1I is REAL
[out]	RT2R	RT2R is REAL
[out]	RT2I	RT2I is REAL The real and imaginary parts of the eigenvalues. If the eigenvalues are a complex conjugate pair, RT1I > 0.
[out]	CS	CS is REAL
[out]	SN	SN is REAL Parameters of the rotation matrix.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Further Details:

  Modified by V. Sima, Research Institute for Informatics, Bucharest,
  Romania, to reduce the risk of cancellation errors,
  when computing real eigenvalues, and to ensure, if possible, that
  abs(RT1R) >= abs(RT2R).

Definition at line 126 of file slanv2.f.

*
*  -- LAPACK auxiliary routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      REAL               A, B, C, CS, D, RT1I, RT1R, RT2I, RT2R, SN
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, HALF, ONE, TWO
      parameter( zero = 0.0e+0, half = 0.5e+0, one = 1.0e+0,
     $                     two = 2.0e+0 )
      REAL               MULTPL
      parameter( multpl = 4.0e+0 )
*     ..
*     .. Local Scalars ..
      REAL               AA, BB, BCMAX, BCMIS, CC, CS1, DD, EPS, P, SAB,
     $                   SAC, SCALE, SIGMA, SN1, TAU, TEMP, Z, SAFMIN, 
     $                   SAFMN2, SAFMX2
      INTEGER            COUNT
*     ..
*     .. External Functions ..
      REAL               SLAMCH, SLAPY2
      EXTERNAL           slamch, slapy2
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, max, min, sign, sqrt
*     ..
*     .. Executable Statements ..
*
      safmin = slamch( 'S' )
      eps = slamch( 'P' )
      safmn2 = slamch( 'B' )**int( log( safmin / eps ) /
     $            log( slamch( 'B' ) ) / two )
      safmx2 = one / safmn2
      IF( c.EQ.zero ) THEN
         cs = one
         sn = zero
*
      ELSE IF( b.EQ.zero ) THEN
*
*        Swap rows and columns
*
         cs = zero
         sn = one
         temp = d
         d = a
         a = temp
         b = -c
         c = zero
*
      ELSE IF( (a-d).EQ.zero .AND. sign( one, b ).NE.
     $   sign( one, c ) ) THEN
         cs = one
         sn = zero
*
      ELSE
*
         temp = a - d
         p = half*temp
         bcmax = max( abs( b ), abs( c ) )
         bcmis = min( abs( b ), abs( c ) )*sign( one, b )*sign( one, c )
         scale = max( abs( p ), bcmax )
         z = ( p / scale )*p + ( bcmax / scale )*bcmis
*
*        If Z is of the order of the machine accuracy, postpone the
*        decision on the nature of eigenvalues
*
         IF( z.GE.multpl*eps ) THEN
*
*           Real eigenvalues. Compute A and D.
*
            z = p + sign( sqrt( scale )*sqrt( z ), p )
            a = d + z
            d = d - ( bcmax / z )*bcmis
*
*           Compute B and the rotation matrix
*
            tau = slapy2( c, z )
            cs = z / tau
            sn = c / tau
            b = b - c
            c = zero
*
         ELSE
*
*           Complex eigenvalues, or real (almost) equal eigenvalues.
*           Make diagonal elements equal.
*
            count = 0
            sigma = b + c
   10       CONTINUE
            count = count + 1
            scale = max( abs(temp), abs(sigma) )
            IF( scale.GE.safmx2 ) THEN
               sigma = sigma * safmn2
               temp = temp * safmn2
               IF (count .LE. 20)
     $            GOTO 10
            END IF
            IF( scale.LE.safmn2 ) THEN
               sigma = sigma * safmx2
               temp = temp * safmx2
               IF (count .LE. 20)
     $            GOTO 10
            END IF
            p = half*temp
            tau = slapy2( sigma, temp )
            cs = sqrt( half*( one+abs( sigma ) / tau ) )
            sn = -( p / ( tau*cs ) )*sign( one, sigma )
*
*           Compute [ AA  BB ] = [ A  B ] [ CS -SN ]
*                   [ CC  DD ]   [ C  D ] [ SN  CS ]
*
            aa = a*cs + b*sn
            bb = -a*sn + b*cs
            cc = c*cs + d*sn
            dd = -c*sn + d*cs
*
*           Compute [ A  B ] = [ CS  SN ] [ AA  BB ]
*                   [ C  D ]   [-SN  CS ] [ CC  DD ]
*
            a = aa*cs + cc*sn
            b = bb*cs + dd*sn
            c = -aa*sn + cc*cs
            d = -bb*sn + dd*cs
*
            temp = half*( a+d )
            a = temp
            d = temp
*
            IF( c.NE.zero ) THEN
               IF( b.NE.zero ) THEN
                  IF( sign( one, b ).EQ.sign( one, c ) ) THEN
*
*                    Real eigenvalues: reduce to upper triangular form
*
                     sab = sqrt( abs( b ) )
                     sac = sqrt( abs( c ) )
                     p = sign( sab*sac, c )
                     tau = one / sqrt( abs( b+c ) )
                     a = temp + p
                     d = temp - p
                     b = b - c
                     c = zero
                     cs1 = sab*tau
                     sn1 = sac*tau
                     temp = cs*cs1 - sn*sn1
                     sn = cs*sn1 + sn*cs1
                     cs = temp
                  END IF
               ELSE
                  b = -c
                  c = zero
                  temp = cs
                  cs = -sn
                  sn = temp
               END IF
            END IF
         END IF
*
      END IF
*
*     Store eigenvalues in (RT1R,RT1I) and (RT2R,RT2I).
*
      rt1r = a
      rt2r = d
      IF( c.EQ.zero ) THEN
         rt1i = zero
         rt2i = zero
      ELSE
         rt1i = sqrt( abs( b ) )*sqrt( abs( c ) )
         rt2i = -rt1i
      END IF
      RETURN
*
*     End of SLANV2
*

Here is the caller graph for this function: