subroutine zhst01	(	integer	N,
		integer	ILO,
		integer	IHI,
		complex*16, dimension( lda, * )	A,
		integer	LDA,
		complex*16, dimension( ldh, * )	H,
		integer	LDH,
		complex*16, dimension( ldq, * )	Q,
		integer	LDQ,
		complex*16, dimension( lwork )	WORK,
		integer	LWORK,
		double precision, dimension( * )	RWORK,
		double precision, dimension( 2 )	RESULT
	)

ZHST01

Purpose:

 ZHST01 tests the reduction of a general matrix A to upper Hessenberg
 form:  A = Q*H*Q'.  Two test ratios are computed;

 RESULT(1) = norm( A - Q*H*Q' ) / ( norm(A) * N * EPS )
 RESULT(2) = norm( I - Q'*Q ) / ( N * EPS )

 The matrix Q is assumed to be given explicitly as it would be
 following ZGEHRD + ZUNGHR.

 In this version, ILO and IHI are not used, but they could be used
 to save some work if this is desired.

Parameters

[in]	N	N is INTEGER The order of the matrix A. N >= 0.
[in]	ILO	ILO is INTEGER
[in]	IHI	IHI is INTEGER A is assumed to be upper triangular in rows and columns 1:ILO-1 and IHI+1:N, so Q differs from the identity only in rows and columns ILO+1:IHI.
[in]	A	A is COMPLEX*16 array, dimension (LDA,N) The original n by n matrix A.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,N).
[in]	H	H is COMPLEX*16 array, dimension (LDH,N) The upper Hessenberg matrix H from the reduction A = Q*H*Q' as computed by ZGEHRD. H is assumed to be zero below the first subdiagonal.
[in]	LDH	LDH is INTEGER The leading dimension of the array H. LDH >= max(1,N).
[in]	Q	Q is COMPLEX*16 array, dimension (LDQ,N) The orthogonal matrix Q from the reduction A = Q*H*Q' as computed by ZGEHRD + ZUNGHR.
[in]	LDQ	LDQ is INTEGER The leading dimension of the array Q. LDQ >= max(1,N).
[out]	WORK	WORK is COMPLEX*16 array, dimension (LWORK)
[in]	LWORK	LWORK is INTEGER The length of the array WORK. LWORK >= 2*N*N.
[out]	RWORK	RWORK is DOUBLE PRECISION array, dimension (N)
[out]	RESULT	RESULT is DOUBLE PRECISION array, dimension (2) RESULT(1) = norm( A - Q*H*Q' ) / ( norm(A) * N * EPS ) RESULT(2) = norm( I - Q'*Q ) / ( N * EPS )

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

November 2011

Definition at line 142 of file zhst01.f.

*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      INTEGER            ihi, ilo, lda, ldh, ldq, lwork, n
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   result( 2 ), rwork( * )
      COMPLEX*16         a( lda, * ), h( ldh, * ), q( ldq, * ),
     $                   work( lwork )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   one, zero
      parameter                ( one = 1.0d+0, zero = 0.0d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            ldwork
      DOUBLE PRECISION   anorm, eps, ovfl, smlnum, unfl, wnorm
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   dlamch, zlange
      EXTERNAL           dlamch, zlange
*     ..
*     .. External Subroutines ..
      EXTERNAL           dlabad, zgemm, zlacpy, zunt01
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dcmplx, max, min
*     ..
*     .. Executable Statements ..
*
*     Quick return if possible
*
      IF( n.LE.0 ) THEN
         result( 1 ) = zero
         result( 2 ) = zero
         RETURN
      END IF
*
      unfl = dlamch( 'Safe minimum' )
      eps = dlamch( 'Precision' )
      ovfl = one / unfl
      CALL dlabad( unfl, ovfl )
      smlnum = unfl*n / eps
*
*     Test 1:  Compute norm( A - Q*H*Q' ) / ( norm(A) * N * EPS )
*
*     Copy A to WORK
*
      ldwork = max( 1, n )
      CALL zlacpy( ' ', n, n, a, lda, work, ldwork )
*
*     Compute Q*H
*
      CALL zgemm( 'No transpose', 'No transpose', n, n, n,
     $            dcmplx( one ), q, ldq, h, ldh, dcmplx( zero ),
     $            work( ldwork*n+1 ), ldwork )
*
*     Compute A - Q*H*Q'
*
      CALL zgemm( 'No transpose', 'Conjugate transpose', n, n, n,
     $            dcmplx( -one ), work( ldwork*n+1 ), ldwork, q, ldq,
     $            dcmplx( one ), work, ldwork )
*
      anorm = max( zlange( '1', n, n, a, lda, rwork ), unfl )
      wnorm = zlange( '1', n, n, work, ldwork, rwork )
*
*     Note that RESULT(1) cannot overflow and is bounded by 1/(N*EPS)
*
      result( 1 ) = min( wnorm, anorm ) / max( smlnum, anorm*eps ) / n
*
*     Test 2:  Compute norm( I - Q'*Q ) / ( N * EPS )
*
      CALL zunt01( 'Columns', n, n, q, ldq, work, lwork, rwork,
     $             result( 2 ) )
*
      RETURN
*
*     End of ZHST01
*

Here is the call graph for this function:

Here is the caller graph for this function: