dspgst()

subroutine dspgst	(	integer	itype,
		character	uplo,
		integer	n,
		double precision, dimension( * )	ap,
		double precision, dimension( * )	bp,
		integer	info
	)

DSPGST

Download DSPGST + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 DSPGST reduces a real symmetric-definite generalized eigenproblem
 to standard form, using packed storage.

 If ITYPE = 1, the problem is A*x = lambda*B*x,
 and A is overwritten by inv(U**T)*A*inv(U) or inv(L)*A*inv(L**T)

 If ITYPE = 2 or 3, the problem is A*B*x = lambda*x or
 B*A*x = lambda*x, and A is overwritten by U*A*U**T or L**T*A*L.

 B must have been previously factorized as U**T*U or L*L**T by DPPTRF.

Parameters

[in]	ITYPE	ITYPE is INTEGER = 1: compute inv(U**T)*A*inv(U) or inv(L)*A*inv(L**T); = 2 or 3: compute U*A*U**T or L**T*A*L.
[in]	UPLO	UPLO is CHARACTER*1 = 'U': Upper triangle of A is stored and B is factored as U**T*U; = 'L': Lower triangle of A is stored and B is factored as L*L**T.
[in]	N	N is INTEGER The order of the matrices A and B. N >= 0.
[in,out]	AP	AP is DOUBLE PRECISION array, dimension (N*(N+1)/2) On entry, the upper or lower triangle of the symmetric matrix A, packed columnwise in a linear array. The j-th column of A is stored in the array AP as follows: if UPLO = 'U', AP(i + (j-1)*j/2) = A(i,j) for 1<=i<=j; if UPLO = 'L', AP(i + (j-1)*(2n-j)/2) = A(i,j) for j<=i<=n. On exit, if INFO = 0, the transformed matrix, stored in the same format as A.
[in]	BP	BP is DOUBLE PRECISION array, dimension (N*(N+1)/2) The triangular factor from the Cholesky factorization of B, stored in the same format as A, as returned by DPPTRF.
[out]	INFO	INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 112 of file dspgst.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            INFO, ITYPE, N
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   AP( * ), BP( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ONE, HALF
      parameter( one = 1.0d0, half = 0.5d0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            UPPER
      INTEGER            J, J1, J1J1, JJ, K, K1, K1K1, KK
      DOUBLE PRECISION   AJJ, AKK, BJJ, BKK, CT
*     ..
*     .. External Subroutines ..
      EXTERNAL           daxpy, dscal, dspmv, dspr2, dtpmv, dtpsv,
     $                   xerbla
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      DOUBLE PRECISION   DDOT
      EXTERNAL           lsame, ddot
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      upper = lsame( uplo, 'U' )
      IF( itype.LT.1 .OR. itype.GT.3 ) THEN
         info = -1
      ELSE IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -2
      ELSE IF( n.LT.0 ) THEN
         info = -3
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'DSPGST', -info )
         RETURN
      END IF
*
      IF( itype.EQ.1 ) THEN
         IF( upper ) THEN
*
*           Compute inv(U**T)*A*inv(U)
*
*           J1 and JJ are the indices of A(1,j) and A(j,j)
*
            jj = 0
            DO 10 j = 1, n
               j1 = jj + 1
               jj = jj + j
*
*              Compute the j-th column of the upper triangle of A
*
               bjj = bp( jj )
               CALL dtpsv( uplo, 'Transpose', 'Nonunit', j, bp,
     $                     ap( j1 ), 1 )
               CALL dspmv( uplo, j-1, -one, ap, bp( j1 ), 1, one,
     $                     ap( j1 ), 1 )
               CALL dscal( j-1, one / bjj, ap( j1 ), 1 )
               ap( jj ) = ( ap( jj )-ddot( j-1, ap( j1 ), 1, bp( j1 ),
     $                    1 ) ) / bjj
   10       CONTINUE
         ELSE
*
*           Compute inv(L)*A*inv(L**T)
*
*           KK and K1K1 are the indices of A(k,k) and A(k+1,k+1)
*
            kk = 1
            DO 20 k = 1, n
               k1k1 = kk + n - k + 1
*
*              Update the lower triangle of A(k:n,k:n)
*
               akk = ap( kk )
               bkk = bp( kk )
               akk = akk / bkk**2
               ap( kk ) = akk
               IF( k.LT.n ) THEN
                  CALL dscal( n-k, one / bkk, ap( kk+1 ), 1 )
                  ct = -half*akk
                  CALL daxpy( n-k, ct, bp( kk+1 ), 1, ap( kk+1 ), 1 )
                  CALL dspr2( uplo, n-k, -one, ap( kk+1 ), 1,
     $                        bp( kk+1 ), 1, ap( k1k1 ) )
                  CALL daxpy( n-k, ct, bp( kk+1 ), 1, ap( kk+1 ), 1 )
                  CALL dtpsv( uplo, 'No transpose', 'Non-unit', n-k,
     $                        bp( k1k1 ), ap( kk+1 ), 1 )
               END IF
               kk = k1k1
   20       CONTINUE
         END IF
      ELSE
         IF( upper ) THEN
*
*           Compute U*A*U**T
*
*           K1 and KK are the indices of A(1,k) and A(k,k)
*
            kk = 0
            DO 30 k = 1, n
               k1 = kk + 1
               kk = kk + k
*
*              Update the upper triangle of A(1:k,1:k)
*
               akk = ap( kk )
               bkk = bp( kk )
               CALL dtpmv( uplo, 'No transpose', 'Non-unit', k-1, bp,
     $                     ap( k1 ), 1 )
               ct = half*akk
               CALL daxpy( k-1, ct, bp( k1 ), 1, ap( k1 ), 1 )
               CALL dspr2( uplo, k-1, one, ap( k1 ), 1, bp( k1 ), 1,
     $                     ap )
               CALL daxpy( k-1, ct, bp( k1 ), 1, ap( k1 ), 1 )
               CALL dscal( k-1, bkk, ap( k1 ), 1 )
               ap( kk ) = akk*bkk**2
   30       CONTINUE
         ELSE
*
*           Compute L**T *A*L
*
*           JJ and J1J1 are the indices of A(j,j) and A(j+1,j+1)
*
            jj = 1
            DO 40 j = 1, n
               j1j1 = jj + n - j + 1
*
*              Compute the j-th column of the lower triangle of A
*
               ajj = ap( jj )
               bjj = bp( jj )
               ap( jj ) = ajj*bjj + ddot( n-j, ap( jj+1 ), 1,
     $                    bp( jj+1 ), 1 )
               CALL dscal( n-j, bjj, ap( jj+1 ), 1 )
               CALL dspmv( uplo, n-j, one, ap( j1j1 ), bp( jj+1 ), 1,
     $                     one, ap( jj+1 ), 1 )
               CALL dtpmv( uplo, 'Transpose', 'Non-unit', n-j+1,
     $                     bp( jj ), ap( jj ), 1 )
               jj = j1j1
   40       CONTINUE
         END IF
      END IF
      RETURN
*
*     End of DSPGST
*

Here is the call graph for this function:

Here is the caller graph for this function: