 LAPACK  3.10.1 LAPACK: Linear Algebra PACKage

## ◆ zpptri()

 subroutine zpptri ( character UPLO, integer N, complex*16, dimension( * ) AP, integer INFO )

ZPPTRI

Download ZPPTRI + dependencies [TGZ] [ZIP] [TXT]

Purpose:
``` ZPPTRI computes the inverse of a complex Hermitian positive definite
matrix A using the Cholesky factorization A = U**H*U or A = L*L**H
computed by ZPPTRF.```
Parameters
 [in] UPLO ``` UPLO is CHARACTER*1 = 'U': Upper triangular factor is stored in AP; = 'L': Lower triangular factor is stored in AP.``` [in] N ``` N is INTEGER The order of the matrix A. N >= 0.``` [in,out] AP ``` AP is COMPLEX*16 array, dimension (N*(N+1)/2) On entry, the triangular factor U or L from the Cholesky factorization A = U**H*U or A = L*L**H, packed columnwise as a linear array. The j-th column of U or L is stored in the array AP as follows: if UPLO = 'U', AP(i + (j-1)*j/2) = U(i,j) for 1<=i<=j; if UPLO = 'L', AP(i + (j-1)*(2n-j)/2) = L(i,j) for j<=i<=n. On exit, the upper or lower triangle of the (Hermitian) inverse of A, overwriting the input factor U or L.``` [out] INFO ``` INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value > 0: if INFO = i, the (i,i) element of the factor U or L is zero, and the inverse could not be computed.```

Definition at line 92 of file zpptri.f.

93 *
94 * -- LAPACK computational routine --
95 * -- LAPACK is a software package provided by Univ. of Tennessee, --
96 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
97 *
98 * .. Scalar Arguments ..
99  CHARACTER UPLO
100  INTEGER INFO, N
101 * ..
102 * .. Array Arguments ..
103  COMPLEX*16 AP( * )
104 * ..
105 *
106 * =====================================================================
107 *
108 * .. Parameters ..
109  DOUBLE PRECISION ONE
110  parameter( one = 1.0d+0 )
111 * ..
112 * .. Local Scalars ..
113  LOGICAL UPPER
114  INTEGER J, JC, JJ, JJN
115  DOUBLE PRECISION AJJ
116 * ..
117 * .. External Functions ..
118  LOGICAL LSAME
119  COMPLEX*16 ZDOTC
120  EXTERNAL lsame, zdotc
121 * ..
122 * .. External Subroutines ..
123  EXTERNAL xerbla, zdscal, zhpr, ztpmv, ztptri
124 * ..
125 * .. Intrinsic Functions ..
126  INTRINSIC dble
127 * ..
128 * .. Executable Statements ..
129 *
130 * Test the input parameters.
131 *
132  info = 0
133  upper = lsame( uplo, 'U' )
134  IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
135  info = -1
136  ELSE IF( n.LT.0 ) THEN
137  info = -2
138  END IF
139  IF( info.NE.0 ) THEN
140  CALL xerbla( 'ZPPTRI', -info )
141  RETURN
142  END IF
143 *
144 * Quick return if possible
145 *
146  IF( n.EQ.0 )
147  \$ RETURN
148 *
149 * Invert the triangular Cholesky factor U or L.
150 *
151  CALL ztptri( uplo, 'Non-unit', n, ap, info )
152  IF( info.GT.0 )
153  \$ RETURN
154  IF( upper ) THEN
155 *
156 * Compute the product inv(U) * inv(U)**H.
157 *
158  jj = 0
159  DO 10 j = 1, n
160  jc = jj + 1
161  jj = jj + j
162  IF( j.GT.1 )
163  \$ CALL zhpr( 'Upper', j-1, one, ap( jc ), 1, ap )
164  ajj = dble( ap( jj ) )
165  CALL zdscal( j, ajj, ap( jc ), 1 )
166  10 CONTINUE
167 *
168  ELSE
169 *
170 * Compute the product inv(L)**H * inv(L).
171 *
172  jj = 1
173  DO 20 j = 1, n
174  jjn = jj + n - j + 1
175  ap( jj ) = dble( zdotc( n-j+1, ap( jj ), 1, ap( jj ), 1 ) )
176  IF( j.LT.n )
177  \$ CALL ztpmv( 'Lower', 'Conjugate transpose', 'Non-unit',
178  \$ n-j, ap( jjn ), ap( jj+1 ), 1 )
179  jj = jjn
180  20 CONTINUE
181  END IF
182 *
183  RETURN
184 *
185 * End of ZPPTRI
186 *
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
subroutine zdscal(N, DA, ZX, INCX)
ZDSCAL
Definition: zdscal.f:78
complex *16 function zdotc(N, ZX, INCX, ZY, INCY)
ZDOTC
Definition: zdotc.f:83
subroutine zhpr(UPLO, N, ALPHA, X, INCX, AP)
ZHPR
Definition: zhpr.f:130
subroutine ztpmv(UPLO, TRANS, DIAG, N, AP, X, INCX)
ZTPMV
Definition: ztpmv.f:142
subroutine ztptri(UPLO, DIAG, N, AP, INFO)
ZTPTRI
Definition: ztptri.f:117
Here is the call graph for this function:
Here is the caller graph for this function: