dpptri()

subroutine dpptri	(	character	uplo,
		integer	n,
		double precision, dimension( * )	ap,
		integer	info
	)

DPPTRI

Download DPPTRI + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 DPPTRI computes the inverse of a real symmetric positive definite
 matrix A using the Cholesky factorization A = U**T*U or A = L*L**T
 computed by DPPTRF.

Parameters

[in]	UPLO	UPLO is CHARACTER*1 = 'U': Upper triangular factor is stored in AP; = 'L': Lower triangular factor is stored in AP.
[in]	N	N is INTEGER The order of the matrix A. N >= 0.
[in,out]	AP	AP is DOUBLE PRECISION array, dimension (N*(N+1)/2) On entry, the triangular factor U or L from the Cholesky factorization A = U**T*U or A = L*L**T, packed columnwise as a linear array. The j-th column of U or L is stored in the array AP as follows: if UPLO = 'U', AP(i + (j-1)*j/2) = U(i,j) for 1<=i<=j; if UPLO = 'L', AP(i + (j-1)*(2n-j)/2) = L(i,j) for j<=i<=n. On exit, the upper or lower triangle of the (symmetric) inverse of A, overwriting the input factor U or L.
[out]	INFO	INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value > 0: if INFO = i, the (i,i) element of the factor U or L is zero, and the inverse could not be computed.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 92 of file dpptri.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            INFO, N
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   AP( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ONE
      parameter( one = 1.0d+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            UPPER
      INTEGER            J, JC, JJ, JJN
      DOUBLE PRECISION   AJJ
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      DOUBLE PRECISION   DDOT
      EXTERNAL           lsame, ddot
*     ..
*     .. External Subroutines ..
      EXTERNAL           dscal, dspr, dtpmv, dtptri, xerbla
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      upper = lsame( uplo, 'U' )
      IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'DPPTRI', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   RETURN
*
*     Invert the triangular Cholesky factor U or L.
*
      CALL dtptri( uplo, 'Non-unit', n, ap, info )
      IF( info.GT.0 )
     $   RETURN
*
      IF( upper ) THEN
*
*        Compute the product inv(U) * inv(U)**T.
*
         jj = 0
         DO 10 j = 1, n
            jc = jj + 1
            jj = jj + j
            IF( j.GT.1 )
     $         CALL dspr( 'Upper', j-1, one, ap( jc ), 1, ap )
            ajj = ap( jj )
            CALL dscal( j, ajj, ap( jc ), 1 )
   10    CONTINUE
*
      ELSE
*
*        Compute the product inv(L)**T * inv(L).
*
         jj = 1
         DO 20 j = 1, n
            jjn = jj + n - j + 1
            ap( jj ) = ddot( n-j+1, ap( jj ), 1, ap( jj ), 1 )
            IF( j.LT.n )
     $         CALL dtpmv( 'Lower', 'Transpose', 'Non-unit', n-j,
     $                     ap( jjn ), ap( jj+1 ), 1 )
            jj = jjn
   20    CONTINUE
      END IF
*
      RETURN
*
*     End of DPPTRI
*

Here is the call graph for this function:

Here is the caller graph for this function: