subroutine zget10	(	integer	M,
		integer	N,
		complex*16, dimension( lda, * )	A,
		integer	LDA,
		complex*16, dimension( ldb, * )	B,
		integer	LDB,
		complex*16, dimension( * )	WORK,
		double precision, dimension( * )	RWORK,
		double precision	RESULT
	)

ZGET10

Purpose:

 ZGET10 compares two matrices A and B and computes the ratio
 RESULT = norm( A - B ) / ( norm(A) * M * EPS )

Parameters

[in]	M	M is INTEGER The number of rows of the matrices A and B.
[in]	N	N is INTEGER The number of columns of the matrices A and B.
[in]	A	A is COMPLEX*16 array, dimension (LDA,N) The m by n matrix A.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,M).
[in]	B	B is COMPLEX*16 array, dimension (LDB,N) The m by n matrix B.
[in]	LDB	LDB is INTEGER The leading dimension of the array B. LDB >= max(1,M).
[out]	WORK	WORK is COMPLEX*16 array, dimension (M)
[out]	RWORK	RWORK is COMPLEX*16 array, dimension (M)
[out]	RESULT	RESULT is DOUBLE PRECISION RESULT = norm( A - B ) / ( norm(A) * M * EPS )

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

November 2011

Definition at line 101 of file zget10.f.

*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      INTEGER            lda, ldb, m, n
      DOUBLE PRECISION   result
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   rwork( * )
      COMPLEX*16         a( lda, * ), b( ldb, * ), work( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   one, zero
      parameter                ( one = 1.0d+0, zero = 0.0d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            j
      DOUBLE PRECISION   anorm, eps, unfl, wnorm
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   dlamch, dzasum, zlange
      EXTERNAL           dlamch, dzasum, zlange
*     ..
*     .. External Subroutines ..
      EXTERNAL           zaxpy, zcopy
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, dcmplx, max, min
*     ..
*     .. Executable Statements ..
*
*     Quick return if possible
*
      IF( m.LE.0 .OR. n.LE.0 ) THEN
         result = zero
         RETURN
      END IF
*
      unfl = dlamch( 'Safe minimum' )
      eps = dlamch( 'Precision' )
*
      wnorm = zero
      DO 10 j = 1, n
         CALL zcopy( m, a( 1, j ), 1, work, 1 )
         CALL zaxpy( m, dcmplx( -one ), b( 1, j ), 1, work, 1 )
         wnorm = max( wnorm, dzasum( n, work, 1 ) )
   10 CONTINUE
*
      anorm = max( zlange( '1', m, n, a, lda, rwork ), unfl )
*
      IF( anorm.GT.wnorm ) THEN
         result = ( wnorm / anorm ) / ( m*eps )
      ELSE
         IF( anorm.LT.one ) THEN
            result = ( min( wnorm, m*anorm ) / anorm ) / ( m*eps )
         ELSE
            result = min( wnorm / anorm, dble( m ) ) / ( m*eps )
         END IF
      END IF
*
      RETURN
*
*     End of ZGET10
*

Here is the call graph for this function:

Here is the caller graph for this function: