LAPACK  3.10.1
LAPACK: Linear Algebra PACKage

◆ cgtsvx()

subroutine cgtsvx ( character  FACT,
character  TRANS,
integer  N,
integer  NRHS,
complex, dimension( * )  DL,
complex, dimension( * )  D,
complex, dimension( * )  DU,
complex, dimension( * )  DLF,
complex, dimension( * )  DF,
complex, dimension( * )  DUF,
complex, dimension( * )  DU2,
integer, dimension( * )  IPIV,
complex, dimension( ldb, * )  B,
integer  LDB,
complex, dimension( ldx, * )  X,
integer  LDX,
real  RCOND,
real, dimension( * )  FERR,
real, dimension( * )  BERR,
complex, dimension( * )  WORK,
real, dimension( * )  RWORK,
integer  INFO 
)

CGTSVX computes the solution to system of linear equations A * X = B for GT matrices

Download CGTSVX + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 CGTSVX uses the LU factorization to compute the solution to a complex
 system of linear equations A * X = B, A**T * X = B, or A**H * X = B,
 where A is a tridiagonal matrix of order N and X and B are N-by-NRHS
 matrices.

 Error bounds on the solution and a condition estimate are also
 provided.
Description:
 The following steps are performed:

 1. If FACT = 'N', the LU decomposition is used to factor the matrix A
    as A = L * U, where L is a product of permutation and unit lower
    bidiagonal matrices and U is upper triangular with nonzeros in
    only the main diagonal and first two superdiagonals.

 2. If some U(i,i)=0, so that U is exactly singular, then the routine
    returns with INFO = i. Otherwise, the factored form of A is used
    to estimate the condition number of the matrix A.  If the
    reciprocal of the condition number is less than machine precision,
    INFO = N+1 is returned as a warning, but the routine still goes on
    to solve for X and compute error bounds as described below.

 3. The system of equations is solved for X using the factored form
    of A.

 4. Iterative refinement is applied to improve the computed solution
    matrix and calculate error bounds and backward error estimates
    for it.
Parameters
[in]FACT
          FACT is CHARACTER*1
          Specifies whether or not the factored form of A has been
          supplied on entry.
          = 'F':  DLF, DF, DUF, DU2, and IPIV contain the factored form
                  of A; DL, D, DU, DLF, DF, DUF, DU2 and IPIV will not
                  be modified.
          = 'N':  The matrix will be copied to DLF, DF, and DUF
                  and factored.
[in]TRANS
          TRANS is CHARACTER*1
          Specifies the form of the system of equations:
          = 'N':  A * X = B     (No transpose)
          = 'T':  A**T * X = B  (Transpose)
          = 'C':  A**H * X = B  (Conjugate transpose)
[in]N
          N is INTEGER
          The order of the matrix A.  N >= 0.
[in]NRHS
          NRHS is INTEGER
          The number of right hand sides, i.e., the number of columns
          of the matrix B.  NRHS >= 0.
[in]DL
          DL is COMPLEX array, dimension (N-1)
          The (n-1) subdiagonal elements of A.
[in]D
          D is COMPLEX array, dimension (N)
          The n diagonal elements of A.
[in]DU
          DU is COMPLEX array, dimension (N-1)
          The (n-1) superdiagonal elements of A.
[in,out]DLF
          DLF is COMPLEX array, dimension (N-1)
          If FACT = 'F', then DLF is an input argument and on entry
          contains the (n-1) multipliers that define the matrix L from
          the LU factorization of A as computed by CGTTRF.

          If FACT = 'N', then DLF is an output argument and on exit
          contains the (n-1) multipliers that define the matrix L from
          the LU factorization of A.
[in,out]DF
          DF is COMPLEX array, dimension (N)
          If FACT = 'F', then DF is an input argument and on entry
          contains the n diagonal elements of the upper triangular
          matrix U from the LU factorization of A.

          If FACT = 'N', then DF is an output argument and on exit
          contains the n diagonal elements of the upper triangular
          matrix U from the LU factorization of A.
[in,out]DUF
          DUF is COMPLEX array, dimension (N-1)
          If FACT = 'F', then DUF is an input argument and on entry
          contains the (n-1) elements of the first superdiagonal of U.

          If FACT = 'N', then DUF is an output argument and on exit
          contains the (n-1) elements of the first superdiagonal of U.
[in,out]DU2
          DU2 is COMPLEX array, dimension (N-2)
          If FACT = 'F', then DU2 is an input argument and on entry
          contains the (n-2) elements of the second superdiagonal of
          U.

          If FACT = 'N', then DU2 is an output argument and on exit
          contains the (n-2) elements of the second superdiagonal of
          U.
[in,out]IPIV
          IPIV is INTEGER array, dimension (N)
          If FACT = 'F', then IPIV is an input argument and on entry
          contains the pivot indices from the LU factorization of A as
          computed by CGTTRF.

          If FACT = 'N', then IPIV is an output argument and on exit
          contains the pivot indices from the LU factorization of A;
          row i of the matrix was interchanged with row IPIV(i).
          IPIV(i) will always be either i or i+1; IPIV(i) = i indicates
          a row interchange was not required.
[in]B
          B is COMPLEX array, dimension (LDB,NRHS)
          The N-by-NRHS right hand side matrix B.
[in]LDB
          LDB is INTEGER
          The leading dimension of the array B.  LDB >= max(1,N).
[out]X
          X is COMPLEX array, dimension (LDX,NRHS)
          If INFO = 0 or INFO = N+1, the N-by-NRHS solution matrix X.
[in]LDX
          LDX is INTEGER
          The leading dimension of the array X.  LDX >= max(1,N).
[out]RCOND
          RCOND is REAL
          The estimate of the reciprocal condition number of the matrix
          A.  If RCOND is less than the machine precision (in
          particular, if RCOND = 0), the matrix is singular to working
          precision.  This condition is indicated by a return code of
          INFO > 0.
[out]FERR
          FERR is REAL array, dimension (NRHS)
          The estimated forward error bound for each solution vector
          X(j) (the j-th column of the solution matrix X).
          If XTRUE is the true solution corresponding to X(j), FERR(j)
          is an estimated upper bound for the magnitude of the largest
          element in (X(j) - XTRUE) divided by the magnitude of the
          largest element in X(j).  The estimate is as reliable as
          the estimate for RCOND, and is almost always a slight
          overestimate of the true error.
[out]BERR
          BERR is REAL array, dimension (NRHS)
          The componentwise relative backward error of each solution
          vector X(j) (i.e., the smallest relative change in
          any element of A or B that makes X(j) an exact solution).
[out]WORK
          WORK is COMPLEX array, dimension (2*N)
[out]RWORK
          RWORK is REAL array, dimension (N)
[out]INFO
          INFO is INTEGER
          = 0:  successful exit
          < 0:  if INFO = -i, the i-th argument had an illegal value
          > 0:  if INFO = i, and i is
                <= N:  U(i,i) is exactly zero.  The factorization
                       has not been completed unless i = N, but the
                       factor U is exactly singular, so the solution
                       and error bounds could not be computed.
                       RCOND = 0 is returned.
                = N+1: U is nonsingular, but RCOND is less than machine
                       precision, meaning that the matrix is singular
                       to working precision.  Nevertheless, the
                       solution and error bounds are computed because
                       there are a number of situations where the
                       computed solution can be more accurate than the
                       value of RCOND would suggest.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.

Definition at line 291 of file cgtsvx.f.

294 *
295 * -- LAPACK driver routine --
296 * -- LAPACK is a software package provided by Univ. of Tennessee, --
297 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
298 *
299 * .. Scalar Arguments ..
300  CHARACTER FACT, TRANS
301  INTEGER INFO, LDB, LDX, N, NRHS
302  REAL RCOND
303 * ..
304 * .. Array Arguments ..
305  INTEGER IPIV( * )
306  REAL BERR( * ), FERR( * ), RWORK( * )
307  COMPLEX B( LDB, * ), D( * ), DF( * ), DL( * ),
308  $ DLF( * ), DU( * ), DU2( * ), DUF( * ),
309  $ WORK( * ), X( LDX, * )
310 * ..
311 *
312 * =====================================================================
313 *
314 * .. Parameters ..
315  REAL ZERO
316  parameter( zero = 0.0e+0 )
317 * ..
318 * .. Local Scalars ..
319  LOGICAL NOFACT, NOTRAN
320  CHARACTER NORM
321  REAL ANORM
322 * ..
323 * .. External Functions ..
324  LOGICAL LSAME
325  REAL CLANGT, SLAMCH
326  EXTERNAL lsame, clangt, slamch
327 * ..
328 * .. External Subroutines ..
329  EXTERNAL ccopy, cgtcon, cgtrfs, cgttrf, cgttrs, clacpy,
330  $ xerbla
331 * ..
332 * .. Intrinsic Functions ..
333  INTRINSIC max
334 * ..
335 * .. Executable Statements ..
336 *
337  info = 0
338  nofact = lsame( fact, 'N' )
339  notran = lsame( trans, 'N' )
340  IF( .NOT.nofact .AND. .NOT.lsame( fact, 'F' ) ) THEN
341  info = -1
342  ELSE IF( .NOT.notran .AND. .NOT.lsame( trans, 'T' ) .AND. .NOT.
343  $ lsame( trans, 'C' ) ) THEN
344  info = -2
345  ELSE IF( n.LT.0 ) THEN
346  info = -3
347  ELSE IF( nrhs.LT.0 ) THEN
348  info = -4
349  ELSE IF( ldb.LT.max( 1, n ) ) THEN
350  info = -14
351  ELSE IF( ldx.LT.max( 1, n ) ) THEN
352  info = -16
353  END IF
354  IF( info.NE.0 ) THEN
355  CALL xerbla( 'CGTSVX', -info )
356  RETURN
357  END IF
358 *
359  IF( nofact ) THEN
360 *
361 * Compute the LU factorization of A.
362 *
363  CALL ccopy( n, d, 1, df, 1 )
364  IF( n.GT.1 ) THEN
365  CALL ccopy( n-1, dl, 1, dlf, 1 )
366  CALL ccopy( n-1, du, 1, duf, 1 )
367  END IF
368  CALL cgttrf( n, dlf, df, duf, du2, ipiv, info )
369 *
370 * Return if INFO is non-zero.
371 *
372  IF( info.GT.0 )THEN
373  rcond = zero
374  RETURN
375  END IF
376  END IF
377 *
378 * Compute the norm of the matrix A.
379 *
380  IF( notran ) THEN
381  norm = '1'
382  ELSE
383  norm = 'I'
384  END IF
385  anorm = clangt( norm, n, dl, d, du )
386 *
387 * Compute the reciprocal of the condition number of A.
388 *
389  CALL cgtcon( norm, n, dlf, df, duf, du2, ipiv, anorm, rcond, work,
390  $ info )
391 *
392 * Compute the solution vectors X.
393 *
394  CALL clacpy( 'Full', n, nrhs, b, ldb, x, ldx )
395  CALL cgttrs( trans, n, nrhs, dlf, df, duf, du2, ipiv, x, ldx,
396  $ info )
397 *
398 * Use iterative refinement to improve the computed solutions and
399 * compute error bounds and backward error estimates for them.
400 *
401  CALL cgtrfs( trans, n, nrhs, dl, d, du, dlf, df, duf, du2, ipiv,
402  $ b, ldb, x, ldx, ferr, berr, work, rwork, info )
403 *
404 * Set INFO = N+1 if the matrix is singular to working precision.
405 *
406  IF( rcond.LT.slamch( 'Epsilon' ) )
407  $ info = n + 1
408 *
409  RETURN
410 *
411 * End of CGTSVX
412 *
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
subroutine ccopy(N, CX, INCX, CY, INCY)
CCOPY
Definition: ccopy.f:81
subroutine cgttrf(N, DL, D, DU, DU2, IPIV, INFO)
CGTTRF
Definition: cgttrf.f:124
subroutine cgtcon(NORM, N, DL, D, DU, DU2, IPIV, ANORM, RCOND, WORK, INFO)
CGTCON
Definition: cgtcon.f:141
subroutine cgtrfs(TRANS, N, NRHS, DL, D, DU, DLF, DF, DUF, DU2, IPIV, B, LDB, X, LDX, FERR, BERR, WORK, RWORK, INFO)
CGTRFS
Definition: cgtrfs.f:210
subroutine cgttrs(TRANS, N, NRHS, DL, D, DU, DU2, IPIV, B, LDB, INFO)
CGTTRS
Definition: cgttrs.f:138
real function clangt(NORM, N, DL, D, DU)
CLANGT returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value ...
Definition: clangt.f:106
subroutine clacpy(UPLO, M, N, A, LDA, B, LDB)
CLACPY copies all or part of one two-dimensional array to another.
Definition: clacpy.f:103
real function slamch(CMACH)
SLAMCH
Definition: slamch.f:68
Here is the call graph for this function:
Here is the caller graph for this function: