subroutine zlaesy	(	complex*16	A,
		complex*16	B,
		complex*16	C,
		complex*16	RT1,
		complex*16	RT2,
		complex*16	EVSCAL,
		complex*16	CS1,
		complex*16	SN1
	)

ZLAESY computes the eigenvalues and eigenvectors of a 2-by-2 complex symmetric matrix.

Download ZLAESY + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 ZLAESY computes the eigendecomposition of a 2-by-2 symmetric matrix
    ( ( A, B );( B, C ) )
 provided the norm of the matrix of eigenvectors is larger than
 some threshold value.

 RT1 is the eigenvalue of larger absolute value, and RT2 of
 smaller absolute value.  If the eigenvectors are computed, then
 on return ( CS1, SN1 ) is the unit eigenvector for RT1, hence

 [  CS1     SN1   ] . [ A  B ] . [ CS1    -SN1   ] = [ RT1  0  ]
 [ -SN1     CS1   ]   [ B  C ]   [ SN1     CS1   ]   [  0  RT2 ]

Parameters

[in]	A	A is COMPLEX*16 The ( 1, 1 ) element of input matrix.
[in]	B	B is COMPLEX*16 The ( 1, 2 ) element of input matrix. The ( 2, 1 ) element is also given by B, since the 2-by-2 matrix is symmetric.
[in]	C	C is COMPLEX*16 The ( 2, 2 ) element of input matrix.
[out]	RT1	RT1 is COMPLEX*16 The eigenvalue of larger modulus.
[out]	RT2	RT2 is COMPLEX*16 The eigenvalue of smaller modulus.
[out]	EVSCAL	EVSCAL is COMPLEX*16 The complex value by which the eigenvector matrix was scaled to make it orthonormal. If EVSCAL is zero, the eigenvectors were not computed. This means one of two things: the 2-by-2 matrix could not be diagonalized, or the norm of the matrix of eigenvectors before scaling was larger than the threshold value THRESH (set below).
[out]	CS1	CS1 is COMPLEX*16
[out]	SN1	SN1 is COMPLEX*16 If EVSCAL .NE. 0, ( CS1, SN1 ) is the unit right eigenvector for RT1.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

September 2012

Definition at line 117 of file zlaesy.f.

*
*  -- LAPACK auxiliary routine (version 3.4.2) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     September 2012
*
*     .. Scalar Arguments ..
      COMPLEX*16         a, b, c, cs1, evscal, rt1, rt2, sn1
*     ..
*
* =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   zero
      parameter                ( zero = 0.0d0 )
      DOUBLE PRECISION   one
      parameter                ( one = 1.0d0 )
      COMPLEX*16         cone
      parameter                ( cone = ( 1.0d0, 0.0d0 ) )
      DOUBLE PRECISION   half
      parameter                ( half = 0.5d0 )
      DOUBLE PRECISION   thresh
      parameter                ( thresh = 0.1d0 )
*     ..
*     .. Local Scalars ..
      DOUBLE PRECISION   babs, evnorm, tabs, z
      COMPLEX*16         s, t, tmp
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, max, sqrt
*     ..
*     .. Executable Statements ..
*
*
*     Special case:  The matrix is actually diagonal.
*     To avoid divide by zero later, we treat this case separately.
*
      IF( abs( b ).EQ.zero ) THEN
         rt1 = a
         rt2 = c
         IF( abs( rt1 ).LT.abs( rt2 ) ) THEN
            tmp = rt1
            rt1 = rt2
            rt2 = tmp
            cs1 = zero
            sn1 = one
         ELSE
            cs1 = one
            sn1 = zero
         END IF
      ELSE
*
*        Compute the eigenvalues and eigenvectors.
*        The characteristic equation is
*           lambda **2 - (A+C) lambda + (A*C - B*B)
*        and we solve it using the quadratic formula.
*
         s = ( a+c )*half
         t = ( a-c )*half
*
*        Take the square root carefully to avoid over/under flow.
*
         babs = abs( b )
         tabs = abs( t )
         z = max( babs, tabs )
         IF( z.GT.zero )
     $      t = z*sqrt( ( t / z )**2+( b / z )**2 )
*
*        Compute the two eigenvalues.  RT1 and RT2 are exchanged
*        if necessary so that RT1 will have the greater magnitude.
*
         rt1 = s + t
         rt2 = s - t
         IF( abs( rt1 ).LT.abs( rt2 ) ) THEN
            tmp = rt1
            rt1 = rt2
            rt2 = tmp
         END IF
*
*        Choose CS1 = 1 and SN1 to satisfy the first equation, then
*        scale the components of this eigenvector so that the matrix
*        of eigenvectors X satisfies  X * X**T = I .  (No scaling is
*        done if the norm of the eigenvalue matrix is less than THRESH.)
*
         sn1 = ( rt1-a ) / b
         tabs = abs( sn1 )
         IF( tabs.GT.one ) THEN
            t = tabs*sqrt( ( one / tabs )**2+( sn1 / tabs )**2 )
         ELSE
            t = sqrt( cone+sn1*sn1 )
         END IF
         evnorm = abs( t )
         IF( evnorm.GE.thresh ) THEN
            evscal = cone / t
            cs1 = evscal
            sn1 = sn1*evscal
         ELSE
            evscal = zero
         END IF
      END IF
      RETURN
*
*     End of ZLAESY
*