subroutine dgetri	(	integer	N,
		double precision, dimension( lda, * )	A,
		integer	LDA,
		integer, dimension( * )	IPIV,
		double precision, dimension( * )	WORK,
		integer	LWORK,
		integer	INFO
	)

DGETRI

Download DGETRI + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 DGETRI computes the inverse of a matrix using the LU factorization
 computed by DGETRF.

 This method inverts U and then computes inv(A) by solving the system
 inv(A)*L = inv(U) for inv(A).

Parameters

[in]	N	N is INTEGER The order of the matrix A. N >= 0.
[in,out]	A	A is DOUBLE PRECISION array, dimension (LDA,N) On entry, the factors L and U from the factorization A = P*L*U as computed by DGETRF. On exit, if INFO = 0, the inverse of the original matrix A.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,N).
[in]	IPIV	IPIV is INTEGER array, dimension (N) The pivot indices from DGETRF; for 1<=i<=N, row i of the matrix was interchanged with row IPIV(i).
[out]	WORK	WORK is DOUBLE PRECISION array, dimension (MAX(1,LWORK)) On exit, if INFO=0, then WORK(1) returns the optimal LWORK.
[in]	LWORK	LWORK is INTEGER The dimension of the array WORK. LWORK >= max(1,N). For optimal performance LWORK >= N*NB, where NB is the optimal blocksize returned by ILAENV. If LWORK = -1, then a workspace query is assumed; the routine only calculates the optimal size of the WORK array, returns this value as the first entry of the WORK array, and no error message related to LWORK is issued by XERBLA.
[out]	INFO	INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value > 0: if INFO = i, U(i,i) is exactly zero; the matrix is singular and its inverse could not be computed.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

November 2011

Definition at line 116 of file dgetri.f.

*
*  -- LAPACK computational routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      INTEGER            info, lda, lwork, n
*     ..
*     .. Array Arguments ..
      INTEGER            ipiv( * )
      DOUBLE PRECISION   a( lda, * ), work( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   zero, one
      parameter                ( zero = 0.0d+0, one = 1.0d+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            lquery
      INTEGER            i, iws, j, jb, jj, jp, ldwork, lwkopt, nb,
     $                   nbmin, nn
*     ..
*     .. External Functions ..
      INTEGER            ilaenv
      EXTERNAL           ilaenv
*     ..
*     .. External Subroutines ..
      EXTERNAL           dgemm, dgemv, dswap, dtrsm, dtrtri, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      nb = ilaenv( 1, 'DGETRI', ' ', n, -1, -1, -1 )
      lwkopt = n*nb
      work( 1 ) = lwkopt
      lquery = ( lwork.EQ.-1 )
      IF( n.LT.0 ) THEN
         info = -1
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -3
      ELSE IF( lwork.LT.max( 1, n ) .AND. .NOT.lquery ) THEN
         info = -6
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'DGETRI', -info )
         RETURN
      ELSE IF( lquery ) THEN
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   RETURN
*
*     Form inv(U).  If INFO > 0 from DTRTRI, then U is singular,
*     and the inverse is not computed.
*
      CALL dtrtri( 'Upper', 'Non-unit', n, a, lda, info )
      IF( info.GT.0 )
     $   RETURN
*
      nbmin = 2
      ldwork = n
      IF( nb.GT.1 .AND. nb.LT.n ) THEN
         iws = max( ldwork*nb, 1 )
         IF( lwork.LT.iws ) THEN
            nb = lwork / ldwork
            nbmin = max( 2, ilaenv( 2, 'DGETRI', ' ', n, -1, -1, -1 ) )
         END IF
      ELSE
         iws = n
      END IF
*
*     Solve the equation inv(A)*L = inv(U) for inv(A).
*
      IF( nb.LT.nbmin .OR. nb.GE.n ) THEN
*
*        Use unblocked code.
*
         DO 20 j = n, 1, -1
*
*           Copy current column of L to WORK and replace with zeros.
*
            DO 10 i = j + 1, n
               work( i ) = a( i, j )
               a( i, j ) = zero
   10       CONTINUE
*
*           Compute current column of inv(A).
*
            IF( j.LT.n )
     $         CALL dgemv( 'No transpose', n, n-j, -one, a( 1, j+1 ),
     $                     lda, work( j+1 ), 1, one, a( 1, j ), 1 )
   20    CONTINUE
      ELSE
*
*        Use blocked code.
*
         nn = ( ( n-1 ) / nb )*nb + 1
         DO 50 j = nn, 1, -nb
            jb = min( nb, n-j+1 )
*
*           Copy current block column of L to WORK and replace with
*           zeros.
*
            DO 40 jj = j, j + jb - 1
               DO 30 i = jj + 1, n
                  work( i+( jj-j )*ldwork ) = a( i, jj )
                  a( i, jj ) = zero
   30          CONTINUE
   40       CONTINUE
*
*           Compute current block column of inv(A).
*
            IF( j+jb.LE.n )
     $         CALL dgemm( 'No transpose', 'No transpose', n, jb,
     $                     n-j-jb+1, -one, a( 1, j+jb ), lda,
     $                     work( j+jb ), ldwork, one, a( 1, j ), lda )
            CALL dtrsm( 'Right', 'Lower', 'No transpose', 'Unit', n, jb,
     $                  one, work( j ), ldwork, a( 1, j ), lda )
   50    CONTINUE
      END IF
*
*     Apply column interchanges.
*
      DO 60 j = n - 1, 1, -1
         jp = ipiv( j )
         IF( jp.NE.j )
     $      CALL dswap( n, a( 1, j ), 1, a( 1, jp ), 1 )
   60 CONTINUE
*
      work( 1 ) = iws
      RETURN
*
*     End of DGETRI
*

Here is the call graph for this function:

Here is the caller graph for this function: