ctbt05()

subroutine ctbt05	(	character	uplo,
		character	trans,
		character	diag,
		integer	n,
		integer	kd,
		integer	nrhs,
		complex, dimension( ldab, * )	ab,
		integer	ldab,
		complex, dimension( ldb, * )	b,
		integer	ldb,
		complex, dimension( ldx, * )	x,
		integer	ldx,
		complex, dimension( ldxact, * )	xact,
		integer	ldxact,
		real, dimension( * )	ferr,
		real, dimension( * )	berr,
		real, dimension( * )	reslts )

CTBT05

Purpose:

!>
!> CTBT05 tests the error bounds from iterative refinement for the
!> computed solution to a system of equations A*X = B, where A is a
!> triangular band matrix.
!>
!> RESLTS(1) = test of the error bound
!>           = norm(X - XACT) / ( norm(X) * FERR )
!>
!> A large value is returned if this ratio is not less than one.
!>
!> RESLTS(2) = residual from the iterative refinement routine
!>           = the maximum of BERR / ( NZ*EPS + (*) ), where
!>             (*) = NZ*UNFL / (min_i (abs(A)*abs(X) +abs(b))_i )
!>             and NZ = max. number of nonzeros in any row of A, plus 1
!> 

Parameters

[in]	UPLO	!> UPLO is CHARACTER*1 !> Specifies whether the matrix A is upper or lower triangular. !> = 'U': Upper triangular !> = 'L': Lower triangular !>
[in]	TRANS	!> TRANS is CHARACTER*1 !> Specifies the form of the system of equations. !> = 'N': A * X = B (No transpose) !> = 'T': A'* X = B (Transpose) !> = 'C': A'* X = B (Conjugate transpose = Transpose) !>
[in]	DIAG	!> DIAG is CHARACTER*1 !> Specifies whether or not the matrix A is unit triangular. !> = 'N': Non-unit triangular !> = 'U': Unit triangular !>
[in]	N	!> N is INTEGER !> The number of rows of the matrices X, B, and XACT, and the !> order of the matrix A. N >= 0. !>
[in]	KD	!> KD is INTEGER !> The number of super-diagonals of the matrix A if UPLO = 'U', !> or the number of sub-diagonals if UPLO = 'L'. KD >= 0. !>
[in]	NRHS	!> NRHS is INTEGER !> The number of columns of the matrices X, B, and XACT. !> NRHS >= 0. !>
[in]	AB	!> AB is COMPLEX array, dimension (LDAB,N) !> The upper or lower triangular band matrix A, stored in the !> first kd+1 rows of the array. The j-th column of A is stored !> in the j-th column of the array AB as follows: !> if UPLO = 'U', AB(kd+1+i-j,j) = A(i,j) for max(1,j-kd)<=i<=j; !> if UPLO = 'L', AB(1+i-j,j) = A(i,j) for j<=i<=min(n,j+kd). !> If DIAG = 'U', the diagonal elements of A are not referenced !> and are assumed to be 1. !>
[in]	LDAB	!> LDAB is INTEGER !> The leading dimension of the array AB. LDAB >= KD+1. !>
[in]	B	!> B is COMPLEX array, dimension (LDB,NRHS) !> The right hand side vectors for the system of linear !> equations. !>
[in]	LDB	!> LDB is INTEGER !> The leading dimension of the array B. LDB >= max(1,N). !>
[in]	X	!> X is COMPLEX array, dimension (LDX,NRHS) !> The computed solution vectors. Each vector is stored as a !> column of the matrix X. !>
[in]	LDX	!> LDX is INTEGER !> The leading dimension of the array X. LDX >= max(1,N). !>
[in]	XACT	!> XACT is COMPLEX array, dimension (LDX,NRHS) !> The exact solution vectors. Each vector is stored as a !> column of the matrix XACT. !>
[in]	LDXACT	!> LDXACT is INTEGER !> The leading dimension of the array XACT. LDXACT >= max(1,N). !>
[in]	FERR	!> FERR is REAL array, dimension (NRHS) !> The estimated forward error bounds for each solution vector !> X. If XTRUE is the true solution, FERR bounds the magnitude !> of the largest entry in (X - XTRUE) divided by the magnitude !> of the largest entry in X. !>
[in]	BERR	!> BERR is REAL array, dimension (NRHS) !> The componentwise relative backward error of each solution !> vector (i.e., the smallest relative change in any entry of A !> or B that makes X an exact solution). !>
[out]	RESLTS	!> RESLTS is REAL array, dimension (2) !> The maximum over the NRHS solution vectors of the ratios: !> RESLTS(1) = norm(X - XACT) / ( norm(X) * FERR ) !> RESLTS(2) = BERR / ( NZ*EPS + (*) ) !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 187 of file ctbt05.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          DIAG, TRANS, UPLO
      INTEGER            KD, LDAB, LDB, LDX, LDXACT, N, NRHS
*     ..
*     .. Array Arguments ..
      REAL               BERR( * ), FERR( * ), RESLTS( * )
      COMPLEX            AB( LDAB, * ), B( LDB, * ), X( LDX, * ),
     $                   XACT( LDXACT, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE
      parameter( zero = 0.0e+0, one = 1.0e+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            NOTRAN, UNIT, UPPER
      INTEGER            I, IFU, IMAX, J, K, NZ
      REAL               AXBI, DIFF, EPS, ERRBND, OVFL, TMP, UNFL, XNORM
      COMPLEX            ZDUM
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            ICAMAX
      REAL               SLAMCH
      EXTERNAL           lsame, icamax, slamch
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, aimag, max, min, real
*     ..
*     .. Statement Functions ..
      REAL               CABS1
*     ..
*     .. Statement Function definitions ..
      cabs1( zdum ) = abs( real( zdum ) ) + abs( aimag( zdum ) )
*     ..
*     .. Executable Statements ..
*
*     Quick exit if N = 0 or NRHS = 0.
*
      IF( n.LE.0 .OR. nrhs.LE.0 ) THEN
         reslts( 1 ) = zero
         reslts( 2 ) = zero
         RETURN
      END IF
*
      eps = slamch( 'Epsilon' )
      unfl = slamch( 'Safe minimum' )
      ovfl = one / unfl
      upper = lsame( uplo, 'U' )
      notran = lsame( trans, 'N' )
      unit = lsame( diag, 'U' )
      nz = min( kd, n-1 ) + 1
*
*     Test 1:  Compute the maximum of
*        norm(X - XACT) / ( norm(X) * FERR )
*     over all the vectors X and XACT using the infinity-norm.
*
      errbnd = zero
      DO 30 j = 1, nrhs
         imax = icamax( n, x( 1, j ), 1 )
         xnorm = max( cabs1( x( imax, j ) ), unfl )
         diff = zero
         DO 10 i = 1, n
            diff = max( diff, cabs1( x( i, j )-xact( i, j ) ) )
   10    CONTINUE
*
         IF( xnorm.GT.one ) THEN
            GO TO 20
         ELSE IF( diff.LE.ovfl*xnorm ) THEN
            GO TO 20
         ELSE
            errbnd = one / eps
            GO TO 30
         END IF
*
   20    CONTINUE
         IF( diff / xnorm.LE.ferr( j ) ) THEN
            errbnd = max( errbnd, ( diff / xnorm ) / ferr( j ) )
         ELSE
            errbnd = one / eps
         END IF
   30 CONTINUE
      reslts( 1 ) = errbnd
*
*     Test 2:  Compute the maximum of BERR / ( NZ*EPS + (*) ), where
*     (*) = NZ*UNFL / (min_i (abs(A)*abs(X) +abs(b))_i )
*
      ifu = 0
      IF( unit )
     $   ifu = 1
      DO 90 k = 1, nrhs
         DO 80 i = 1, n
            tmp = cabs1( b( i, k ) )
            IF( upper ) THEN
               IF( .NOT.notran ) THEN
                  DO 40 j = max( i-kd, 1 ), i - ifu
                     tmp = tmp + cabs1( ab( kd+1-i+j, i ) )*
     $                     cabs1( x( j, k ) )
   40             CONTINUE
                  IF( unit )
     $               tmp = tmp + cabs1( x( i, k ) )
               ELSE
                  IF( unit )
     $               tmp = tmp + cabs1( x( i, k ) )
                  DO 50 j = i + ifu, min( i+kd, n )
                     tmp = tmp + cabs1( ab( kd+1+i-j, j ) )*
     $                     cabs1( x( j, k ) )
   50             CONTINUE
               END IF
            ELSE
               IF( notran ) THEN
                  DO 60 j = max( i-kd, 1 ), i - ifu
                     tmp = tmp + cabs1( ab( 1+i-j, j ) )*
     $                     cabs1( x( j, k ) )
   60             CONTINUE
                  IF( unit )
     $               tmp = tmp + cabs1( x( i, k ) )
               ELSE
                  IF( unit )
     $               tmp = tmp + cabs1( x( i, k ) )
                  DO 70 j = i + ifu, min( i+kd, n )
                     tmp = tmp + cabs1( ab( 1+j-i, i ) )*
     $                     cabs1( x( j, k ) )
   70             CONTINUE
               END IF
            END IF
            IF( i.EQ.1 ) THEN
               axbi = tmp
            ELSE
               axbi = min( axbi, tmp )
            END IF
   80    CONTINUE
         tmp = berr( k ) / ( nz*eps+nz*unfl / max( axbi, nz*unfl ) )
         IF( k.EQ.1 ) THEN
            reslts( 2 ) = tmp
         ELSE
            reslts( 2 ) = max( reslts( 2 ), tmp )
         END IF
   90 CONTINUE
*
      RETURN
*
*     End of CTBT05
*

Here is the caller graph for this function: