subroutine cgttrs	(	character	TRANS,
		integer	N,
		integer	NRHS,
		complex, dimension( * )	DL,
		complex, dimension( * )	D,
		complex, dimension( * )	DU,
		complex, dimension( * )	DU2,
		integer, dimension( * )	IPIV,
		complex, dimension( ldb, * )	B,
		integer	LDB,
		integer	INFO
	)

CGTTRS

Download CGTTRS + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 CGTTRS solves one of the systems of equations
    A * X = B,  A**T * X = B,  or  A**H * X = B,
 with a tridiagonal matrix A using the LU factorization computed
 by CGTTRF.

Parameters

[in]	TRANS	TRANS is CHARACTER*1 Specifies the form of the system of equations. = 'N': A * X = B (No transpose) = 'T': A**T * X = B (Transpose) = 'C': A**H * X = B (Conjugate transpose)
[in]	N	N is INTEGER The order of the matrix A.
[in]	NRHS	NRHS is INTEGER The number of right hand sides, i.e., the number of columns of the matrix B. NRHS >= 0.
[in]	DL	DL is COMPLEX array, dimension (N-1) The (n-1) multipliers that define the matrix L from the LU factorization of A.
[in]	D	D is COMPLEX array, dimension (N) The n diagonal elements of the upper triangular matrix U from the LU factorization of A.
[in]	DU	DU is COMPLEX array, dimension (N-1) The (n-1) elements of the first super-diagonal of U.
[in]	DU2	DU2 is COMPLEX array, dimension (N-2) The (n-2) elements of the second super-diagonal of U.
[in]	IPIV	IPIV is INTEGER array, dimension (N) The pivot indices; for 1 <= i <= n, row i of the matrix was interchanged with row IPIV(i). IPIV(i) will always be either i or i+1; IPIV(i) = i indicates a row interchange was not required.
[in,out]	B	B is COMPLEX array, dimension (LDB,NRHS) On entry, the matrix of right hand side vectors B. On exit, B is overwritten by the solution vectors X.
[in]	LDB	LDB is INTEGER The leading dimension of the array B. LDB >= max(1,N).
[out]	INFO	INFO is INTEGER = 0: successful exit < 0: if INFO = -k, the k-th argument had an illegal value

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

September 2012

Definition at line 140 of file cgttrs.f.

*
*  -- LAPACK computational routine (version 3.4.2) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     September 2012
*
*     .. Scalar Arguments ..
      CHARACTER          trans
      INTEGER            info, ldb, n, nrhs
*     ..
*     .. Array Arguments ..
      INTEGER            ipiv( * )
      COMPLEX            b( ldb, * ), d( * ), dl( * ), du( * ), du2( * )
*     ..
*
*  =====================================================================
*
*     .. Local Scalars ..
      LOGICAL            notran
      INTEGER            itrans, j, jb, nb
*     ..
*     .. External Functions ..
      INTEGER            ilaenv
      EXTERNAL           ilaenv
*     ..
*     .. External Subroutines ..
      EXTERNAL           cgtts2, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min
*     ..
*     .. Executable Statements ..
*
      info = 0
      notran = ( trans.EQ.'N' .OR. trans.EQ.'n' )
      IF( .NOT.notran .AND. .NOT.( trans.EQ.'T' .OR. trans.EQ.
     $    't' ) .AND. .NOT.( trans.EQ.'C' .OR. trans.EQ.'c' ) ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( nrhs.LT.0 ) THEN
         info = -3
      ELSE IF( ldb.LT.max( n, 1 ) ) THEN
         info = -10
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CGTTRS', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 .OR. nrhs.EQ.0 )
     $   RETURN
*
*     Decode TRANS
*
      IF( notran ) THEN
         itrans = 0
      ELSE IF( trans.EQ.'T' .OR. trans.EQ.'t' ) THEN
         itrans = 1
      ELSE
         itrans = 2
      END IF
*
*     Determine the number of right-hand sides to solve at a time.
*
      IF( nrhs.EQ.1 ) THEN
         nb = 1
      ELSE
         nb = max( 1, ilaenv( 1, 'CGTTRS', trans, n, nrhs, -1, -1 ) )
      END IF
*
      IF( nb.GE.nrhs ) THEN
         CALL cgtts2( itrans, n, nrhs, dl, d, du, du2, ipiv, b, ldb )
      ELSE
         DO 10 j = 1, nrhs, nb
            jb = min( nrhs-j+1, nb )
            CALL cgtts2( itrans, n, jb, dl, d, du, du2, ipiv, b( 1, j ),
     $                   ldb )
   10    CONTINUE
      END IF
*
*     End of CGTTRS
*

Here is the call graph for this function:

Here is the caller graph for this function: