subroutine dsyswapr	(	character	UPLO,
		integer	N,
		double precision, dimension( lda, n )	A,
		integer	LDA,
		integer	I1,
		integer	I2
	)

DSYSWAPR applies an elementary permutation on the rows and columns of a symmetric matrix.

Download DSYSWAPR + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 DSYSWAPR applies an elementary permutation on the rows and the columns of
 a symmetric matrix.

Parameters

[in]	UPLO	UPLO is CHARACTER*1 Specifies whether the details of the factorization are stored as an upper or lower triangular matrix. = 'U': Upper triangular, form is A = U*D*U**T; = 'L': Lower triangular, form is A = L*D*L**T.
[in]	N	N is INTEGER The order of the matrix A. N >= 0.
[in,out]	A	A is DOUBLE PRECISION array, dimension (LDA,N) On entry, the NB diagonal matrix D and the multipliers used to obtain the factor U or L as computed by DSYTRF. On exit, if INFO = 0, the (symmetric) inverse of the original matrix. If UPLO = 'U', the upper triangular part of the inverse is formed and the part of A below the diagonal is not referenced; if UPLO = 'L' the lower triangular part of the inverse is formed and the part of A above the diagonal is not referenced.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,N).
[in]	I1	I1 is INTEGER Index of the first row to swap
[in]	I2	I2 is INTEGER Index of the second row to swap

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

September 2012

Definition at line 104 of file dsyswapr.f.

*
*  -- LAPACK auxiliary routine (version 3.4.2) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     September 2012
*
*     .. Scalar Arguments ..
      CHARACTER        uplo
      INTEGER          i1, i2, lda, n
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION a( lda, n )
*
*  =====================================================================
*
*     ..
*     .. Local Scalars ..
      LOGICAL            upper
      INTEGER            i
      DOUBLE PRECISION   tmp
*
*     .. External Functions ..
      LOGICAL            lsame
      EXTERNAL           lsame
*     ..
*     .. External Subroutines ..
      EXTERNAL         dswap
*     ..
*     .. Executable Statements ..
*
      upper = lsame( uplo, 'U' )
      IF (upper) THEN
*
*         UPPER
*         first swap
*          - swap column I1 and I2 from I1 to I1-1 
         CALL dswap( i1-1, a(1,i1), 1, a(1,i2), 1 )
*
*          second swap :
*          - swap A(I1,I1) and A(I2,I2)
*          - swap row I1 from I1+1 to I2-1 with col I2 from I1+1 to I2-1     
         tmp=a(i1,i1)
         a(i1,i1)=a(i2,i2)
         a(i2,i2)=tmp
*
         DO i=1,i2-i1-1
            tmp=a(i1,i1+i)
            a(i1,i1+i)=a(i1+i,i2)
            a(i1+i,i2)=tmp
         END DO
*
*          third swap
*          - swap row I1 and I2 from I2+1 to N
         DO i=i2+1,n
            tmp=a(i1,i)
            a(i1,i)=a(i2,i)
            a(i2,i)=tmp
         END DO
*
        ELSE
*
*         LOWER
*         first swap
*          - swap row I1 and I2 from I1 to I1-1 
         CALL dswap( i1-1, a(i1,1), lda, a(i2,1), lda )
*
*         second swap :
*          - swap A(I1,I1) and A(I2,I2)
*          - swap col I1 from I1+1 to I2-1 with row I2 from I1+1 to I2-1     
          tmp=a(i1,i1)
          a(i1,i1)=a(i2,i2)
          a(i2,i2)=tmp
*
          DO i=1,i2-i1-1
             tmp=a(i1+i,i1)
             a(i1+i,i1)=a(i2,i1+i)
             a(i2,i1+i)=tmp
          END DO
*
*         third swap
*          - swap col I1 and I2 from I2+1 to N
          DO i=i2+1,n
             tmp=a(i,i1)
             a(i,i1)=a(i,i2)
             a(i,i2)=tmp
          END DO
*
      ENDIF

Here is the call graph for this function:

Here is the caller graph for this function: