d0/dd9/zla__porcond__c_8f_source.html

*> \brief \b ZLA_PORCOND_C computes the infinity norm condition number of op(A)*inv(diag(c)) for Hermitian positive-definite matrices.

*

*  =========== DOCUMENTATION ===========

*

* Online html documentation available at

*            http://www.netlib.org/lapack/explore-html/

*

*> \htmlonly

*> Download ZLA_PORCOND_C + dependencies

*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zla_porcond_c.f">

*> [TGZ]</a>

*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zla_porcond_c.f">

*> [ZIP]</a>

*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zla_porcond_c.f">

*> [TXT]</a>

*> \endhtmlonly

*

*  Definition:

*  ===========

*

*       DOUBLE PRECISION FUNCTION ZLA_PORCOND_C( UPLO, N, A, LDA, AF,

*                                                LDAF, C, CAPPLY, INFO,

*                                                WORK, RWORK )

*

*       .. Scalar Arguments ..

*       CHARACTER          UPLO

*       LOGICAL            CAPPLY

*       INTEGER            N, LDA, LDAF, INFO

*       ..

*       .. Array Arguments ..

*       COMPLEX*16         A( LDA, * ), AF( LDAF, * ), WORK( * )

*       DOUBLE PRECISION   C( * ), RWORK( * )

*       ..

*

*

*> \par Purpose:

*  =============

*>

*> \verbatim

*>

*>    ZLA_PORCOND_C Computes the infinity norm condition number of

*>    op(A) * inv(diag(C)) where C is a DOUBLE PRECISION vector

*> \endverbatim

*

*  Arguments:

*  ==========

*

*> \param[in] UPLO

*> \verbatim

*>          UPLO is CHARACTER*1

*>       = 'U':  Upper triangle of A is stored;

*>       = 'L':  Lower triangle of A is stored.

*> \endverbatim

*>

*> \param[in] N

*> \verbatim

*>          N is INTEGER

*>     The number of linear equations, i.e., the order of the

*>     matrix A.  N >= 0.

*> \endverbatim

*>

*> \param[in] A

*> \verbatim

*>          A is COMPLEX*16 array, dimension (LDA,N)

*>     On entry, the N-by-N matrix A

*> \endverbatim

*>

*> \param[in] LDA

*> \verbatim

*>          LDA is INTEGER

*>     The leading dimension of the array A.  LDA >= max(1,N).

*> \endverbatim

*>

*> \param[in] AF

*> \verbatim

*>          AF is COMPLEX*16 array, dimension (LDAF,N)

*>     The triangular factor U or L from the Cholesky factorization

*>     A = U**H*U or A = L*L**H, as computed by ZPOTRF.

*> \endverbatim

*>

*> \param[in] LDAF

*> \verbatim

*>          LDAF is INTEGER

*>     The leading dimension of the array AF.  LDAF >= max(1,N).

*> \endverbatim

*>

*> \param[in] C

*> \verbatim

*>          C is DOUBLE PRECISION array, dimension (N)

*>     The vector C in the formula op(A) * inv(diag(C)).

*> \endverbatim

*>

*> \param[in] CAPPLY

*> \verbatim

*>          CAPPLY is LOGICAL

*>     If .TRUE. then access the vector C in the formula above.

*> \endverbatim

*>

*> \param[out] INFO

*> \verbatim

*>          INFO is INTEGER

*>       = 0:  Successful exit.

*>     i > 0:  The ith argument is invalid.

*> \endverbatim

*>

*> \param[out] WORK

*> \verbatim

*>          WORK is COMPLEX*16 array, dimension (2*N).

*>     Workspace.

*> \endverbatim

*>

*> \param[out] RWORK

*> \verbatim

*>          RWORK is DOUBLE PRECISION array, dimension (N).

*>     Workspace.

*> \endverbatim

*

*  Authors:

*  ========

*

*> \author Univ. of Tennessee

*> \author Univ. of California Berkeley

*> \author Univ. of Colorado Denver

*> \author NAG Ltd.

*

*> \ingroup la_porcond

*

*  =====================================================================

      DOUBLE PRECISION FUNCTION zla_porcond_c( UPLO, N, A, LDA, AF,

     $                                         LDAF, C, CAPPLY, INFO,

     $                                         WORK, RWORK )

*

*  -- LAPACK computational routine --

*  -- LAPACK is a software package provided by Univ. of Tennessee,    --

*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--

*

*     .. Scalar Arguments ..

      CHARACTER          uplo

      LOGICAL            capply

      INTEGER            n, lda, ldaf, info

*     ..

*     .. Array Arguments ..

      COMPLEX*16         a( lda, * ), af( ldaf, * ), work( * )

      DOUBLE PRECISION   c( * ), rwork( * )

*     ..

*

*  =====================================================================

*

*     .. Local Scalars ..

      INTEGER            kase

      DOUBLE PRECISION   ainvnm, anorm, tmp

      INTEGER            i, j

      LOGICAL            up, upper

      COMPLEX*16         zdum

*     ..

*     .. Local Arrays ..

      INTEGER            isave( 3 )

*     ..

*     .. External Functions ..

      LOGICAL            lsame

      EXTERNAL           lsame

*     ..

*     .. External Subroutines ..

      EXTERNAL           zlacn2, zpotrs, xerbla

*     ..

*     .. Intrinsic Functions ..

      INTRINSIC          abs, max, real, dimag

*     ..

*     .. Statement Functions ..

      DOUBLE PRECISION cabs1

*     ..

*     .. Statement Function Definitions ..

      cabs1( zdum ) = abs( dble( zdum ) ) + abs( dimag( zdum ) )

*     ..

*     .. Executable Statements ..

*

      zla_porcond_c = 0.0d+0

*

      info = 0

      upper = lsame( uplo, 'U' )

      IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN

         info = -1

      ELSE IF( n.LT.0 ) THEN

         info = -2

      ELSE IF( lda.LT.max( 1, n ) ) THEN

         info = -4

      ELSE IF( ldaf.LT.max( 1, n ) ) THEN

         info = -6

      END IF

      IF( info.NE.0 ) THEN

         CALL xerbla( 'ZLA_PORCOND_C', -info )

         RETURN

      END IF

      up = .false.

      IF ( lsame( uplo, 'U' ) ) up = .true.

*

*     Compute norm of op(A)*op2(C).

*

      anorm = 0.0d+0

      IF ( up ) THEN

         DO i = 1, n

            tmp = 0.0d+0

            IF ( capply ) THEN

               DO j = 1, i

                  tmp = tmp + cabs1( a( j, i ) ) / c( j )

               END DO

               DO j = i+1, n

                  tmp = tmp + cabs1( a( i, j ) ) / c( j )

               END DO

            ELSE

               DO j = 1, i

                  tmp = tmp + cabs1( a( j, i ) )

               END DO

               DO j = i+1, n

                  tmp = tmp + cabs1( a( i, j ) )

               END DO

            END IF

            rwork( i ) = tmp

            anorm = max( anorm, tmp )

         END DO

      ELSE

         DO i = 1, n

            tmp = 0.0d+0

            IF ( capply ) THEN

               DO j = 1, i

                  tmp = tmp + cabs1( a( i, j ) ) / c( j )

               END DO

               DO j = i+1, n

                  tmp = tmp + cabs1( a( j, i ) ) / c( j )

               END DO

            ELSE

               DO j = 1, i

                  tmp = tmp + cabs1( a( i, j ) )

               END DO

               DO j = i+1, n

                  tmp = tmp + cabs1( a( j, i ) )

               END DO

            END IF

            rwork( i ) = tmp

            anorm = max( anorm, tmp )

         END DO

      END IF

*

*     Quick return if possible.

*

      IF( n.EQ.0 ) THEN

         zla_porcond_c = 1.0d+0

         RETURN

      ELSE IF( anorm .EQ. 0.0d+0 ) THEN

         RETURN

      END IF

*

*     Estimate the norm of inv(op(A)).

*

      ainvnm = 0.0d+0

*

      kase = 0

   10 CONTINUE

      CALL zlacn2( n, work( n+1 ), work, ainvnm, kase, isave )

      IF( kase.NE.0 ) THEN

         IF( kase.EQ.2 ) THEN

*

*           Multiply by R.

*

            DO i = 1, n

               work( i ) = work( i ) * rwork( i )

            END DO

*

            IF ( up ) THEN

               CALL zpotrs( 'U', n, 1, af, ldaf,

     $            work, n, info )

            ELSE

               CALL zpotrs( 'L', n, 1, af, ldaf,

     $            work, n, info )

            ENDIF

*

*           Multiply by inv(C).

*

            IF ( capply ) THEN

               DO i = 1, n

                  work( i ) = work( i ) * c( i )

               END DO

            END IF

         ELSE

*

*           Multiply by inv(C**H).

*

            IF ( capply ) THEN

               DO i = 1, n

                  work( i ) = work( i ) * c( i )

               END DO

            END IF

*

            IF ( up ) THEN

               CALL zpotrs( 'U', n, 1, af, ldaf,

     $            work, n, info )

            ELSE

               CALL zpotrs( 'L', n, 1, af, ldaf,

     $            work, n, info )

            END IF

*

*           Multiply by R.

*

            DO i = 1, n

               work( i ) = work( i ) * rwork( i )

            END DO

         END IF

         GO TO 10

      END IF

*

*     Compute the estimate of the reciprocal condition number.

*

      IF( ainvnm .NE. 0.0d+0 )

     $   zla_porcond_c = 1.0d+0 / ainvnm

*

      RETURN

*

*     End of ZLA_PORCOND_C

*

      END

xerbla
subroutine xerbla(srname, info)
Definition cblat2.f:3285

zla_porcond_c
double precision function zla_porcond_c(uplo, n, a, lda, af, ldaf, c, capply, info, work, rwork)
ZLA_PORCOND_C computes the infinity norm condition number of op(A)*inv(diag(c)) for Hermitian positiv...
Definition zla_porcond_c.f:132

zlacn2
subroutine zlacn2(n, v, x, est, kase, isave)
ZLACN2 estimates the 1-norm of a square matrix, using reverse communication for evaluating matrix-vec...
Definition zlacn2.f:133

lsame
logical function lsame(ca, cb)
LSAME
Definition lsame.f:48

zpotrs
subroutine zpotrs(uplo, n, nrhs, a, lda, b, ldb, info)
ZPOTRS
Definition zpotrs.f:110