subroutine spot03	(	character	UPLO,
		integer	N,
		real, dimension( lda, * )	A,
		integer	LDA,
		real, dimension( ldainv, * )	AINV,
		integer	LDAINV,
		real, dimension( ldwork, * )	WORK,
		integer	LDWORK,
		real, dimension( * )	RWORK,
		real	RCOND,
		real	RESID
	)

SPOT03

Purpose:

 SPOT03 computes the residual for a symmetric matrix times its
 inverse:
    norm( I - A*AINV ) / ( N * norm(A) * norm(AINV) * EPS ),
 where EPS is the machine epsilon.

Parameters

[in]	UPLO	UPLO is CHARACTER*1 Specifies whether the upper or lower triangular part of the symmetric matrix A is stored: = 'U': Upper triangular = 'L': Lower triangular
[in]	N	N is INTEGER The number of rows and columns of the matrix A. N >= 0.
[in]	A	A is REAL array, dimension (LDA,N) The original symmetric matrix A.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,N)
[in,out]	AINV	AINV is REAL array, dimension (LDAINV,N) On entry, the inverse of the matrix A, stored as a symmetric matrix in the same format as A. In this version, AINV is expanded into a full matrix and multiplied by A, so the opposing triangle of AINV will be changed; i.e., if the upper triangular part of AINV is stored, the lower triangular part will be used as work space.
[in]	LDAINV	LDAINV is INTEGER The leading dimension of the array AINV. LDAINV >= max(1,N).
[out]	WORK	WORK is REAL array, dimension (LDWORK,N)
[in]	LDWORK	LDWORK is INTEGER The leading dimension of the array WORK. LDWORK >= max(1,N).
[out]	RWORK	RWORK is REAL array, dimension (N)
[out]	RCOND	RCOND is REAL The reciprocal of the condition number of A, computed as ( 1/norm(A) ) / norm(AINV).
[out]	RESID	RESID is REAL norm(I - A*AINV) / ( N * norm(A) * norm(AINV) * EPS )

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

November 2011

Definition at line 127 of file spot03.f.

*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      CHARACTER          uplo
      INTEGER            lda, ldainv, ldwork, n
      REAL               rcond, resid
*     ..
*     .. Array Arguments ..
      REAL               a( lda, * ), ainv( ldainv, * ), rwork( * ),
     $                   work( ldwork, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               zero, one
      parameter                ( zero = 0.0e+0, one = 1.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            i, j
      REAL               ainvnm, anorm, eps
*     ..
*     .. External Functions ..
      LOGICAL            lsame
      REAL               slamch, slange, slansy
      EXTERNAL           lsame, slamch, slange, slansy
*     ..
*     .. External Subroutines ..
      EXTERNAL           ssymm
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          real
*     ..
*     .. Executable Statements ..
*
*     Quick exit if N = 0.
*
      IF( n.LE.0 ) THEN
         rcond = one
         resid = zero
         RETURN
      END IF
*
*     Exit with RESID = 1/EPS if ANORM = 0 or AINVNM = 0.
*
      eps = slamch( 'Epsilon' )
      anorm = slansy( '1', uplo, n, a, lda, rwork )
      ainvnm = slansy( '1', uplo, n, ainv, ldainv, rwork )
      IF( anorm.LE.zero .OR. ainvnm.LE.zero ) THEN
         rcond = zero
         resid = one / eps
         RETURN
      END IF
      rcond = ( one / anorm ) / ainvnm
*
*     Expand AINV into a full matrix and call SSYMM to multiply
*     AINV on the left by A.
*
      IF( lsame( uplo, 'U' ) ) THEN
         DO 20 j = 1, n
            DO 10 i = 1, j - 1
               ainv( j, i ) = ainv( i, j )
   10       CONTINUE
   20    CONTINUE
      ELSE
         DO 40 j = 1, n
            DO 30 i = j + 1, n
               ainv( j, i ) = ainv( i, j )
   30       CONTINUE
   40    CONTINUE
      END IF
      CALL ssymm( 'Left', uplo, n, n, -one, a, lda, ainv, ldainv, zero,
     $            work, ldwork )
*
*     Add the identity matrix to WORK .
*
      DO 50 i = 1, n
         work( i, i ) = work( i, i ) + one
   50 CONTINUE
*
*     Compute norm(I - A*AINV) / (N * norm(A) * norm(AINV) * EPS)
*
      resid = slange( '1', n, n, work, ldwork, rwork )
*
      resid = ( ( resid*rcond ) / eps ) / REAL( n )
*
      RETURN
*
*     End of SPOT03
*

Here is the call graph for this function:

Here is the caller graph for this function: