LAPACK  3.6.1
LAPACK: Linear Algebra PACKage
subroutine dorbdb1 ( integer  M,
integer  P,
integer  Q,
double precision, dimension(ldx11,*)  X11,
integer  LDX11,
double precision, dimension(ldx21,*)  X21,
integer  LDX21,
double precision, dimension(*)  THETA,
double precision, dimension(*)  PHI,
double precision, dimension(*)  TAUP1,
double precision, dimension(*)  TAUP2,
double precision, dimension(*)  TAUQ1,
double precision, dimension(*)  WORK,
integer  LWORK,
integer  INFO 
)

DORBDB1

Download DORBDB1 + dependencies [TGZ] [ZIP] [TXT]

Purpose: 

 DORBDB1 simultaneously bidiagonalizes the blocks of a tall and skinny
 matrix X with orthonomal columns:

                            [ B11 ]
      [ X11 ]   [ P1 |    ] [  0  ]
      [-----] = [---------] [-----] Q1**T .
      [ X21 ]   [    | P2 ] [ B21 ]
                            [  0  ]

 X11 is P-by-Q, and X21 is (M-P)-by-Q. Q must be no larger than P,
 M-P, or M-Q. Routines DORBDB2, DORBDB3, and DORBDB4 handle cases in
 which Q is not the minimum dimension.

 The orthogonal matrices P1, P2, and Q1 are P-by-P, (M-P)-by-(M-P),
 and (M-Q)-by-(M-Q), respectively. They are represented implicitly by
 Householder vectors.

 B11 and B12 are Q-by-Q bidiagonal matrices represented implicitly by
 angles THETA, PHI.
Parameters
[in]M
          M is INTEGER
           The number of rows X11 plus the number of rows in X21.
[in]P
          P is INTEGER
           The number of rows in X11. 0 <= P <= M.
[in]Q
          Q is INTEGER
           The number of columns in X11 and X21. 0 <= Q <=
           MIN(P,M-P,M-Q).
[in,out]X11
          X11 is DOUBLE PRECISION array, dimension (LDX11,Q)
           On entry, the top block of the matrix X to be reduced. On
           exit, the columns of tril(X11) specify reflectors for P1 and
           the rows of triu(X11,1) specify reflectors for Q1.
[in]LDX11
          LDX11 is INTEGER
           The leading dimension of X11. LDX11 >= P.
[in,out]X21
          X21 is DOUBLE PRECISION array, dimension (LDX21,Q)
           On entry, the bottom block of the matrix X to be reduced. On
           exit, the columns of tril(X21) specify reflectors for P2.
[in]LDX21
          LDX21 is INTEGER
           The leading dimension of X21. LDX21 >= M-P.
[out]THETA
          THETA is DOUBLE PRECISION array, dimension (Q)
           The entries of the bidiagonal blocks B11, B21 are defined by
           THETA and PHI. See Further Details.
[out]PHI
          PHI is DOUBLE PRECISION array, dimension (Q-1)
           The entries of the bidiagonal blocks B11, B21 are defined by
           THETA and PHI. See Further Details.
[out]TAUP1
          TAUP1 is DOUBLE PRECISION array, dimension (P)
           The scalar factors of the elementary reflectors that define
           P1.
[out]TAUP2
          TAUP2 is DOUBLE PRECISION array, dimension (M-P)
           The scalar factors of the elementary reflectors that define
           P2.
[out]TAUQ1
          TAUQ1 is DOUBLE PRECISION array, dimension (Q)
           The scalar factors of the elementary reflectors that define
           Q1.
[out]WORK
          WORK is DOUBLE PRECISION array, dimension (LWORK)
[in]LWORK
          LWORK is INTEGER
           The dimension of the array WORK. LWORK >= M-Q.
 
           If LWORK = -1, then a workspace query is assumed; the routine
           only calculates the optimal size of the WORK array, returns
           this value as the first entry of the WORK array, and no error
           message related to LWORK is issued by XERBLA.
[out]INFO
          INFO is INTEGER
           = 0:  successful exit.
           < 0:  if INFO = -i, the i-th argument had an illegal value.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
July 2012
Further Details: 
  The upper-bidiagonal blocks B11, B21 are represented implicitly by
  angles THETA(1), ..., THETA(Q) and PHI(1), ..., PHI(Q-1). Every entry
  in each bidiagonal band is a product of a sine or cosine of a THETA
  with a sine or cosine of a PHI. See [1] or DORCSD for details.

  P1, P2, and Q1 are represented as products of elementary reflectors.
  See DORCSD2BY1 for details on generating P1, P2, and Q1 using DORGQR
  and DORGLQ.
References:
[1] Brian D. Sutton. Computing the complete CS decomposition. Numer. Algorithms, 50(1):33-65, 2009.

Definition at line 205 of file dorbdb1.f.

205 *
206 * -- LAPACK computational routine (version 3.6.1) --
207 * -- LAPACK is a software package provided by Univ. of Tennessee, --
208 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
209 * July 2012
210 *
211 * .. Scalar Arguments ..
212  INTEGER info, lwork, m, p, q, ldx11, ldx21
213 * ..
214 * .. Array Arguments ..
215  DOUBLE PRECISION phi(*), theta(*)
216  DOUBLE PRECISION taup1(*), taup2(*), tauq1(*), work(*),
217  $ x11(ldx11,*), x21(ldx21,*)
218 * ..
219 *
220 * ====================================================================
221 *
222 * .. Parameters ..
223  DOUBLE PRECISION one
224  parameter ( one = 1.0d0 )
225 * ..
226 * .. Local Scalars ..
227  DOUBLE PRECISION c, s
228  INTEGER childinfo, i, ilarf, iorbdb5, llarf, lorbdb5,
229  $ lworkmin, lworkopt
230  LOGICAL lquery
231 * ..
232 * .. External Subroutines ..
233  EXTERNAL dlarf, dlarfgp, dorbdb5, drot, xerbla
234 * ..
235 * .. External Functions ..
236  DOUBLE PRECISION dnrm2
237  EXTERNAL dnrm2
238 * ..
239 * .. Intrinsic Function ..
240  INTRINSIC atan2, cos, max, sin, sqrt
241 * ..
242 * .. Executable Statements ..
243 *
244 * Test input arguments
245 *
246  info = 0
247  lquery = lwork .EQ. -1
248 *
249  IF( m .LT. 0 ) THEN
250  info = -1
251  ELSE IF( p .LT. q .OR. m-p .LT. q ) THEN
252  info = -2
253  ELSE IF( q .LT. 0 .OR. m-q .LT. q ) THEN
254  info = -3
255  ELSE IF( ldx11 .LT. max( 1, p ) ) THEN
256  info = -5
257  ELSE IF( ldx21 .LT. max( 1, m-p ) ) THEN
258  info = -7
259  END IF
260 *
261 * Compute workspace
262 *
263  IF( info .EQ. 0 ) THEN
264  ilarf = 2
265  llarf = max( p-1, m-p-1, q-1 )
266  iorbdb5 = 2
267  lorbdb5 = q-2
268  lworkopt = max( ilarf+llarf-1, iorbdb5+lorbdb5-1 )
269  lworkmin = lworkopt
270  work(1) = lworkopt
271  IF( lwork .LT. lworkmin .AND. .NOT.lquery ) THEN
272  info = -14
273  END IF
274  END IF
275  IF( info .NE. 0 ) THEN
276  CALL xerbla( 'DORBDB1', -info )
277  RETURN
278  ELSE IF( lquery ) THEN
279  RETURN
280  END IF
281 *
282 * Reduce columns 1, ..., Q of X11 and X21
283 *
284  DO i = 1, q
285 *
286  CALL dlarfgp( p-i+1, x11(i,i), x11(i+1,i), 1, taup1(i) )
287  CALL dlarfgp( m-p-i+1, x21(i,i), x21(i+1,i), 1, taup2(i) )
288  theta(i) = atan2( x21(i,i), x11(i,i) )
289  c = cos( theta(i) )
290  s = sin( theta(i) )
291  x11(i,i) = one
292  x21(i,i) = one
293  CALL dlarf( 'L', p-i+1, q-i, x11(i,i), 1, taup1(i), x11(i,i+1),
294  $ ldx11, work(ilarf) )
295  CALL dlarf( 'L', m-p-i+1, q-i, x21(i,i), 1, taup2(i),
296  $ x21(i,i+1), ldx21, work(ilarf) )
297 *
298  IF( i .LT. q ) THEN
299  CALL drot( q-i, x11(i,i+1), ldx11, x21(i,i+1), ldx21, c, s )
300  CALL dlarfgp( q-i, x21(i,i+1), x21(i,i+2), ldx21, tauq1(i) )
301  s = x21(i,i+1)
302  x21(i,i+1) = one
303  CALL dlarf( 'R', p-i, q-i, x21(i,i+1), ldx21, tauq1(i),
304  $ x11(i+1,i+1), ldx11, work(ilarf) )
305  CALL dlarf( 'R', m-p-i, q-i, x21(i,i+1), ldx21, tauq1(i),
306  $ x21(i+1,i+1), ldx21, work(ilarf) )
307  c = sqrt( dnrm2( p-i, x11(i+1,i+1), 1 )**2
308  $ + dnrm2( m-p-i, x21(i+1,i+1), 1 )**2 )
309  phi(i) = atan2( s, c )
310  CALL dorbdb5( p-i, m-p-i, q-i-1, x11(i+1,i+1), 1,
311  $ x21(i+1,i+1), 1, x11(i+1,i+2), ldx11,
312  $ x21(i+1,i+2), ldx21, work(iorbdb5), lorbdb5,
313  $ childinfo )
314  END IF
315 *
316  END DO
317 *
318  RETURN
319 *
320 * End of DORBDB1
321 *
dlarfgp
subroutine dlarfgp(N, ALPHA, X, INCX, TAU)
DLARFGP generates an elementary reflector (Householder matrix) with non-negative beta.
Definition: dlarfgp.f:106
drot
subroutine drot(N, DX, INCX, DY, INCY, C, S)
DROT
Definition: drot.f:53
dlarf
subroutine dlarf(SIDE, M, N, V, INCV, TAU, C, LDC, WORK)
DLARF applies an elementary reflector to a general rectangular matrix.
Definition: dlarf.f:126
xerbla
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
dnrm2
double precision function dnrm2(N, X, INCX)
DNRM2
Definition: dnrm2.f:56
dorbdb5
subroutine dorbdb5(M1, M2, N, X1, INCX1, X2, INCX2, Q1, LDQ1, Q2, LDQ2, WORK, LWORK, INFO)
DORBDB5
Definition: dorbdb5.f:158

Here is the call graph for this function:

Here is the caller graph for this function: