ztrsyl.f

Go to the documentation of this file.

*> \brief \b ZTRSYL
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*> \htmlonly
*> Download ZTRSYL + dependencies
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/ztrsyl.f">
*> [TGZ]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/ztrsyl.f">
*> [ZIP]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/ztrsyl.f">
*> [TXT]</a>
*> \endhtmlonly
*
*  Definition:
*  ===========
*
*       SUBROUTINE ZTRSYL( TRANA, TRANB, ISGN, M, N, A, LDA, B, LDB, C,
*                          LDC, SCALE, INFO )
*
*       .. Scalar Arguments ..
*       CHARACTER          TRANA, TRANB
*       INTEGER            INFO, ISGN, LDA, LDB, LDC, M, N
*       DOUBLE PRECISION   SCALE
*       ..
*       .. Array Arguments ..
*       COMPLEX*16         A( LDA, * ), B( LDB, * ), C( LDC, * )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> ZTRSYL solves the complex Sylvester matrix equation:
*>
*>    op(A)*X + X*op(B) = scale*C or
*>    op(A)*X - X*op(B) = scale*C,
*>
*> where op(A) = A or A**H, and A and B are both upper triangular. A is
*> M-by-M and B is N-by-N; the right hand side C and the solution X are
*> M-by-N; and scale is an output scale factor, set <= 1 to avoid
*> overflow in X.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] TRANA
*> \verbatim
*>          TRANA is CHARACTER*1
*>          Specifies the option op(A):
*>          = 'N': op(A) = A    (No transpose)
*>          = 'C': op(A) = A**H (Conjugate transpose)
*> \endverbatim
*>
*> \param[in] TRANB
*> \verbatim
*>          TRANB is CHARACTER*1
*>          Specifies the option op(B):
*>          = 'N': op(B) = B    (No transpose)
*>          = 'C': op(B) = B**H (Conjugate transpose)
*> \endverbatim
*>
*> \param[in] ISGN
*> \verbatim
*>          ISGN is INTEGER
*>          Specifies the sign in the equation:
*>          = +1: solve op(A)*X + X*op(B) = scale*C
*>          = -1: solve op(A)*X - X*op(B) = scale*C
*> \endverbatim
*>
*> \param[in] M
*> \verbatim
*>          M is INTEGER
*>          The order of the matrix A, and the number of rows in the
*>          matrices X and C. M >= 0.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The order of the matrix B, and the number of columns in the
*>          matrices X and C. N >= 0.
*> \endverbatim
*>
*> \param[in] A
*> \verbatim
*>          A is COMPLEX*16 array, dimension (LDA,M)
*>          The upper triangular matrix A.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of the array A. LDA >= max(1,M).
*> \endverbatim
*>
*> \param[in] B
*> \verbatim
*>          B is COMPLEX*16 array, dimension (LDB,N)
*>          The upper triangular matrix B.
*> \endverbatim
*>
*> \param[in] LDB
*> \verbatim
*>          LDB is INTEGER
*>          The leading dimension of the array B. LDB >= max(1,N).
*> \endverbatim
*>
*> \param[in,out] C
*> \verbatim
*>          C is COMPLEX*16 array, dimension (LDC,N)
*>          On entry, the M-by-N right hand side matrix C.
*>          On exit, C is overwritten by the solution matrix X.
*> \endverbatim
*>
*> \param[in] LDC
*> \verbatim
*>          LDC is INTEGER
*>          The leading dimension of the array C. LDC >= max(1,M)
*> \endverbatim
*>
*> \param[out] SCALE
*> \verbatim
*>          SCALE is DOUBLE PRECISION
*>          The scale factor, scale, set <= 1 to avoid overflow in X.
*> \endverbatim
*>
*> \param[out] INFO
*> \verbatim
*>          INFO is INTEGER
*>          = 0: successful exit
*>          < 0: if INFO = -i, the i-th argument had an illegal value
*>          = 1: A and B have common or very close eigenvalues; perturbed
*>               values were used to solve the equation (but the matrices
*>               A and B are unchanged).
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup trsyl
*
*  =====================================================================
      SUBROUTINE ztrsyl( TRANA, TRANB, ISGN, M, N, A, LDA, B, LDB, C,
     $                   LDC, SCALE, INFO )
*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          TRANA, TRANB
      INTEGER            INFO, ISGN, LDA, LDB, LDC, M, N
      DOUBLE PRECISION   SCALE
*     ..
*     .. Array Arguments ..
      COMPLEX*16         A( LDA, * ), B( LDB, * ), C( LDC, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ONE
      parameter( one = 1.0d+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            NOTRNA, NOTRNB
      INTEGER            J, K, L
      DOUBLE PRECISION   BIGNUM, DA11, DB, EPS, SCALOC, SGN, SMIN,
     $                   smlnum
      COMPLEX*16         A11, SUML, SUMR, VEC, X11
*     ..
*     .. Local Arrays ..
      DOUBLE PRECISION   DUM( 1 )
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      DOUBLE PRECISION   DLAMCH, ZLANGE
      COMPLEX*16         ZDOTC, ZDOTU, ZLADIV
      EXTERNAL           lsame, dlamch, zlange, zdotc, zdotu, zladiv
*     ..
*     .. External Subroutines ..
      EXTERNAL           xerbla, zdscal
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, dble, dcmplx, dconjg, dimag, max, min
*     ..
*     .. Executable Statements ..
*
*     Decode and Test input parameters
*
      notrna = lsame( trana, 'N' )
      notrnb = lsame( tranb, 'N' )
*
      info = 0
      IF( .NOT.notrna .AND. .NOT.lsame( trana, 'C' ) ) THEN
         info = -1
      ELSE IF( .NOT.notrnb .AND. .NOT.lsame( tranb, 'C' ) ) THEN
         info = -2
      ELSE IF( isgn.NE.1 .AND. isgn.NE.-1 ) THEN
         info = -3
      ELSE IF( m.LT.0 ) THEN
         info = -4
      ELSE IF( n.LT.0 ) THEN
         info = -5
      ELSE IF( lda.LT.max( 1, m ) ) THEN
         info = -7
      ELSE IF( ldb.LT.max( 1, n ) ) THEN
         info = -9
      ELSE IF( ldc.LT.max( 1, m ) ) THEN
         info = -11
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'ZTRSYL', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      scale = one
      IF( m.EQ.0 .OR. n.EQ.0 )
     $   RETURN
*
*     Set constants to control overflow
*
      eps = dlamch( 'P' )
      smlnum = dlamch( 'S' )
      bignum = one / smlnum
      smlnum = smlnum*dble( m*n ) / eps
      bignum = one / smlnum
      smin = max( smlnum, eps*zlange( 'M', m, m, a, lda, dum ),
     $       eps*zlange( 'M', n, n, b, ldb, dum ) )
      sgn = isgn
*
      IF( notrna .AND. notrnb ) THEN
*
*        Solve    A*X + ISGN*X*B = scale*C.
*
*        The (K,L)th block of X is determined starting from
*        bottom-left corner column by column by
*
*            A(K,K)*X(K,L) + ISGN*X(K,L)*B(L,L) = C(K,L) - R(K,L)
*
*        Where
*                    M                        L-1
*          R(K,L) = SUM [A(K,I)*X(I,L)] +ISGN*SUM [X(K,J)*B(J,L)].
*                  I=K+1                      J=1
*
         DO 30 l = 1, n
            DO 20 k = m, 1, -1
*
               suml = zdotu( m-k, a( k, min( k+1, m ) ), lda,
     $                c( min( k+1, m ), l ), 1 )
               sumr = zdotu( l-1, c( k, 1 ), ldc, b( 1, l ), 1 )
               vec = c( k, l ) - ( suml+sgn*sumr )
*
               scaloc = one
               a11 = a( k, k ) + sgn*b( l, l )
               da11 = abs( dble( a11 ) ) + abs( dimag( a11 ) )
               IF( da11.LE.smin ) THEN
                  a11 = smin
                  da11 = smin
                  info = 1
               END IF
               db = abs( dble( vec ) ) + abs( dimag( vec ) )
               IF( da11.LT.one .AND. db.GT.one ) THEN
                  IF( db.GT.bignum*da11 )
     $               scaloc = one / db
               END IF
               x11 = zladiv( vec*dcmplx( scaloc ), a11 )
*
               IF( scaloc.NE.one ) THEN
                  DO 10 j = 1, n
                     CALL zdscal( m, scaloc, c( 1, j ), 1 )
   10             CONTINUE
                  scale = scale*scaloc
               END IF
               c( k, l ) = x11
*
   20       CONTINUE
   30    CONTINUE
*
      ELSE IF( .NOT.notrna .AND. notrnb ) THEN
*
*        Solve    A**H *X + ISGN*X*B = scale*C.
*
*        The (K,L)th block of X is determined starting from
*        upper-left corner column by column by
*
*            A**H(K,K)*X(K,L) + ISGN*X(K,L)*B(L,L) = C(K,L) - R(K,L)
*
*        Where
*                   K-1                           L-1
*          R(K,L) = SUM [A**H(I,K)*X(I,L)] + ISGN*SUM [X(K,J)*B(J,L)]
*                   I=1                           J=1
*
         DO 60 l = 1, n
            DO 50 k = 1, m
*
               suml = zdotc( k-1, a( 1, k ), 1, c( 1, l ), 1 )
               sumr = zdotu( l-1, c( k, 1 ), ldc, b( 1, l ), 1 )
               vec = c( k, l ) - ( suml+sgn*sumr )
*
               scaloc = one
               a11 = dconjg( a( k, k ) ) + sgn*b( l, l )
               da11 = abs( dble( a11 ) ) + abs( dimag( a11 ) )
               IF( da11.LE.smin ) THEN
                  a11 = smin
                  da11 = smin
                  info = 1
               END IF
               db = abs( dble( vec ) ) + abs( dimag( vec ) )
               IF( da11.LT.one .AND. db.GT.one ) THEN
                  IF( db.GT.bignum*da11 )
     $               scaloc = one / db
               END IF
*
               x11 = zladiv( vec*dcmplx( scaloc ), a11 )
*
               IF( scaloc.NE.one ) THEN
                  DO 40 j = 1, n
                     CALL zdscal( m, scaloc, c( 1, j ), 1 )
   40             CONTINUE
                  scale = scale*scaloc
               END IF
               c( k, l ) = x11
*
   50       CONTINUE
   60    CONTINUE
*
      ELSE IF( .NOT.notrna .AND. .NOT.notrnb ) THEN
*
*        Solve    A**H*X + ISGN*X*B**H = C.
*
*        The (K,L)th block of X is determined starting from
*        upper-right corner column by column by
*
*            A**H(K,K)*X(K,L) + ISGN*X(K,L)*B**H(L,L) = C(K,L) - R(K,L)
*
*        Where
*                    K-1
*           R(K,L) = SUM [A**H(I,K)*X(I,L)] +
*                    I=1
*                           N
*                     ISGN*SUM [X(K,J)*B**H(L,J)].
*                          J=L+1
*
         DO 90 l = n, 1, -1
            DO 80 k = 1, m
*
               suml = zdotc( k-1, a( 1, k ), 1, c( 1, l ), 1 )
               sumr = zdotc( n-l, c( k, min( l+1, n ) ), ldc,
     $                b( l, min( l+1, n ) ), ldb )
               vec = c( k, l ) - ( suml+sgn*dconjg( sumr ) )
*
               scaloc = one
               a11 = dconjg( a( k, k )+sgn*b( l, l ) )
               da11 = abs( dble( a11 ) ) + abs( dimag( a11 ) )
               IF( da11.LE.smin ) THEN
                  a11 = smin
                  da11 = smin
                  info = 1
               END IF
               db = abs( dble( vec ) ) + abs( dimag( vec ) )
               IF( da11.LT.one .AND. db.GT.one ) THEN
                  IF( db.GT.bignum*da11 )
     $               scaloc = one / db
               END IF
*
               x11 = zladiv( vec*dcmplx( scaloc ), a11 )
*
               IF( scaloc.NE.one ) THEN
                  DO 70 j = 1, n
                     CALL zdscal( m, scaloc, c( 1, j ), 1 )
   70             CONTINUE
                  scale = scale*scaloc
               END IF
               c( k, l ) = x11
*
   80       CONTINUE
   90    CONTINUE
*
      ELSE IF( notrna .AND. .NOT.notrnb ) THEN
*
*        Solve    A*X + ISGN*X*B**H = C.
*
*        The (K,L)th block of X is determined starting from
*        bottom-left corner column by column by
*
*           A(K,K)*X(K,L) + ISGN*X(K,L)*B**H(L,L) = C(K,L) - R(K,L)
*
*        Where
*                    M                          N
*          R(K,L) = SUM [A(K,I)*X(I,L)] + ISGN*SUM [X(K,J)*B**H(L,J)]
*                  I=K+1                      J=L+1
*
         DO 120 l = n, 1, -1
            DO 110 k = m, 1, -1
*
               suml = zdotu( m-k, a( k, min( k+1, m ) ), lda,
     $                c( min( k+1, m ), l ), 1 )
               sumr = zdotc( n-l, c( k, min( l+1, n ) ), ldc,
     $                b( l, min( l+1, n ) ), ldb )
               vec = c( k, l ) - ( suml+sgn*dconjg( sumr ) )
*
               scaloc = one
               a11 = a( k, k ) + sgn*dconjg( b( l, l ) )
               da11 = abs( dble( a11 ) ) + abs( dimag( a11 ) )
               IF( da11.LE.smin ) THEN
                  a11 = smin
                  da11 = smin
                  info = 1
               END IF
               db = abs( dble( vec ) ) + abs( dimag( vec ) )
               IF( da11.LT.one .AND. db.GT.one ) THEN
                  IF( db.GT.bignum*da11 )
     $               scaloc = one / db
               END IF
*
               x11 = zladiv( vec*dcmplx( scaloc ), a11 )
*
               IF( scaloc.NE.one ) THEN
                  DO 100 j = 1, n
                     CALL zdscal( m, scaloc, c( 1, j ), 1 )
  100             CONTINUE
                  scale = scale*scaloc
               END IF
               c( k, l ) = x11
*
  110       CONTINUE
  120    CONTINUE
*
      END IF
*
      RETURN
*
*     End of ZTRSYL
*
      END