subroutine zchkgk	(	integer	NIN,
		integer	NOUT
	)

ZCHKGK

Purpose:

 ZCHKGK tests ZGGBAK, a routine for backward balancing  of
 a matrix pair (A, B).

Parameters

[in]	NIN	NIN is INTEGER The logical unit number for input. NIN > 0.
[in]	NOUT	NOUT is INTEGER The logical unit number for output. NOUT > 0.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

November 2011

Definition at line 56 of file zchkgk.f.

*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      INTEGER            nin, nout
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            lda, ldb, ldvl, ldvr
      parameter                ( lda = 50, ldb = 50, ldvl = 50, ldvr = 50 )
      INTEGER            lde, ldf, ldwork, lrwork
      parameter                ( lde = 50, ldf = 50, ldwork = 50,
     $                   lrwork = 6*50 )
      DOUBLE PRECISION   zero
      parameter                ( zero = 0.0d+0 )
      COMPLEX*16         czero, cone
      parameter                ( czero = ( 0.0d+0, 0.0d+0 ),
     $                   cone = ( 1.0d+0, 0.0d+0 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            i, ihi, ilo, info, j, knt, m, n, ninfo
      DOUBLE PRECISION   anorm, bnorm, eps, rmax, vmax
      COMPLEX*16         cdum
*     ..
*     .. Local Arrays ..
      INTEGER            lmax( 4 )
      DOUBLE PRECISION   lscale( lda ), rscale( lda ), rwork( lrwork )
      COMPLEX*16         a( lda, lda ), af( lda, lda ), b( ldb, ldb ),
     $                   bf( ldb, ldb ), e( lde, lde ), f( ldf, ldf ),
     $                   vl( ldvl, ldvl ), vlf( ldvl, ldvl ),
     $                   vr( ldvr, ldvr ), vrf( ldvr, ldvr ),
     $                   work( ldwork, ldwork )
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   dlamch, zlange
      EXTERNAL           dlamch, zlange
*     ..
*     .. External Subroutines ..
      EXTERNAL           zgemm, zggbak, zggbal, zlacpy
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, dble, dimag, max
*     ..
*     .. Statement Functions ..
      DOUBLE PRECISION   cabs1
*     ..
*     .. Statement Function definitions ..
      cabs1( cdum ) = abs( dble( cdum ) ) + abs( dimag( cdum ) )
*     ..
*     .. Executable Statements ..
*
      lmax( 1 ) = 0
      lmax( 2 ) = 0
      lmax( 3 ) = 0
      lmax( 4 ) = 0
      ninfo = 0
      knt = 0
      rmax = zero
*
      eps = dlamch( 'Precision' )
*
   10 CONTINUE
      READ( nin, fmt = * )n, m
      IF( n.EQ.0 )
     $   GO TO 100
*
      DO 20 i = 1, n
         READ( nin, fmt = * )( a( i, j ), j = 1, n )
   20 CONTINUE
*
      DO 30 i = 1, n
         READ( nin, fmt = * )( b( i, j ), j = 1, n )
   30 CONTINUE
*
      DO 40 i = 1, n
         READ( nin, fmt = * )( vl( i, j ), j = 1, m )
   40 CONTINUE
*
      DO 50 i = 1, n
         READ( nin, fmt = * )( vr( i, j ), j = 1, m )
   50 CONTINUE
*
      knt = knt + 1
*
      anorm = zlange( 'M', n, n, a, lda, rwork )
      bnorm = zlange( 'M', n, n, b, ldb, rwork )
*
      CALL zlacpy( 'FULL', n, n, a, lda, af, lda )
      CALL zlacpy( 'FULL', n, n, b, ldb, bf, ldb )
*
      CALL zggbal( 'B', n, a, lda, b, ldb, ilo, ihi, lscale, rscale,
     $             rwork, info )
      IF( info.NE.0 ) THEN
         ninfo = ninfo + 1
         lmax( 1 ) = knt
      END IF
*
      CALL zlacpy( 'FULL', n, m, vl, ldvl, vlf, ldvl )
      CALL zlacpy( 'FULL', n, m, vr, ldvr, vrf, ldvr )
*
      CALL zggbak( 'B', 'L', n, ilo, ihi, lscale, rscale, m, vl, ldvl,
     $             info )
      IF( info.NE.0 ) THEN
         ninfo = ninfo + 1
         lmax( 2 ) = knt
      END IF
*
      CALL zggbak( 'B', 'R', n, ilo, ihi, lscale, rscale, m, vr, ldvr,
     $             info )
      IF( info.NE.0 ) THEN
         ninfo = ninfo + 1
         lmax( 3 ) = knt
      END IF
*
*     Test of ZGGBAK
*
*     Check tilde(VL)'*A*tilde(VR) - VL'*tilde(A)*VR
*     where tilde(A) denotes the transformed matrix.
*
      CALL zgemm( 'N', 'N', n, m, n, cone, af, lda, vr, ldvr, czero,
     $            work, ldwork )
      CALL zgemm( 'C', 'N', m, m, n, cone, vl, ldvl, work, ldwork,
     $            czero, e, lde )
*
      CALL zgemm( 'N', 'N', n, m, n, cone, a, lda, vrf, ldvr, czero,
     $            work, ldwork )
      CALL zgemm( 'C', 'N', m, m, n, cone, vlf, ldvl, work, ldwork,
     $            czero, f, ldf )
*
      vmax = zero
      DO 70 j = 1, m
         DO 60 i = 1, m
            vmax = max( vmax, cabs1( e( i, j )-f( i, j ) ) )
   60    CONTINUE
   70 CONTINUE
      vmax = vmax / ( eps*max( anorm, bnorm ) )
      IF( vmax.GT.rmax ) THEN
         lmax( 4 ) = knt
         rmax = vmax
      END IF
*
*     Check tilde(VL)'*B*tilde(VR) - VL'*tilde(B)*VR
*
      CALL zgemm( 'N', 'N', n, m, n, cone, bf, ldb, vr, ldvr, czero,
     $            work, ldwork )
      CALL zgemm( 'C', 'N', m, m, n, cone, vl, ldvl, work, ldwork,
     $            czero, e, lde )
*
      CALL zgemm( 'n', 'n', n, m, n, cone, b, ldb, vrf, ldvr, czero,
     $            work, ldwork )
      CALL zgemm( 'C', 'N', m, m, n, cone, vlf, ldvl, work, ldwork,
     $            czero, f, ldf )
*
      vmax = zero
      DO 90 j = 1, m
         DO 80 i = 1, m
            vmax = max( vmax, cabs1( e( i, j )-f( i, j ) ) )
   80    CONTINUE
   90 CONTINUE
      vmax = vmax / ( eps*max( anorm, bnorm ) )
      IF( vmax.GT.rmax ) THEN
         lmax( 4 ) = knt
         rmax = vmax
      END IF
*
      GO TO 10
*
  100 CONTINUE
*
      WRITE( nout, fmt = 9999 )
 9999 FORMAT( 1x, '.. test output of ZGGBAK .. ' )
*
      WRITE( nout, fmt = 9998 )rmax
 9998 FORMAT( ' value of largest test error                  =', d12.3 )
      WRITE( nout, fmt = 9997 )lmax( 1 )
 9997 FORMAT( ' example number where ZGGBAL info is not 0    =', i4 )
      WRITE( nout, fmt = 9996 )lmax( 2 )
 9996 FORMAT( ' example number where ZGGBAK(L) info is not 0 =', i4 )
      WRITE( nout, fmt = 9995 )lmax( 3 )
 9995 FORMAT( ' example number where ZGGBAK(R) info is not 0 =', i4 )
      WRITE( nout, fmt = 9994 )lmax( 4 )
 9994 FORMAT( ' example number having largest error          =', i4 )
      WRITE( nout, fmt = 9992 )ninfo
 9992 FORMAT( ' number of examples where info is not 0       =', i4 )
      WRITE( nout, fmt = 9991 )knt
 9991 FORMAT( ' total number of examples tested              =', i4 )
*
      RETURN
*
*     End of ZCHKGK
*

Here is the call graph for this function:

Here is the caller graph for this function: