LAPACK  3.10.1
LAPACK: Linear Algebra PACKage

◆ zlantr()

double precision function zlantr ( character  NORM,
character  UPLO,
character  DIAG,
integer  M,
integer  N,
complex*16, dimension( lda, * )  A,
integer  LDA,
double precision, dimension( * )  WORK 
)

ZLANTR returns the value of the 1-norm, or the Frobenius norm, or the infinity norm, or the element of largest absolute value of a trapezoidal or triangular matrix.

Download ZLANTR + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 ZLANTR  returns the value of the one norm,  or the Frobenius norm, or
 the  infinity norm,  or the  element of  largest absolute value  of a
 trapezoidal or triangular matrix A.
Returns
ZLANTR
    ZLANTR = ( max(abs(A(i,j))), NORM = 'M' or 'm'
             (
             ( norm1(A),         NORM = '1', 'O' or 'o'
             (
             ( normI(A),         NORM = 'I' or 'i'
             (
             ( normF(A),         NORM = 'F', 'f', 'E' or 'e'

 where  norm1  denotes the  one norm of a matrix (maximum column sum),
 normI  denotes the  infinity norm  of a matrix  (maximum row sum) and
 normF  denotes the  Frobenius norm of a matrix (square root of sum of
 squares).  Note that  max(abs(A(i,j)))  is not a consistent matrix norm.
Parameters
[in]NORM
          NORM is CHARACTER*1
          Specifies the value to be returned in ZLANTR as described
          above.
[in]UPLO
          UPLO is CHARACTER*1
          Specifies whether the matrix A is upper or lower trapezoidal.
          = 'U':  Upper trapezoidal
          = 'L':  Lower trapezoidal
          Note that A is triangular instead of trapezoidal if M = N.
[in]DIAG
          DIAG is CHARACTER*1
          Specifies whether or not the matrix A has unit diagonal.
          = 'N':  Non-unit diagonal
          = 'U':  Unit diagonal
[in]M
          M is INTEGER
          The number of rows of the matrix A.  M >= 0, and if
          UPLO = 'U', M <= N.  When M = 0, ZLANTR is set to zero.
[in]N
          N is INTEGER
          The number of columns of the matrix A.  N >= 0, and if
          UPLO = 'L', N <= M.  When N = 0, ZLANTR is set to zero.
[in]A
          A is COMPLEX*16 array, dimension (LDA,N)
          The trapezoidal matrix A (A is triangular if M = N).
          If UPLO = 'U', the leading m by n upper trapezoidal part of
          the array A contains the upper trapezoidal matrix, and the
          strictly lower triangular part of A is not referenced.
          If UPLO = 'L', the leading m by n lower trapezoidal part of
          the array A contains the lower trapezoidal matrix, and the
          strictly upper triangular part of A is not referenced.  Note
          that when DIAG = 'U', the diagonal elements of A are not
          referenced and are assumed to be one.
[in]LDA
          LDA is INTEGER
          The leading dimension of the array A.  LDA >= max(M,1).
[out]WORK
          WORK is DOUBLE PRECISION array, dimension (MAX(1,LWORK)),
          where LWORK >= M when NORM = 'I'; otherwise, WORK is not
          referenced.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.

Definition at line 140 of file zlantr.f.

142 *
143 * -- LAPACK auxiliary routine --
144 * -- LAPACK is a software package provided by Univ. of Tennessee, --
145 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
146 *
147 * .. Scalar Arguments ..
148  CHARACTER DIAG, NORM, UPLO
149  INTEGER LDA, M, N
150 * ..
151 * .. Array Arguments ..
152  DOUBLE PRECISION WORK( * )
153  COMPLEX*16 A( LDA, * )
154 * ..
155 *
156 * =====================================================================
157 *
158 * .. Parameters ..
159  DOUBLE PRECISION ONE, ZERO
160  parameter( one = 1.0d+0, zero = 0.0d+0 )
161 * ..
162 * .. Local Scalars ..
163  LOGICAL UDIAG
164  INTEGER I, J
165  DOUBLE PRECISION SCALE, SUM, VALUE
166 * ..
167 * .. External Functions ..
168  LOGICAL LSAME, DISNAN
169  EXTERNAL lsame, disnan
170 * ..
171 * .. External Subroutines ..
172  EXTERNAL zlassq
173 * ..
174 * .. Intrinsic Functions ..
175  INTRINSIC abs, min, sqrt
176 * ..
177 * .. Executable Statements ..
178 *
179  IF( min( m, n ).EQ.0 ) THEN
180  VALUE = zero
181  ELSE IF( lsame( norm, 'M' ) ) THEN
182 *
183 * Find max(abs(A(i,j))).
184 *
185  IF( lsame( diag, 'U' ) ) THEN
186  VALUE = one
187  IF( lsame( uplo, 'U' ) ) THEN
188  DO 20 j = 1, n
189  DO 10 i = 1, min( m, j-1 )
190  sum = abs( a( i, j ) )
191  IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
192  10 CONTINUE
193  20 CONTINUE
194  ELSE
195  DO 40 j = 1, n
196  DO 30 i = j + 1, m
197  sum = abs( a( i, j ) )
198  IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
199  30 CONTINUE
200  40 CONTINUE
201  END IF
202  ELSE
203  VALUE = zero
204  IF( lsame( uplo, 'U' ) ) THEN
205  DO 60 j = 1, n
206  DO 50 i = 1, min( m, j )
207  sum = abs( a( i, j ) )
208  IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
209  50 CONTINUE
210  60 CONTINUE
211  ELSE
212  DO 80 j = 1, n
213  DO 70 i = j, m
214  sum = abs( a( i, j ) )
215  IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
216  70 CONTINUE
217  80 CONTINUE
218  END IF
219  END IF
220  ELSE IF( ( lsame( norm, 'O' ) ) .OR. ( norm.EQ.'1' ) ) THEN
221 *
222 * Find norm1(A).
223 *
224  VALUE = zero
225  udiag = lsame( diag, 'U' )
226  IF( lsame( uplo, 'U' ) ) THEN
227  DO 110 j = 1, n
228  IF( ( udiag ) .AND. ( j.LE.m ) ) THEN
229  sum = one
230  DO 90 i = 1, j - 1
231  sum = sum + abs( a( i, j ) )
232  90 CONTINUE
233  ELSE
234  sum = zero
235  DO 100 i = 1, min( m, j )
236  sum = sum + abs( a( i, j ) )
237  100 CONTINUE
238  END IF
239  IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
240  110 CONTINUE
241  ELSE
242  DO 140 j = 1, n
243  IF( udiag ) THEN
244  sum = one
245  DO 120 i = j + 1, m
246  sum = sum + abs( a( i, j ) )
247  120 CONTINUE
248  ELSE
249  sum = zero
250  DO 130 i = j, m
251  sum = sum + abs( a( i, j ) )
252  130 CONTINUE
253  END IF
254  IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
255  140 CONTINUE
256  END IF
257  ELSE IF( lsame( norm, 'I' ) ) THEN
258 *
259 * Find normI(A).
260 *
261  IF( lsame( uplo, 'U' ) ) THEN
262  IF( lsame( diag, 'U' ) ) THEN
263  DO 150 i = 1, m
264  work( i ) = one
265  150 CONTINUE
266  DO 170 j = 1, n
267  DO 160 i = 1, min( m, j-1 )
268  work( i ) = work( i ) + abs( a( i, j ) )
269  160 CONTINUE
270  170 CONTINUE
271  ELSE
272  DO 180 i = 1, m
273  work( i ) = zero
274  180 CONTINUE
275  DO 200 j = 1, n
276  DO 190 i = 1, min( m, j )
277  work( i ) = work( i ) + abs( a( i, j ) )
278  190 CONTINUE
279  200 CONTINUE
280  END IF
281  ELSE
282  IF( lsame( diag, 'U' ) ) THEN
283  DO 210 i = 1, min( m, n )
284  work( i ) = one
285  210 CONTINUE
286  DO 220 i = n + 1, m
287  work( i ) = zero
288  220 CONTINUE
289  DO 240 j = 1, n
290  DO 230 i = j + 1, m
291  work( i ) = work( i ) + abs( a( i, j ) )
292  230 CONTINUE
293  240 CONTINUE
294  ELSE
295  DO 250 i = 1, m
296  work( i ) = zero
297  250 CONTINUE
298  DO 270 j = 1, n
299  DO 260 i = j, m
300  work( i ) = work( i ) + abs( a( i, j ) )
301  260 CONTINUE
302  270 CONTINUE
303  END IF
304  END IF
305  VALUE = zero
306  DO 280 i = 1, m
307  sum = work( i )
308  IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
309  280 CONTINUE
310  ELSE IF( ( lsame( norm, 'F' ) ) .OR. ( lsame( norm, 'E' ) ) ) THEN
311 *
312 * Find normF(A).
313 *
314  IF( lsame( uplo, 'U' ) ) THEN
315  IF( lsame( diag, 'U' ) ) THEN
316  scale = one
317  sum = min( m, n )
318  DO 290 j = 2, n
319  CALL zlassq( min( m, j-1 ), a( 1, j ), 1, scale, sum )
320  290 CONTINUE
321  ELSE
322  scale = zero
323  sum = one
324  DO 300 j = 1, n
325  CALL zlassq( min( m, j ), a( 1, j ), 1, scale, sum )
326  300 CONTINUE
327  END IF
328  ELSE
329  IF( lsame( diag, 'U' ) ) THEN
330  scale = one
331  sum = min( m, n )
332  DO 310 j = 1, n
333  CALL zlassq( m-j, a( min( m, j+1 ), j ), 1, scale,
334  $ sum )
335  310 CONTINUE
336  ELSE
337  scale = zero
338  sum = one
339  DO 320 j = 1, n
340  CALL zlassq( m-j+1, a( j, j ), 1, scale, sum )
341  320 CONTINUE
342  END IF
343  END IF
344  VALUE = scale*sqrt( sum )
345  END IF
346 *
347  zlantr = VALUE
348  RETURN
349 *
350 * End of ZLANTR
351 *
logical function disnan(DIN)
DISNAN tests input for NaN.
Definition: disnan.f:59
subroutine zlassq(n, x, incx, scl, sumsq)
ZLASSQ updates a sum of squares represented in scaled form.
Definition: zlassq.f90:137
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
double precision function zlantr(NORM, UPLO, DIAG, M, N, A, LDA, WORK)
ZLANTR returns the value of the 1-norm, or the Frobenius norm, or the infinity norm,...
Definition: zlantr.f:142
Here is the call graph for this function: