 LAPACK 3.11.0 LAPACK: Linear Algebra PACKage
Searching...
No Matches

## ◆ zlaqsp()

 subroutine zlaqsp ( character UPLO, integer N, complex*16, dimension( * ) AP, double precision, dimension( * ) S, double precision SCOND, double precision AMAX, character EQUED )

ZLAQSP scales a symmetric/Hermitian matrix in packed storage, using scaling factors computed by sppequ.

Purpose:
``` ZLAQSP equilibrates a symmetric matrix A using the scaling factors
in the vector S.```
Parameters
 [in] UPLO ``` UPLO is CHARACTER*1 Specifies whether the upper or lower triangular part of the symmetric matrix A is stored. = 'U': Upper triangular = 'L': Lower triangular``` [in] N ``` N is INTEGER The order of the matrix A. N >= 0.``` [in,out] AP ``` AP is COMPLEX*16 array, dimension (N*(N+1)/2) On entry, the upper or lower triangle of the symmetric matrix A, packed columnwise in a linear array. The j-th column of A is stored in the array AP as follows: if UPLO = 'U', AP(i + (j-1)*j/2) = A(i,j) for 1<=i<=j; if UPLO = 'L', AP(i + (j-1)*(2n-j)/2) = A(i,j) for j<=i<=n. On exit, the equilibrated matrix: diag(S) * A * diag(S), in the same storage format as A.``` [in] S ``` S is DOUBLE PRECISION array, dimension (N) The scale factors for A.``` [in] SCOND ``` SCOND is DOUBLE PRECISION Ratio of the smallest S(i) to the largest S(i).``` [in] AMAX ``` AMAX is DOUBLE PRECISION Absolute value of largest matrix entry.``` [out] EQUED ``` EQUED is CHARACTER*1 Specifies whether or not equilibration was done. = 'N': No equilibration. = 'Y': Equilibration was done, i.e., A has been replaced by diag(S) * A * diag(S).```
Internal Parameters:
```  THRESH is a threshold value used to decide if scaling should be done
based on the ratio of the scaling factors.  If SCOND < THRESH,
scaling is done.

LARGE and SMALL are threshold values used to decide if scaling should
be done based on the absolute size of the largest matrix element.
If AMAX > LARGE or AMAX < SMALL, scaling is done.```

Definition at line 125 of file zlaqsp.f.

126*
127* -- LAPACK auxiliary routine --
128* -- LAPACK is a software package provided by Univ. of Tennessee, --
129* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
130*
131* .. Scalar Arguments ..
132 CHARACTER EQUED, UPLO
133 INTEGER N
134 DOUBLE PRECISION AMAX, SCOND
135* ..
136* .. Array Arguments ..
137 DOUBLE PRECISION S( * )
138 COMPLEX*16 AP( * )
139* ..
140*
141* =====================================================================
142*
143* .. Parameters ..
144 DOUBLE PRECISION ONE, THRESH
145 parameter( one = 1.0d+0, thresh = 0.1d+0 )
146* ..
147* .. Local Scalars ..
148 INTEGER I, J, JC
149 DOUBLE PRECISION CJ, LARGE, SMALL
150* ..
151* .. External Functions ..
152 LOGICAL LSAME
153 DOUBLE PRECISION DLAMCH
154 EXTERNAL lsame, dlamch
155* ..
156* .. Executable Statements ..
157*
158* Quick return if possible
159*
160 IF( n.LE.0 ) THEN
161 equed = 'N'
162 RETURN
163 END IF
164*
165* Initialize LARGE and SMALL.
166*
167 small = dlamch( 'Safe minimum' ) / dlamch( 'Precision' )
168 large = one / small
169*
170 IF( scond.GE.thresh .AND. amax.GE.small .AND. amax.LE.large ) THEN
171*
172* No equilibration
173*
174 equed = 'N'
175 ELSE
176*
177* Replace A by diag(S) * A * diag(S).
178*
179 IF( lsame( uplo, 'U' ) ) THEN
180*
181* Upper triangle of A is stored.
182*
183 jc = 1
184 DO 20 j = 1, n
185 cj = s( j )
186 DO 10 i = 1, j
187 ap( jc+i-1 ) = cj*s( i )*ap( jc+i-1 )
188 10 CONTINUE
189 jc = jc + j
190 20 CONTINUE
191 ELSE
192*
193* Lower triangle of A is stored.
194*
195 jc = 1
196 DO 40 j = 1, n
197 cj = s( j )
198 DO 30 i = j, n
199 ap( jc+i-j ) = cj*s( i )*ap( jc+i-j )
200 30 CONTINUE
201 jc = jc + n - j + 1
202 40 CONTINUE
203 END IF
204 equed = 'Y'
205 END IF
206*
207 RETURN
208*
209* End of ZLAQSP
210*
double precision function dlamch(CMACH)
DLAMCH
Definition: dlamch.f:69
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53