subroutine zppt01	(	character	UPLO,
		integer	N,
		complex*16, dimension( * )	A,
		complex*16, dimension( * )	AFAC,
		double precision, dimension( * )	RWORK,
		double precision	RESID
	)

ZPPT01

Purpose:

 ZPPT01 reconstructs a Hermitian positive definite packed matrix A
 from its L*L' or U'*U factorization and computes the residual
    norm( L*L' - A ) / ( N * norm(A) * EPS ) or
    norm( U'*U - A ) / ( N * norm(A) * EPS ),
 where EPS is the machine epsilon, L' is the conjugate transpose of
 L, and U' is the conjugate transpose of U.

Parameters

[in]	UPLO	UPLO is CHARACTER*1 Specifies whether the upper or lower triangular part of the Hermitian matrix A is stored: = 'U': Upper triangular = 'L': Lower triangular
[in]	N	N is INTEGER The number of rows and columns of the matrix A. N >= 0.
[in]	A	A is COMPLEX*16 array, dimension (N*(N+1)/2) The original Hermitian matrix A, stored as a packed triangular matrix.
[in,out]	AFAC	AFAC is COMPLEX*16 array, dimension (N*(N+1)/2) On entry, the factor L or U from the L*L' or U'*U factorization of A, stored as a packed triangular matrix. Overwritten with the reconstructed matrix, and then with the difference L*L' - A (or U'*U - A).
[out]	RWORK	RWORK is DOUBLE PRECISION array, dimension (N)
[out]	RESID	RESID is DOUBLE PRECISION If UPLO = 'L', norm(L*L' - A) / ( N * norm(A) * EPS ) If UPLO = 'U', norm(U'*U - A) / ( N * norm(A) * EPS )

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

November 2011

Definition at line 97 of file zppt01.f.

*
*  -- LAPACK test routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      CHARACTER          uplo
      INTEGER            n
      DOUBLE PRECISION   resid
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   rwork( * )
      COMPLEX*16         a( * ), afac( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   zero, one
      parameter                ( zero = 0.0d+0, one = 1.0d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            i, k, kc
      DOUBLE PRECISION   anorm, eps, tr
      COMPLEX*16         tc
*     ..
*     .. External Functions ..
      LOGICAL            lsame
      DOUBLE PRECISION   dlamch, zlanhp
      COMPLEX*16         zdotc
      EXTERNAL           lsame, dlamch, zlanhp, zdotc
*     ..
*     .. External Subroutines ..
      EXTERNAL           zhpr, zscal, ztpmv
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, dimag
*     ..
*     .. Executable Statements ..
*
*     Quick exit if N = 0
*
      IF( n.LE.0 ) THEN
         resid = zero
         RETURN
      END IF
*
*     Exit with RESID = 1/EPS if ANORM = 0.
*
      eps = dlamch( 'Epsilon' )
      anorm = zlanhp( '1', uplo, n, a, rwork )
      IF( anorm.LE.zero ) THEN
         resid = one / eps
         RETURN
      END IF
*
*     Check the imaginary parts of the diagonal elements and return with
*     an error code if any are nonzero.
*
      kc = 1
      IF( lsame( uplo, 'U' ) ) THEN
         DO 10 k = 1, n
            IF( dimag( afac( kc ) ).NE.zero ) THEN
               resid = one / eps
               RETURN
            END IF
            kc = kc + k + 1
   10    CONTINUE
      ELSE
         DO 20 k = 1, n
            IF( dimag( afac( kc ) ).NE.zero ) THEN
               resid = one / eps
               RETURN
            END IF
            kc = kc + n - k + 1
   20    CONTINUE
      END IF
*
*     Compute the product U'*U, overwriting U.
*
      IF( lsame( uplo, 'U' ) ) THEN
         kc = ( n*( n-1 ) ) / 2 + 1
         DO 30 k = n, 1, -1
*
*           Compute the (K,K) element of the result.
*
            tr = zdotc( k, afac( kc ), 1, afac( kc ), 1 )
            afac( kc+k-1 ) = tr
*
*           Compute the rest of column K.
*
            IF( k.GT.1 ) THEN
               CALL ztpmv( 'Upper', 'Conjugate', 'Non-unit', k-1, afac,
     $                     afac( kc ), 1 )
               kc = kc - ( k-1 )
            END IF
   30    CONTINUE
*
*        Compute the difference  L*L' - A
*
         kc = 1
         DO 50 k = 1, n
            DO 40 i = 1, k - 1
               afac( kc+i-1 ) = afac( kc+i-1 ) - a( kc+i-1 )
   40       CONTINUE
            afac( kc+k-1 ) = afac( kc+k-1 ) - dble( a( kc+k-1 ) )
            kc = kc + k
   50    CONTINUE
*
*     Compute the product L*L', overwriting L.
*
      ELSE
         kc = ( n*( n+1 ) ) / 2
         DO 60 k = n, 1, -1
*
*           Add a multiple of column K of the factor L to each of
*           columns K+1 through N.
*
            IF( k.LT.n )
     $         CALL zhpr( 'Lower', n-k, one, afac( kc+1 ), 1,
     $                    afac( kc+n-k+1 ) )
*
*           Scale column K by the diagonal element.
*
            tc = afac( kc )
            CALL zscal( n-k+1, tc, afac( kc ), 1 )
*
            kc = kc - ( n-k+2 )
   60    CONTINUE
*
*        Compute the difference  U'*U - A
*
         kc = 1
         DO 80 k = 1, n
            afac( kc ) = afac( kc ) - dble( a( kc ) )
            DO 70 i = k + 1, n
               afac( kc+i-k ) = afac( kc+i-k ) - a( kc+i-k )
   70       CONTINUE
            kc = kc + n - k + 1
   80    CONTINUE
      END IF
*
*     Compute norm( L*U - A ) / ( N * norm(A) * EPS )
*
      resid = zlanhp( '1', uplo, n, afac, rwork )
*
      resid = ( ( resid / dble( n ) ) / anorm ) / eps
*
      RETURN
*
*     End of ZPPT01
*

Here is the call graph for this function:

Here is the caller graph for this function: