LAPACK  3.6.1
LAPACK: Linear Algebra PACKage
subroutine sgehd2 ( integer  N,
integer  ILO,
integer  IHI,
real, dimension( lda, * )  A,
integer  LDA,
real, dimension( * )  TAU,
real, dimension( * )  WORK,
integer  INFO 
)

SGEHD2 reduces a general square matrix to upper Hessenberg form using an unblocked algorithm.

Download SGEHD2 + dependencies [TGZ] [ZIP] [TXT]

Purpose: 
 SGEHD2 reduces a real general matrix A to upper Hessenberg form H by
 an orthogonal similarity transformation:  Q**T * A * Q = H .
Parameters
[in]N
          N is INTEGER
          The order of the matrix A.  N >= 0.
[in]ILO
          ILO is INTEGER
[in]IHI
          IHI is INTEGER

          It is assumed that A is already upper triangular in rows
          and columns 1:ILO-1 and IHI+1:N. ILO and IHI are normally
          set by a previous call to SGEBAL; otherwise they should be
          set to 1 and N respectively. See Further Details.
          1 <= ILO <= IHI <= max(1,N).
[in,out]A
          A is REAL array, dimension (LDA,N)
          On entry, the n by n general matrix to be reduced.
          On exit, the upper triangle and the first subdiagonal of A
          are overwritten with the upper Hessenberg matrix H, and the
          elements below the first subdiagonal, with the array TAU,
          represent the orthogonal matrix Q as a product of elementary
          reflectors. See Further Details.
[in]LDA
          LDA is INTEGER
          The leading dimension of the array A.  LDA >= max(1,N).
[out]TAU
          TAU is REAL array, dimension (N-1)
          The scalar factors of the elementary reflectors (see Further
          Details).
[out]WORK
          WORK is REAL array, dimension (N)
[out]INFO
          INFO is INTEGER
          = 0:  successful exit.
          < 0:  if INFO = -i, the i-th argument had an illegal value.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
September 2012
Further Details: 
  The matrix Q is represented as a product of (ihi-ilo) elementary
  reflectors

     Q = H(ilo) H(ilo+1) . . . H(ihi-1).

  Each H(i) has the form

     H(i) = I - tau * v * v**T

  where tau is a real scalar, and v is a real vector with
  v(1:i) = 0, v(i+1) = 1 and v(ihi+1:n) = 0; v(i+2:ihi) is stored on
  exit in A(i+2:ihi,i), and tau in TAU(i).

  The contents of A are illustrated by the following example, with
  n = 7, ilo = 2 and ihi = 6:

  on entry,                        on exit,

  ( a   a   a   a   a   a   a )    (  a   a   h   h   h   h   a )
  (     a   a   a   a   a   a )    (      a   h   h   h   h   a )
  (     a   a   a   a   a   a )    (      h   h   h   h   h   h )
  (     a   a   a   a   a   a )    (      v2  h   h   h   h   h )
  (     a   a   a   a   a   a )    (      v2  v3  h   h   h   h )
  (     a   a   a   a   a   a )    (      v2  v3  v4  h   h   h )
  (                         a )    (                          a )

  where a denotes an element of the original matrix A, h denotes a
  modified element of the upper Hessenberg matrix H, and vi denotes an
  element of the vector defining H(i).

Definition at line 151 of file sgehd2.f.

151 *
152 * -- LAPACK computational routine (version 3.4.2) --
153 * -- LAPACK is a software package provided by Univ. of Tennessee, --
154 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
155 * September 2012
156 *
157 * .. Scalar Arguments ..
158  INTEGER ihi, ilo, info, lda, n
159 * ..
160 * .. Array Arguments ..
161  REAL a( lda, * ), tau( * ), work( * )
162 * ..
163 *
164 * =====================================================================
165 *
166 * .. Parameters ..
167  REAL one
168  parameter ( one = 1.0e+0 )
169 * ..
170 * .. Local Scalars ..
171  INTEGER i
172  REAL aii
173 * ..
174 * .. External Subroutines ..
175  EXTERNAL slarf, slarfg, xerbla
176 * ..
177 * .. Intrinsic Functions ..
178  INTRINSIC max, min
179 * ..
180 * .. Executable Statements ..
181 *
182 * Test the input parameters
183 *
184  info = 0
185  IF( n.LT.0 ) THEN
186  info = -1
187  ELSE IF( ilo.LT.1 .OR. ilo.GT.max( 1, n ) ) THEN
188  info = -2
189  ELSE IF( ihi.LT.min( ilo, n ) .OR. ihi.GT.n ) THEN
190  info = -3
191  ELSE IF( lda.LT.max( 1, n ) ) THEN
192  info = -5
193  END IF
194  IF( info.NE.0 ) THEN
195  CALL xerbla( 'SGEHD2', -info )
196  RETURN
197  END IF
198 *
199  DO 10 i = ilo, ihi - 1
200 *
201 * Compute elementary reflector H(i) to annihilate A(i+2:ihi,i)
202 *
203  CALL slarfg( ihi-i, a( i+1, i ), a( min( i+2, n ), i ), 1,
204  $ tau( i ) )
205  aii = a( i+1, i )
206  a( i+1, i ) = one
207 *
208 * Apply H(i) to A(1:ihi,i+1:ihi) from the right
209 *
210  CALL slarf( 'Right', ihi, ihi-i, a( i+1, i ), 1, tau( i ),
211  $ a( 1, i+1 ), lda, work )
212 *
213 * Apply H(i) to A(i+1:ihi,i+1:n) from the left
214 *
215  CALL slarf( 'Left', ihi-i, n-i, a( i+1, i ), 1, tau( i ),
216  $ a( i+1, i+1 ), lda, work )
217 *
218  a( i+1, i ) = aii
219  10 CONTINUE
220 *
221  RETURN
222 *
223 * End of SGEHD2
224 *
slarfg
subroutine slarfg(N, ALPHA, X, INCX, TAU)
SLARFG generates an elementary reflector (Householder matrix).
Definition: slarfg.f:108
xerbla
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
slarf
subroutine slarf(SIDE, M, N, V, INCV, TAU, C, LDC, WORK)
SLARF applies an elementary reflector to a general rectangular matrix.
Definition: slarf.f:126

Here is the call graph for this function:

Here is the caller graph for this function: