zlapll()

subroutine zlapll	(	integer	n,
		complex*16, dimension( * )	x,
		integer	incx,
		complex*16, dimension( * )	y,
		integer	incy,
		double precision	ssmin
	)

ZLAPLL measures the linear dependence of two vectors.

Download ZLAPLL + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 Given two column vectors X and Y, let

                      A = ( X Y ).

 The subroutine first computes the QR factorization of A = Q*R,
 and then computes the SVD of the 2-by-2 upper triangular matrix R.
 The smaller singular value of R is returned in SSMIN, which is used
 as the measurement of the linear dependency of the vectors X and Y.

Parameters

[in]	N	N is INTEGER The length of the vectors X and Y.
[in,out]	X	X is COMPLEX*16 array, dimension (1+(N-1)*INCX) On entry, X contains the N-vector X. On exit, X is overwritten.
[in]	INCX	INCX is INTEGER The increment between successive elements of X. INCX > 0.
[in,out]	Y	Y is COMPLEX*16 array, dimension (1+(N-1)*INCY) On entry, Y contains the N-vector Y. On exit, Y is overwritten.
[in]	INCY	INCY is INTEGER The increment between successive elements of Y. INCY > 0.
[out]	SSMIN	SSMIN is DOUBLE PRECISION The smallest singular value of the N-by-2 matrix A = ( X Y ).

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 99 of file zlapll.f.

*
*  -- LAPACK auxiliary routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            INCX, INCY, N
      DOUBLE PRECISION   SSMIN
*     ..
*     .. Array Arguments ..
      COMPLEX*16         X( * ), Y( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO
      parameter( zero = 0.0d+0 )
      COMPLEX*16         CONE
      parameter( cone = ( 1.0d+0, 0.0d+0 ) )
*     ..
*     .. Local Scalars ..
      DOUBLE PRECISION   SSMAX
      COMPLEX*16         A11, A12, A22, C, TAU
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, dconjg
*     ..
*     .. External Functions ..
      COMPLEX*16         ZDOTC
      EXTERNAL           zdotc
*     ..
*     .. External Subroutines ..
      EXTERNAL           dlas2, zaxpy, zlarfg
*     ..
*     .. Executable Statements ..
*
*     Quick return if possible
*
      IF( n.LE.1 ) THEN
         ssmin = zero
         RETURN
      END IF
*
*     Compute the QR factorization of the N-by-2 matrix ( X Y )
*
      CALL zlarfg( n, x( 1 ), x( 1+incx ), incx, tau )
      a11 = x( 1 )
      x( 1 ) = cone
*
      c = -dconjg( tau )*zdotc( n, x, incx, y, incy )
      CALL zaxpy( n, c, x, incx, y, incy )
*
      CALL zlarfg( n-1, y( 1+incy ), y( 1+2*incy ), incy, tau )
*
      a12 = y( 1 )
      a22 = y( 1+incy )
*
*     Compute the SVD of 2-by-2 Upper triangular matrix.
*
      CALL dlas2( abs( a11 ), abs( a12 ), abs( a22 ), ssmin, ssmax )
*
      RETURN
*
*     End of ZLAPLL
*

Here is the call graph for this function:

Here is the caller graph for this function: