zlatrd()

subroutine zlatrd	(	character	uplo,
		integer	n,
		integer	nb,
		complex*16, dimension( lda, * )	a,
		integer	lda,
		double precision, dimension( * )	e,
		complex*16, dimension( * )	tau,
		complex*16, dimension( ldw, * )	w,
		integer	ldw )

ZLATRD reduces the first nb rows and columns of a symmetric/Hermitian matrix A to real tridiagonal form by an unitary similarity transformation.

Download ZLATRD + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> ZLATRD reduces NB rows and columns of a complex Hermitian matrix A to
!> Hermitian tridiagonal form by a unitary similarity
!> transformation Q**H * A * Q, and returns the matrices V and W which are
!> needed to apply the transformation to the unreduced part of A.
!>
!> If UPLO = 'U', ZLATRD reduces the last NB rows and columns of a
!> matrix, of which the upper triangle is supplied;
!> if UPLO = 'L', ZLATRD reduces the first NB rows and columns of a
!> matrix, of which the lower triangle is supplied.
!>
!> This is an auxiliary routine called by ZHETRD.
!> 

Parameters

[in]	UPLO	!> UPLO is CHARACTER*1 !> Specifies whether the upper or lower triangular part of the !> Hermitian matrix A is stored: !> = 'U': Upper triangular !> = 'L': Lower triangular !>
[in]	N	!> N is INTEGER !> The order of the matrix A. !>
[in]	NB	!> NB is INTEGER !> The number of rows and columns to be reduced. !>
[in,out]	A	!> A is COMPLEX*16 array, dimension (LDA,N) !> On entry, the Hermitian matrix A. If UPLO = 'U', the leading !> n-by-n upper triangular part of A contains the upper !> triangular part of the matrix A, and the strictly lower !> triangular part of A is not referenced. If UPLO = 'L', the !> leading n-by-n lower triangular part of A contains the lower !> triangular part of the matrix A, and the strictly upper !> triangular part of A is not referenced. !> On exit: !> if UPLO = 'U', the last NB columns have been reduced to !> tridiagonal form, with the diagonal elements overwriting !> the diagonal elements of A; the elements above the diagonal !> with the array TAU, represent the unitary matrix Q as a !> product of elementary reflectors; !> if UPLO = 'L', the first NB columns have been reduced to !> tridiagonal form, with the diagonal elements overwriting !> the diagonal elements of A; the elements below the diagonal !> with the array TAU, represent the unitary matrix Q as a !> product of elementary reflectors. !> See Further Details. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= max(1,N). !>
[out]	E	!> E is DOUBLE PRECISION array, dimension (N-1) !> If UPLO = 'U', E(n-nb:n-1) contains the superdiagonal !> elements of the last NB columns of the reduced matrix; !> if UPLO = 'L', E(1:nb) contains the subdiagonal elements of !> the first NB columns of the reduced matrix. !>
[out]	TAU	!> TAU is COMPLEX*16 array, dimension (N-1) !> The scalar factors of the elementary reflectors, stored in !> TAU(n-nb:n-1) if UPLO = 'U', and in TAU(1:nb) if UPLO = 'L'. !> See Further Details. !>
[out]	W	!> W is COMPLEX*16 array, dimension (LDW,NB) !> The n-by-nb matrix W required to update the unreduced part !> of A. !>
[in]	LDW	!> LDW is INTEGER !> The leading dimension of the array W. LDW >= max(1,N). !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Further Details:

!>
!>  If UPLO = 'U', the matrix Q is represented as a product of elementary
!>  reflectors
!>
!>     Q = H(n) H(n-1) . . . H(n-nb+1).
!>
!>  Each H(i) has the form
!>
!>     H(i) = I - tau * v * v**H
!>
!>  where tau is a complex scalar, and v is a complex vector with
!>  v(i:n) = 0 and v(i-1) = 1; v(1:i-1) is stored on exit in A(1:i-1,i),
!>  and tau in TAU(i-1).
!>
!>  If UPLO = 'L', the matrix Q is represented as a product of elementary
!>  reflectors
!>
!>     Q = H(1) H(2) . . . H(nb).
!>
!>  Each H(i) has the form
!>
!>     H(i) = I - tau * v * v**H
!>
!>  where tau is a complex scalar, and v is a complex vector with
!>  v(1:i) = 0 and v(i+1) = 1; v(i+1:n) is stored on exit in A(i+1:n,i),
!>  and tau in TAU(i).
!>
!>  The elements of the vectors v together form the n-by-nb matrix V
!>  which is needed, with W, to apply the transformation to the unreduced
!>  part of the matrix, using a Hermitian rank-2k update of the form:
!>  A := A - V*W**H - W*V**H.
!>
!>  The contents of A on exit are illustrated by the following examples
!>  with n = 5 and nb = 2:
!>
!>  if UPLO = 'U':                       if UPLO = 'L':
!>
!>    (  a   a   a   v4  v5 )              (  d                  )
!>    (      a   a   v4  v5 )              (  1   d              )
!>    (          a   1   v5 )              (  v1  1   a          )
!>    (              d   1  )              (  v1  v2  a   a      )
!>    (                  d  )              (  v1  v2  a   a   a  )
!>
!>  where d denotes a diagonal element of the reduced matrix, a denotes
!>  an element of the original matrix that is unchanged, and vi denotes
!>  an element of the vector defining H(i).
!> 

Definition at line 196 of file zlatrd.f.

*
*  -- LAPACK auxiliary routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            LDA, LDW, N, NB
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   E( * )
      COMPLEX*16         A( LDA, * ), TAU( * ), W( LDW, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      COMPLEX*16         ZERO, ONE, HALF
      parameter( zero = ( 0.0d+0, 0.0d+0 ),
     $                   one = ( 1.0d+0, 0.0d+0 ),
     $                   half = ( 0.5d+0, 0.0d+0 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            I, IW
      COMPLEX*16         ALPHA
*     ..
*     .. External Subroutines ..
      EXTERNAL           zaxpy, zgemv, zhemv, zlacgv, zlarfg,
     $                   zscal
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      COMPLEX*16         ZDOTC
      EXTERNAL           lsame, zdotc
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, min
*     ..
*     .. Executable Statements ..
*
*     Quick return if possible
*
      IF( n.LE.0 )
     $   RETURN
*
      IF( lsame( uplo, 'U' ) ) THEN
*
*        Reduce last NB columns of upper triangle
*
         DO 10 i = n, n - nb + 1, -1
            iw = i - n + nb
            IF( i.LT.n ) THEN
*
*              Update A(1:i,i)
*
               a( i, i ) = dble( a( i, i ) )
               CALL zlacgv( n-i, w( i, iw+1 ), ldw )
               CALL zgemv( 'No transpose', i, n-i, -one, a( 1, i+1 ),
     $                     lda, w( i, iw+1 ), ldw, one, a( 1, i ), 1 )
               CALL zlacgv( n-i, w( i, iw+1 ), ldw )
               CALL zlacgv( n-i, a( i, i+1 ), lda )
               CALL zgemv( 'No transpose', i, n-i, -one, w( 1,
     $                     iw+1 ),
     $                     ldw, a( i, i+1 ), lda, one, a( 1, i ), 1 )
               CALL zlacgv( n-i, a( i, i+1 ), lda )
               a( i, i ) = dble( a( i, i ) )
            END IF
            IF( i.GT.1 ) THEN
*
*              Generate elementary reflector H(i) to annihilate
*              A(1:i-2,i)
*
               alpha = a( i-1, i )
               CALL zlarfg( i-1, alpha, a( 1, i ), 1, tau( i-1 ) )
               e( i-1 ) = dble( alpha )
               a( i-1, i ) = one
*
*              Compute W(1:i-1,i)
*
               CALL zhemv( 'Upper', i-1, one, a, lda, a( 1, i ), 1,
     $                     zero, w( 1, iw ), 1 )
               IF( i.LT.n ) THEN
                  CALL zgemv( 'Conjugate transpose', i-1, n-i, one,
     $                        w( 1, iw+1 ), ldw, a( 1, i ), 1, zero,
     $                        w( i+1, iw ), 1 )
                  CALL zgemv( 'No transpose', i-1, n-i, -one,
     $                        a( 1, i+1 ), lda, w( i+1, iw ), 1, one,
     $                        w( 1, iw ), 1 )
                  CALL zgemv( 'Conjugate transpose', i-1, n-i, one,
     $                        a( 1, i+1 ), lda, a( 1, i ), 1, zero,
     $                        w( i+1, iw ), 1 )
                  CALL zgemv( 'No transpose', i-1, n-i, -one,
     $                        w( 1, iw+1 ), ldw, w( i+1, iw ), 1, one,
     $                        w( 1, iw ), 1 )
               END IF
               CALL zscal( i-1, tau( i-1 ), w( 1, iw ), 1 )
               alpha = -half*tau( i-1 )*zdotc( i-1, w( 1, iw ), 1,
     $                 a( 1, i ), 1 )
               CALL zaxpy( i-1, alpha, a( 1, i ), 1, w( 1, iw ), 1 )
            END IF
*
   10    CONTINUE
      ELSE
*
*        Reduce first NB columns of lower triangle
*
         DO 20 i = 1, nb
*
*           Update A(i:n,i)
*
            a( i, i ) = dble( a( i, i ) )
            CALL zlacgv( i-1, w( i, 1 ), ldw )
            CALL zgemv( 'No transpose', n-i+1, i-1, -one, a( i, 1 ),
     $                  lda, w( i, 1 ), ldw, one, a( i, i ), 1 )
            CALL zlacgv( i-1, w( i, 1 ), ldw )
            CALL zlacgv( i-1, a( i, 1 ), lda )
            CALL zgemv( 'No transpose', n-i+1, i-1, -one, w( i, 1 ),
     $                  ldw, a( i, 1 ), lda, one, a( i, i ), 1 )
            CALL zlacgv( i-1, a( i, 1 ), lda )
            a( i, i ) = dble( a( i, i ) )
            IF( i.LT.n ) THEN
*
*              Generate elementary reflector H(i) to annihilate
*              A(i+2:n,i)
*
               alpha = a( i+1, i )
               CALL zlarfg( n-i, alpha, a( min( i+2, n ), i ), 1,
     $                      tau( i ) )
               e( i ) = dble( alpha )
               a( i+1, i ) = one
*
*              Compute W(i+1:n,i)
*
               CALL zhemv( 'Lower', n-i, one, a( i+1, i+1 ), lda,
     $                     a( i+1, i ), 1, zero, w( i+1, i ), 1 )
               CALL zgemv( 'Conjugate transpose', n-i, i-1, one,
     $                     w( i+1, 1 ), ldw, a( i+1, i ), 1, zero,
     $                     w( 1, i ), 1 )
               CALL zgemv( 'No transpose', n-i, i-1, -one, a( i+1,
     $                     1 ),
     $                     lda, w( 1, i ), 1, one, w( i+1, i ), 1 )
               CALL zgemv( 'Conjugate transpose', n-i, i-1, one,
     $                     a( i+1, 1 ), lda, a( i+1, i ), 1, zero,
     $                     w( 1, i ), 1 )
               CALL zgemv( 'No transpose', n-i, i-1, -one, w( i+1,
     $                     1 ),
     $                     ldw, w( 1, i ), 1, one, w( i+1, i ), 1 )
               CALL zscal( n-i, tau( i ), w( i+1, i ), 1 )
               alpha = -half*tau( i )*zdotc( n-i, w( i+1, i ), 1,
     $                 a( i+1, i ), 1 )
               CALL zaxpy( n-i, alpha, a( i+1, i ), 1, w( i+1, i ),
     $                     1 )
            END IF
*
   20    CONTINUE
      END IF
*
      RETURN
*
*     End of ZLATRD
*

Here is the call graph for this function:

Here is the caller graph for this function: