LAPACK  3.10.1 LAPACK: Linear Algebra PACKage

## ◆ zlanhs()

 double precision function zlanhs ( character NORM, integer N, complex*16, dimension( lda, * ) A, integer LDA, double precision, dimension( * ) WORK )

ZLANHS returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value of any element of an upper Hessenberg matrix.

Purpose:
``` ZLANHS  returns the value of the one norm,  or the Frobenius norm, or
the  infinity norm,  or the  element of  largest absolute value  of a
Hessenberg matrix A.```
Returns
ZLANHS
```    ZLANHS = ( max(abs(A(i,j))), NORM = 'M' or 'm'
(
( norm1(A),         NORM = '1', 'O' or 'o'
(
( normI(A),         NORM = 'I' or 'i'
(
( normF(A),         NORM = 'F', 'f', 'E' or 'e'

where  norm1  denotes the  one norm of a matrix (maximum column sum),
normI  denotes the  infinity norm  of a matrix  (maximum row sum) and
normF  denotes the  Frobenius norm of a matrix (square root of sum of
squares).  Note that  max(abs(A(i,j)))  is not a consistent matrix norm.```
Parameters
 [in] NORM ``` NORM is CHARACTER*1 Specifies the value to be returned in ZLANHS as described above.``` [in] N ``` N is INTEGER The order of the matrix A. N >= 0. When N = 0, ZLANHS is set to zero.``` [in] A ``` A is COMPLEX*16 array, dimension (LDA,N) The n by n upper Hessenberg matrix A; the part of A below the first sub-diagonal is not referenced.``` [in] LDA ``` LDA is INTEGER The leading dimension of the array A. LDA >= max(N,1).``` [out] WORK ``` WORK is DOUBLE PRECISION array, dimension (MAX(1,LWORK)), where LWORK >= N when NORM = 'I'; otherwise, WORK is not referenced.```

Definition at line 108 of file zlanhs.f.

109 *
110 * -- LAPACK auxiliary routine --
111 * -- LAPACK is a software package provided by Univ. of Tennessee, --
112 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
113 *
114 * .. Scalar Arguments ..
115  CHARACTER NORM
116  INTEGER LDA, N
117 * ..
118 * .. Array Arguments ..
119  DOUBLE PRECISION WORK( * )
120  COMPLEX*16 A( LDA, * )
121 * ..
122 *
123 * =====================================================================
124 *
125 * .. Parameters ..
126  DOUBLE PRECISION ONE, ZERO
127  parameter( one = 1.0d+0, zero = 0.0d+0 )
128 * ..
129 * .. Local Scalars ..
130  INTEGER I, J
131  DOUBLE PRECISION SCALE, SUM, VALUE
132 * ..
133 * .. External Functions ..
134  LOGICAL LSAME, DISNAN
135  EXTERNAL lsame, disnan
136 * ..
137 * .. External Subroutines ..
138  EXTERNAL zlassq
139 * ..
140 * .. Intrinsic Functions ..
141  INTRINSIC abs, min, sqrt
142 * ..
143 * .. Executable Statements ..
144 *
145  IF( n.EQ.0 ) THEN
146  VALUE = zero
147  ELSE IF( lsame( norm, 'M' ) ) THEN
148 *
149 * Find max(abs(A(i,j))).
150 *
151  VALUE = zero
152  DO 20 j = 1, n
153  DO 10 i = 1, min( n, j+1 )
154  sum = abs( a( i, j ) )
155  IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
156  10 CONTINUE
157  20 CONTINUE
158  ELSE IF( ( lsame( norm, 'O' ) ) .OR. ( norm.EQ.'1' ) ) THEN
159 *
160 * Find norm1(A).
161 *
162  VALUE = zero
163  DO 40 j = 1, n
164  sum = zero
165  DO 30 i = 1, min( n, j+1 )
166  sum = sum + abs( a( i, j ) )
167  30 CONTINUE
168  IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
169  40 CONTINUE
170  ELSE IF( lsame( norm, 'I' ) ) THEN
171 *
172 * Find normI(A).
173 *
174  DO 50 i = 1, n
175  work( i ) = zero
176  50 CONTINUE
177  DO 70 j = 1, n
178  DO 60 i = 1, min( n, j+1 )
179  work( i ) = work( i ) + abs( a( i, j ) )
180  60 CONTINUE
181  70 CONTINUE
182  VALUE = zero
183  DO 80 i = 1, n
184  sum = work( i )
185  IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
186  80 CONTINUE
187  ELSE IF( ( lsame( norm, 'F' ) ) .OR. ( lsame( norm, 'E' ) ) ) THEN
188 *
189 * Find normF(A).
190 *
191  scale = zero
192  sum = one
193  DO 90 j = 1, n
194  CALL zlassq( min( n, j+1 ), a( 1, j ), 1, scale, sum )
195  90 CONTINUE
196  VALUE = scale*sqrt( sum )
197  END IF
198 *
199  zlanhs = VALUE
200  RETURN
201 *
202 * End of ZLANHS
203 *
logical function disnan(DIN)
DISNAN tests input for NaN.
Definition: disnan.f:59
subroutine zlassq(n, x, incx, scl, sumsq)
ZLASSQ updates a sum of squares represented in scaled form.
Definition: zlassq.f90:137
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
double precision function zlanhs(NORM, N, A, LDA, WORK)
ZLANHS returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value ...
Definition: zlanhs.f:109
Here is the call graph for this function: