subroutine zckglm	(	integer	NN,
		integer, dimension( * )	NVAL,
		integer, dimension( * )	MVAL,
		integer, dimension( * )	PVAL,
		integer	NMATS,
		integer, dimension( 4 )	ISEED,
		double precision	THRESH,
		integer	NMAX,
		complex*16, dimension( * )	A,
		complex*16, dimension( * )	AF,
		complex*16, dimension( * )	B,
		complex*16, dimension( * )	BF,
		complex*16, dimension( * )	X,
		complex*16, dimension( * )	WORK,
		double precision, dimension( * )	RWORK,
		integer	NIN,
		integer	NOUT,
		integer	INFO
	)

ZCKGLM

Purpose:

 ZCKGLM tests ZGGGLM - subroutine for solving generalized linear
                       model problem.

Parameters

[in]	NN	NN is INTEGER The number of values of N, M and P contained in the vectors NVAL, MVAL and PVAL.
[in]	NVAL	NVAL is INTEGER array, dimension (NN) The values of the matrix row dimension N.
[in]	MVAL	MVAL is INTEGER array, dimension (NN) The values of the matrix column dimension M.
[in]	PVAL	PVAL is INTEGER array, dimension (NN) The values of the matrix column dimension P.
[in]	NMATS	NMATS is INTEGER The number of matrix types to be tested for each combination of matrix dimensions. If NMATS >= NTYPES (the maximum number of matrix types), then all the different types are generated for testing. If NMATS < NTYPES, another input line is read to get the numbers of the matrix types to be used.
[in,out]	ISEED	ISEED is INTEGER array, dimension (4) On entry, the seed of the random number generator. The array elements should be between 0 and 4095, otherwise they will be reduced mod 4096, and ISEED(4) must be odd. On exit, the next seed in the random number sequence after all the test matrices have been generated.
[in]	THRESH	THRESH is DOUBLE PRECISION The threshold value for the test ratios. A result is included in the output file if RESID >= THRESH. To have every test ratio printed, use THRESH = 0.
[in]	NMAX	NMAX is INTEGER The maximum value permitted for M or N, used in dimensioning the work arrays.
[out]	A	A is COMPLEX*16 array, dimension (NMAX*NMAX)
[out]	AF	AF is COMPLEX*16 array, dimension (NMAX*NMAX)
[out]	B	B is COMPLEX*16 array, dimension (NMAX*NMAX)
[out]	BF	BF is COMPLEX*16 array, dimension (NMAX*NMAX)
[out]	X	X is COMPLEX*16 array, dimension (4*NMAX)
[out]	RWORK	RWORK is DOUBLE PRECISION array, dimension (NMAX)
[out]	WORK	WORK is COMPLEX*16 array, dimension (NMAX*NMAX)
[in]	NIN	NIN is INTEGER The unit number for input.
[in]	NOUT	NOUT is INTEGER The unit number for output.
[out]	INFO	INFO is INTEGER = 0 : successful exit > 0 : If ZLATMS returns an error code, the absolute value of it is returned.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

November 2011

Definition at line 170 of file zckglm.f.

*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      INTEGER            info, nin, nmats, nmax, nn, nout
      DOUBLE PRECISION   thresh
*     ..
*     .. Array Arguments ..
      INTEGER            iseed( 4 ), mval( * ), nval( * ), pval( * )
      DOUBLE PRECISION   rwork( * )
      COMPLEX*16         a( * ), af( * ), b( * ), bf( * ), work( * ),
     $                   x( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            ntypes
      parameter                ( ntypes = 8 )
*     ..
*     .. Local Scalars ..
      LOGICAL            firstt
      CHARACTER          dista, distb, type
      CHARACTER*3        path
      INTEGER            i, iinfo, ik, imat, kla, klb, kua, kub, lda,
     $                   ldb, lwork, m, modea, modeb, n, nfail, nrun, p
      DOUBLE PRECISION   anorm, bnorm, cndnma, cndnmb, resid
*     ..
*     .. Local Arrays ..
      LOGICAL            dotype( ntypes )
*     ..
*     .. External Functions ..
      COMPLEX*16         zlarnd
      EXTERNAL           zlarnd
*     ..
*     .. External Subroutines ..
      EXTERNAL           alahdg, alareq, alasum, dlatb9, zglmts, zlatms
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs
*     ..
*     .. Executable Statements ..
*
*     Initialize constants.
*
      path( 1: 3 ) = 'GLM'
      info = 0
      nrun = 0
      nfail = 0
      firstt = .true.
      CALL alareq( path, nmats, dotype, ntypes, nin, nout )
      lda = nmax
      ldb = nmax
      lwork = nmax*nmax
*
*     Check for valid input values.
*
      DO 10 ik = 1, nn
         m = mval( ik )
         p = pval( ik )
         n = nval( ik )
         IF( m.GT.n .OR. n.GT.m+p ) THEN
            IF( firstt ) THEN
               WRITE( nout, fmt = * )
               firstt = .false.
            END IF
            WRITE( nout, fmt = 9997 )m, p, n
         END IF
   10 CONTINUE
      firstt = .true.
*
*     Do for each value of M in MVAL.
*
      DO 40 ik = 1, nn
         m = mval( ik )
         p = pval( ik )
         n = nval( ik )
         IF( m.GT.n .OR. n.GT.m+p )
     $      GO TO 40
*
         DO 30 imat = 1, ntypes
*
*           Do the tests only if DOTYPE( IMAT ) is true.
*
            IF( .NOT.dotype( imat ) )
     $         GO TO 30
*
*           Set up parameters with DLATB9 and generate test
*           matrices A and B with ZLATMS.
*
            CALL dlatb9( path, imat, m, p, n, TYPE, kla, kua, klb, kub,
     $                   anorm, bnorm, modea, modeb, cndnma, cndnmb,
     $                   dista, distb )
*
            CALL zlatms( n, m, dista, iseed, TYPE, rwork, modea, cndnma,
     $                   anorm, kla, kua, 'No packing', a, lda, work,
     $                   iinfo )
            IF( iinfo.NE.0 ) THEN
               WRITE( nout, fmt = 9999 )iinfo
               info = abs( iinfo )
               GO TO 30
            END IF
*
            CALL zlatms( n, p, distb, iseed, TYPE, rwork, modeb, cndnmb,
     $                   bnorm, klb, kub, 'No packing', b, ldb, work,
     $                   iinfo )
            IF( iinfo.NE.0 ) THEN
               WRITE( nout, fmt = 9999 )iinfo
               info = abs( iinfo )
               GO TO 30
            END IF
*
*           Generate random left hand side vector of GLM
*
            DO 20 i = 1, n
               x( i ) = zlarnd( 2, iseed )
   20       CONTINUE
*
            CALL zglmts( n, m, p, a, af, lda, b, bf, ldb, x,
     $                   x( nmax+1 ), x( 2*nmax+1 ), x( 3*nmax+1 ),
     $                   work, lwork, rwork, resid )
*
*           Print information about the tests that did not
*           pass the threshold.
*
            IF( resid.GE.thresh ) THEN
               IF( nfail.EQ.0 .AND. firstt ) THEN
                  firstt = .false.
                  CALL alahdg( nout, path )
               END IF
               WRITE( nout, fmt = 9998 )n, m, p, imat, 1, resid
               nfail = nfail + 1
            END IF
            nrun = nrun + 1
*
   30    CONTINUE
   40 CONTINUE
*
*     Print a summary of the results.
*
      CALL alasum( path, nout, nfail, nrun, 0 )
*
 9999 FORMAT( ' ZLATMS in ZCKGLM INFO = ', i5 )
 9998 FORMAT( ' N=', i4, ' M=', i4, ', P=', i4, ', type ', i2,
     $      ', test ', i2, ', ratio=', g13.6 )
 9997 FORMAT( ' *** Invalid input  for GLM:  M = ', i6, ', P = ', i6,
     $      ', N = ', i6, ';', / '     must satisfy M <= N <= M+P  ',
     $      '(this set of values will be skipped)' )
      RETURN
*
*     End of ZCKGLM
*

Here is the call graph for this function:

Here is the caller graph for this function: