dlahrd()

subroutine dlahrd	(	integer	n,
		integer	k,
		integer	nb,
		double precision, dimension( lda, * )	a,
		integer	lda,
		double precision, dimension( nb )	tau,
		double precision, dimension( ldt, nb )	t,
		integer	ldt,
		double precision, dimension( ldy, nb )	y,
		integer	ldy )

DLAHRD reduces the first nb columns of a general rectangular matrix A so that elements below the k-th subdiagonal are zero, and returns auxiliary matrices which are needed to apply the transformation to the unreduced part of A.

Download DLAHRD + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> This routine is deprecated and has been replaced by routine DLAHR2.
!>
!> DLAHRD reduces the first NB columns of a real general n-by-(n-k+1)
!> matrix A so that elements below the k-th subdiagonal are zero. The
!> reduction is performed by an orthogonal similarity transformation
!> Q**T * A * Q. The routine returns the matrices V and T which determine
!> Q as a block reflector I - V*T*V**T, and also the matrix Y = A * V * T.
!> 

Parameters

[in]	N	!> N is INTEGER !> The order of the matrix A. !>
[in]	K	!> K is INTEGER !> The offset for the reduction. Elements below the k-th !> subdiagonal in the first NB columns are reduced to zero. !>
[in]	NB	!> NB is INTEGER !> The number of columns to be reduced. !>
[in,out]	A	!> A is DOUBLE PRECISION array, dimension (LDA,N-K+1) !> On entry, the n-by-(n-k+1) general matrix A. !> On exit, the elements on and above the k-th subdiagonal in !> the first NB columns are overwritten with the corresponding !> elements of the reduced matrix; the elements below the k-th !> subdiagonal, with the array TAU, represent the matrix Q as a !> product of elementary reflectors. The other columns of A are !> unchanged. See Further Details. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= max(1,N). !>
[out]	TAU	!> TAU is DOUBLE PRECISION array, dimension (NB) !> The scalar factors of the elementary reflectors. See Further !> Details. !>
[out]	T	!> T is DOUBLE PRECISION array, dimension (LDT,NB) !> The upper triangular matrix T. !>
[in]	LDT	!> LDT is INTEGER !> The leading dimension of the array T. LDT >= NB. !>
[out]	Y	!> Y is DOUBLE PRECISION array, dimension (LDY,NB) !> The n-by-nb matrix Y. !>
[in]	LDY	!> LDY is INTEGER !> The leading dimension of the array Y. LDY >= N. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Further Details:

!>
!>  The matrix Q is represented as a product of nb elementary reflectors
!>
!>     Q = H(1) H(2) . . . H(nb).
!>
!>  Each H(i) has the form
!>
!>     H(i) = I - tau * v * v**T
!>
!>  where tau is a real scalar, and v is a real vector with
!>  v(1:i+k-1) = 0, v(i+k) = 1; v(i+k+1:n) is stored on exit in
!>  A(i+k+1:n,i), and tau in TAU(i).
!>
!>  The elements of the vectors v together form the (n-k+1)-by-nb matrix
!>  V which is needed, with T and Y, to apply the transformation to the
!>  unreduced part of the matrix, using an update of the form:
!>  A := (I - V*T*V**T) * (A - Y*V**T).
!>
!>  The contents of A on exit are illustrated by the following example
!>  with n = 7, k = 3 and nb = 2:
!>
!>     ( a   h   a   a   a )
!>     ( a   h   a   a   a )
!>     ( a   h   a   a   a )
!>     ( h   h   a   a   a )
!>     ( v1  h   a   a   a )
!>     ( v1  v2  a   a   a )
!>     ( v1  v2  a   a   a )
!>
!>  where a denotes an element of the original matrix A, h denotes a
!>  modified element of the upper Hessenberg matrix H, and vi denotes an
!>  element of the vector defining H(i).
!> 

Definition at line 164 of file dlahrd.f.

*
*  -- LAPACK auxiliary routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            K, LDA, LDT, LDY, N, NB
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   A( LDA, * ), T( LDT, NB ), TAU( NB ),
     $                   Y( LDY, NB )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      parameter( zero = 0.0d+0, one = 1.0d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I
      DOUBLE PRECISION   EI
*     ..
*     .. External Subroutines ..
      EXTERNAL           daxpy, dcopy, dgemv, dlarfg, dscal, dtrmv
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          min
*     ..
*     .. Executable Statements ..
*
*     Quick return if possible
*
      IF( n.LE.1 )
     $   RETURN
*
      DO 10 i = 1, nb
         IF( i.GT.1 ) THEN
*
*           Update A(1:n,i)
*
*           Compute i-th column of A - Y * V**T
*
            CALL dgemv( 'No transpose', n, i-1, -one, y, ldy,
     $                  a( k+i-1, 1 ), lda, one, a( 1, i ), 1 )
*
*           Apply I - V * T**T * V**T to this column (call it b) from the
*           left, using the last column of T as workspace
*
*           Let  V = ( V1 )   and   b = ( b1 )   (first I-1 rows)
*                    ( V2 )             ( b2 )
*
*           where V1 is unit lower triangular
*
*           w := V1**T * b1
*
            CALL dcopy( i-1, a( k+1, i ), 1, t( 1, nb ), 1 )
            CALL dtrmv( 'Lower', 'Transpose', 'Unit', i-1,
     $                  a( k+1, 1 ), lda, t( 1, nb ), 1 )
*
*           w := w + V2**T *b2
*
            CALL dgemv( 'Transpose', n-k-i+1, i-1, one, a( k+i, 1 ),
     $                  lda, a( k+i, i ), 1, one, t( 1, nb ), 1 )
*
*           w := T**T *w
*
            CALL dtrmv( 'Upper', 'Transpose', 'Non-unit', i-1,
     $                  t, ldt, t( 1, nb ), 1 )
*
*           b2 := b2 - V2*w
*
            CALL dgemv( 'No transpose', n-k-i+1, i-1, -one,
     $                  a( k+i, 1 ), lda, t( 1, nb ), 1, one,
     $                  a( k+i, i ), 1 )
*
*           b1 := b1 - V1*w
*
            CALL dtrmv( 'Lower', 'No transpose', 'Unit', i-1,
     $                  a( k+1, 1 ), lda, t( 1, nb ), 1 )
            CALL daxpy( i-1, -one, t( 1, nb ), 1, a( k+1, i ), 1 )
*
            a( k+i-1, i-1 ) = ei
         END IF
*
*        Generate the elementary reflector H(i) to annihilate
*        A(k+i+1:n,i)
*
         CALL dlarfg( n-k-i+1, a( k+i, i ), a( min( k+i+1, n ), i ), 1,
     $                tau( i ) )
         ei = a( k+i, i )
         a( k+i, i ) = one
*
*        Compute  Y(1:n,i)
*
         CALL dgemv( 'No transpose', n, n-k-i+1, one, a( 1, i+1 ),
     $               lda, a( k+i, i ), 1, zero, y( 1, i ), 1 )
         CALL dgemv( 'Transpose', n-k-i+1, i-1, one, a( k+i, 1 ),
     $               lda, a( k+i, i ), 1, zero, t( 1, i ), 1 )
         CALL dgemv( 'No transpose', n, i-1, -one, y, ldy, t( 1, i ),
     $               1, one, y( 1, i ), 1 )
         CALL dscal( n, tau( i ), y( 1, i ), 1 )
*
*        Compute T(1:i,i)
*
         CALL dscal( i-1, -tau( i ), t( 1, i ), 1 )
         CALL dtrmv( 'Upper', 'No transpose', 'Non-unit', i-1,
     $               t, ldt, t( 1, i ), 1 )
         t( i, i ) = tau( i )
*
   10 CONTINUE
      a( k+nb, nb ) = ei
*
      RETURN
*
*     End of DLAHRD
*

Here is the call graph for this function: